#!/usr/bin/perl
# Kyle Christensen <kyle@junglist.org>
# http://junglist.org/files/scripts/cvs2rss.pl
# 
# This script (when setup properly) will magically create an RSS 2.0 compliant feed
# that logs your cvs commits as well as a diff of the changes made.
#
# Run this from your CVSROOT/loginfo like:
#
#	/path/to/cvs2rss.pl %{sVv}
#
# Also, make sure your apache server has an AddType for rss like:
#
# 	AddType application/rss+xml .rss
#
# P.S. The "other" cvs2rss.pl isn't really cvs2rss, it is more like cvs2xml, boo!
# P.P.S. Parts of this are stolen from commit2rss.rb and the XML::RSS examples.
#
# Version 1.0 - 08.24.04 RSS Compliant, no cvs diff capability yet..
# Version 1.1 - 08.31.04 Adding CVS Diff capability
# Edit by Guy Albertelli, -- corrected the packaging of Entities
#                          - commits now <pre>ed
#                          - removed html rants
#

use strict;
use HTML::Entities();
use XML::RSS;
use POSIX;

# Stuff you need to setup 
my $cvslink = 'http://install.loncapa.org/cgi-bin/cvsweb.cgi/';
my $rssFeed ="/home/loninst/public_html/loncapa.rss";
my $emailDomain = "loncapa.org";
my $channelTitle = "Lon-CAPA RSS Feed";
my $channelLink = "http://install.loncapa.org/loncapa.rss";
my $numEntries = 30;

# Set this to 1 to enable cvs rdiff
my $cvsDiff = 1;

# Leave everything else alone
my $author = getpwuid(getuid());
my $pubDate = strftime('%a, %d %b %Y %H:%M:%S %Z',localtime(time));

my @args = split(" ", $ARGV[0]);
my $dir = shift(@args);

# bail when this is a new directory
&bail if $args[0] eq '-' && "$args[1] $args[2]" eq 'New directory';
# bail if this is an import
&bail if $args[0] eq '-' && $args[1] eq 'Imported';


my $rss = new XML::RSS(version => '2.0');

# If rssFeed exists, parse it
if (-r "$rssFeed") {
    $rss->parsefile($rssFeed);
}

$rss->channel(
	      title=> $channelTitle,
	      link => $channelLink,
	      language => 'en',
	      description => $channelTitle,
	      copyright => '(c) 2005 MSU Board of Trustees.',
	      pubDate => $pubDate 
	      );

# Limit entries in the feed to $numEntries
pop(@{$rss->{'items'}}) while (@{$rss->{'items'}} >= $numEntries);

my $commit_msg;
while (<STDIN>) {
    chomp($_);
    if ($_=~/^[A-Z].*:\s*$/) {
	$_ = "<br /><b>" . &HTML::Entities::encode($_,'<>&"') . "</b><br />";
    } else {
	$_ = &HTML::Entities::encode($_,'<>&"');
	$_ .= "<br />";
    }
    $commit_msg .= $_;
}

$commit_msg .= '<br /><b>Author:</b><br />'.$author.'<br />';

foreach my $file (@args) {
    my @title=split(",",$file);

    my $description = $commit_msg;
    # Format title of the rss item
    # Remove space, append / and set title to /file/that/changed - oldversion/newversion
    $title[0] =~s/ /\//;
    $title[0] = $dir.'/'.$title[0];

    # Format the cvslog msg itself

    if ($cvsDiff == 1) { 

	# If the old version of the file is not NONE (if
	# it isn't a new file), and if it is a pm/pl/conf/tab file.
	# This will rdiff it against the previous version, and
	# include that diff in the rss feed

	if (($title[1] != "NONE") 
	    && ($title[0]=~/(.*)\.(pm|pl|conf|tab)$/)
	    && ($title[0]!~|/localize/localize/..\.pm|) ) {
	    my $tmpFile = "/tmp/diff.$$";
	    my $cmdLine = "cvs -n rdiff -u -kk -r " . $title[1] .  " -r " . $title[2] . " " . $title[0] . ">" . $tmpFile;
	    system($cmdLine);
	    
	    $description .= "<br /><b>Differences:</b><br /><pre>";
	    open CVSDIFF, "<" . $tmpFile;
	    foreach my $line (<CVSDIFF>) {
		$description .= &HTML::Entities::encode($line,'<>&"');
	    }
	    $description .= "</pre>";
	    unlink($tmpFile);   
	}
    }

    my $link = $cvslink.$title[0];
    if ($title[1] != "NONE") {
        $link .= '.diff?r1='.$title[1].';r2='.$title[2].';f=h';
    }

    $rss->add_item(
		   title => "/" . $title[0] . " - " . $title[1] . "/" . $title[2],
		   author => $author,
		   description=> $description,
		   mode => 'insert',
		   pubDate => $pubDate,
		   link => $link
		   );		
}

foreach my $element (@{$rss->{'items'}}) {
    $element->{'description'} = 
	&HTML::Entities::encode($element->{'description'},'<>&"');
}

$rss->save($rssFeed);

# Rsync this rss feed to another publically accessable machine.
#my $cmdLine="rsync -r -e ssh --delete /export/www/rss/html/ builder\@monkey:/export/www/rss/html/";
#system($cmdLine);

sub bail {
    my @toss = <STDIN>;
    exit @_;
}
