1: # The LearningOnline Network with CAPA
2: # Construct and maintain state and binary representation of course for user
3: #
4: # $Id: lonuserstate.pm,v 1.38 2002/08/17 18:23:27 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Server for RAT Maps
29: #
30: # (Edit Handler for RAT Maps
31: # (TeX Content Handler
32: #
33: # YEAR=2000
34: # 05/29/00,05/30 Gerd Kortemeyer)
35: # 7/1 Gerd Kortemeyer)
36: # 7/1,7/3,7/4,7/7,7/8,7/10 Gerd Kortemeyer)
37: #
38: # 7/15,7/17,7/18,8/1,8/2,8/4,8/5,8/21,8/22,8/23,8/30,
39: # 9/2,9/4,9/29,9/30,10/2,10/11,10/30,10/31,
40: # 11/1,11/2,11/14,11/16,11/22,12/28,
41: # YEAR=2001
42: # 07/05/01,08/30,08/31 Gerd Kortemeyer
43: # 12/16 Scott Harrison
44: #
45: ###
46:
47: package Apache::lonuserstate;
48:
49: # ------------------------------------------------- modules used by this module
50: use strict;
51: use Apache::Constants qw(:common :http);
52: use Apache::File;
53: use HTML::TokeParser;
54: use Apache::lonnet();
55: use Apache::loncommon();
56: use GDBM_File;
57: use Apache::lonmsg;
58: use Safe;
59: use Safe::Hole;
60: use Opcode;
61:
62: # ---------------------------------------------------- Globals for this package
63:
64: my $pc; # Package counter
65: my %hash; # The big tied hash
66: my %parmhash;# The hash with the parameters
67: my @cond; # Array with all of the conditions
68: my $errtext; # variable with all errors
69: my $retfurl; # variable with the very first URL in the course
70: my %randompick; # randomly picked resources
71: # --------------------------------------------------------- Loads map from disk
72:
73: sub loadmap {
74: my $uri=shift;
75: if ($hash{'map_pc_'.$uri}) { return OK; }
76:
77: $pc++;
78: my $lpc=$pc;
79: $hash{'map_pc_'.$uri}=$lpc;
80: $hash{'map_id_'.$lpc}=$uri;
81:
82: # Determine and check filename
83: my $fn=&Apache::lonnet::filelocation('',$uri);
84:
85: my $ispage=($fn=~/\.page$/);
86:
87: unless (($fn=~/\.sequence$/) ||
88: ($fn=~/\.page$/)) {
89: $errtext.="Invalid map: $fn\n";
90: return OK;
91: }
92:
93: my $instr=&Apache::lonnet::getfile($fn);
94:
95: unless ($instr == -1) {
96:
97: # Successfully got file, parse it
98:
99: my $parser = HTML::TokeParser->new(\$instr);
100: my $token;
101:
102: my $linkpc=0;
103:
104: $fn=~/\.(\w+)$/;
105:
106: $hash{'map_type_'.$lpc}=$1;
107:
108: while ($token = $parser->get_token) {
109: if ($token->[0] eq 'S') {
110: if ($token->[1] eq 'resource') {
111: # -------------------------------------------------------------------- Resource
112:
113: my $rid=$lpc.'.'.$token->[2]->{'id'};
114:
115: $hash{'kind_'.$rid}='res';
116: $hash{'title_'.$rid}=$token->[2]->{'title'};
117: my $turi=$token->[2]->{'src'};
118: unless ($ispage) {
119: $turi=~/\.(\w+)$/;
120: my $embstyle=&Apache::loncommon::fileembstyle($1);
121: if ($token->[2]->{'external'} eq 'true') {
122: $turi=~s/^http\:\/\//\/adm\/wrapper\/ext\//;
123: } else {
124: my $embstyle=&Apache::loncommon::fileembstyle($1);
125: if (($embstyle eq 'img') || ($embstyle eq 'emb')) {
126: $turi='/adm/wrapper'.$turi;
127: }
128: }
129: }
130: $hash{'src_'.$rid}=$turi;
131:
132: if (defined($hash{'ids_'.$turi})) {
133: $hash{'ids_'.$turi}.=','.$rid;
134: } else {
135: $hash{'ids_'.$turi}=''.$rid;
136: }
137:
138: if ($token->[2]->{'external'} eq 'true') {
139: $hash{'ext_'.$rid}='true:';
140: } else {
141: $hash{'ext_'.$rid}='false:';
142: }
143: if ($token->[2]->{'type'}) {
144: $hash{'type_'.$rid}=$token->[2]->{'type'};
145: if ($token->[2]->{'type'} eq 'start') {
146: $hash{'map_start_'.$uri}="$rid";
147: }
148: if ($token->[2]->{'type'} eq 'finish') {
149: $hash{'map_finish_'.$uri}="$rid";
150: }
151: } else {
152: $hash{'type_'.$rid}='normal';
153: }
154:
155: if (($turi=~/\.sequence$/) ||
156: ($turi=~/\.page$/)) {
157: $hash{'is_map_'.$rid}=1;
158: &loadmap($turi);
159: }
160:
161: } elsif ($token->[1] eq 'condition') {
162: # ------------------------------------------------------------------- Condition
163:
164: my $rid=$lpc.'.'.$token->[2]->{'id'};
165:
166: $hash{'kind_'.$rid}='cond';
167: $cond[$#cond+1]=$token->[2]->{'value'};
168: $hash{'condid_'.$rid}=$#cond;
169: if ($token->[2]->{'type'}) {
170: $cond[$#cond].=':'.$token->[2]->{'type'};
171: } else {
172: $cond[$#cond].=':normal';
173: }
174:
175: } elsif ($token->[1] eq 'link') {
176: # ----------------------------------------------------------------------- Links
177:
178: $linkpc++;
179: my $linkid=$lpc.'.'.$linkpc;
180:
181: my $goesto=$lpc.'.'.$token->[2]->{'to'};
182: my $comesfrom=$lpc.'.'.$token->[2]->{'from'};
183: my $undercond=0;
184:
185: if ($token->[2]->{'condition'}) {
186: $undercond=$lpc.'.'.$token->[2]->{'condition'};
187: }
188:
189: $hash{'goesto_'.$linkid}=$goesto;
190: $hash{'comesfrom_'.$linkid}=$comesfrom;
191: $hash{'undercond_'.$linkid}=$undercond;
192:
193: if (defined($hash{'to_'.$comesfrom})) {
194: $hash{'to_'.$comesfrom}.=','.$linkid;
195: } else {
196: $hash{'to_'.$comesfrom}=''.$linkid;
197: }
198: if (defined($hash{'from_'.$goesto})) {
199: $hash{'from_'.$goesto}.=','.$linkid;
200: } else {
201: $hash{'from_'.$goesto}=''.$linkid;
202: }
203: } elsif ($token->[1] eq 'param') {
204: # ------------------------------------------------------------------- Parameter
205:
206: my $referid=$lpc.'.'.$token->[2]->{'to'};
207: my $part=$token->[2]->{'part'};
208: unless ($part) { $part=0; }
209: my $newparam=
210: &Apache::lonnet::escape($token->[2]->{'type'}).':'.
211: &Apache::lonnet::escape($part.'.'.
212: $token->[2]->{'name'}).'='.
213: &Apache::lonnet::escape($token->[2]->{'value'});
214: if (defined($hash{'param_'.$referid})) {
215: $hash{'param_'.$referid}.='&'.$newparam;
216: } else {
217: $hash{'param_'.$referid}=''.$newparam;
218: }
219: if ($token->[2]->{'name'} eq 'parameter_mapalias') {
220: $hash{'mapalias_'.$token->[2]->{'value'}}=$referid;
221: }
222: if ($token->[2]->{'name'} eq 'parameter_randompick') {
223: $randompick{$referid}=$token->[2]->{'value'};
224: }
225: }
226:
227: }
228: }
229:
230: } else {
231: $errtext.='Map not loaded: The file does not exist. ';
232: }
233: }
234:
235: # --------------------------------------------------------- Simplify expression
236:
237: sub simplify {
238: my $expression=shift;
239: # (8)=8
240: $expression=~s/\((\d+)\)/$1/g;
241: # 8&8=8
242: $expression=~s/(\D)(\d+)\&\2(\D)/$1$2$3/g;
243: # 8|8=8
244: $expression=~s/(\D)(\d+)\|\2(\D)/$1$2$3/g;
245: # (5&3)&4=5&3&4
246: $expression=~s/\((\d+)((?:\&\d+)+)\)\&(\d+\D)/$1$2\&$3/g;
247: # (((5&3)|(4&6)))=((5&3)|(4&6))
248: $expression=~
249: s/\((\(\(\d+(?:\&\d+)*\)(?:\|\(\d+(?:\&\d+)*\))+\))\)/$1/g;
250: # ((5&3)|(4&6))|(1&2)=(5&3)|(4&6)|(1&2)
251: $expression=~
252: s/\((\(\d+(?:\&\d+)*\))((?:\|\(\d+(?:\&\d+)*\))+)\)\|(\(\d+(?:\&\d+)*\))/\($1$2\|$3\)/g;
253: return $expression;
254: }
255:
256: # -------------------------------------------------------- Build condition hash
257:
258: sub traceroute {
259: my ($sofar,$rid,$beenhere)=@_;
260: $sofar=simplify($sofar);
261: unless ($beenhere=~/\&$rid\&/) {
262: $beenhere.=$rid.'&';
263: if (($retfurl eq '') && ($hash{'src_'.$rid})) {
264: my ($mapid,$resid)=split(/\./,$rid);
265: $retfurl=$hash{'src_'.$rid}.
266: (($hash{'src_'.$rid}=~/\?/)?'&':'?').'symb='.
267: &Apache::lonnet::symbclean(
268: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
269: '___'.$resid.'___'.
270: &Apache::lonnet::declutter($hash{'src_'.$rid}));
271: }
272: if (defined($hash{'conditions_'.$rid})) {
273: $hash{'conditions_'.$rid}=simplify(
274: '('.$hash{'conditions_'.$rid}.')|('.$sofar.')');
275: } else {
276: $hash{'conditions_'.$rid}=$sofar;
277: }
278: if (defined($hash{'is_map_'.$rid})) {
279: if (defined($hash{'map_start_'.$hash{'src_'.$rid}})) {
280: &traceroute($sofar,$hash{'map_start_'.$hash{'src_'.$rid}},'&');
281: if (defined($hash{'map_finish_'.$hash{'src_'.$rid}})) {
282: $sofar=
283: $hash{'conditions_'.$hash{'map_finish_'.$hash{'src_'.$rid}}};
284: }
285: }
286: }
287: if (defined($hash{'to_'.$rid})) {
288: foreach (split(/\,/,$hash{'to_'.$rid})) {
289: my $further=$sofar;
290: if ($hash{'undercond_'.$_}) {
291: if (defined($hash{'condid_'.$hash{'undercond_'.$_}})) {
292: $further=simplify('('.$further.')&('.
293: $hash{'condid_'.$hash{'undercond_'.$_}}.')');
294: } else {
295: $errtext.='Undefined condition ID: '
296: .$hash{'undercond_'.$_}.'. ';
297: }
298: }
299: &traceroute($further,$hash{'goesto_'.$_},$beenhere);
300: }
301: }
302: }
303: }
304:
305: # ------------------------------ Cascading conditions, quick access, parameters
306:
307: sub accinit {
308: my ($uri,$short,$fn)=@_;
309: my %acchash=();
310: my %captured=();
311: my $condcounter=0;
312: $acchash{'acc.cond.'.$short.'.0'}=0;
313: foreach (keys %hash) {
314: if ($_=~/^conditions/) {
315: my $expr=$hash{$_};
316: foreach ($expr=~m/(\(\(\d+(?:\&\d+)+\)(?:\|\(\d+(?:\&\d+)+\))+\))/g) {
317: my $sub=$_;
318: my $orig=$_;
319: $sub=~/\(\((\d+\&(:?\d+\&)*)(?:\d+\&*)+\)(?:\|\(\1(?:\d+\&*)+\))+\)/;
320: my $factor=$1;
321: $sub=~s/$factor//g;
322: $sub=~s/^\(/\($factor\(/;
323: $sub.=')';
324: $sub=simplify($sub);
325: $orig=~s/(\W)/\\$1/g;
326: $expr=~s/$orig/$sub/;
327: }
328: $hash{$_}=$expr;
329: unless (defined($captured{$expr})) {
330: $condcounter++;
331: $captured{$expr}=$condcounter;
332: $acchash{'acc.cond.'.$short.'.'.$condcounter}=$expr;
333: }
334: } elsif ($_=~/^param_(\d+)\.(\d+)/) {
335: my $prefix=&Apache::lonnet::declutter($hash{'map_id_'.$1}).
336: '___'.$2.'___'.&Apache::lonnet::declutter($hash{'src_'.$1.'.'.$2});
337: foreach (split(/\&/,$hash{$_})) {
338: my ($typename,$value)=split(/\=/,$_);
339: my ($type,$name)=split(/\:/,$typename);
340: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name)}=
341: &Apache::lonnet::unescape($value);
342: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name).'.type'}=
343: &Apache::lonnet::unescape($type);
344: }
345: }
346: }
347: foreach (keys %hash) {
348: if ($_=~/^ids/) {
349: foreach (split(/\,/,$hash{$_})) {
350: my $resid=$_;
351: my $uri=$hash{'src_'.$resid};
352: $uri=~s/^\/adm\/wrapper//;
353: my @uriparts=split(/\//,$uri);
354: my $urifile=$uriparts[$#uriparts];
355: $#uriparts--;
356: my $uripath=join('/',@uriparts);
357: $uripath=~s/^\/res\///;
358: if ($uripath) {
359: my $uricond='0';
360: if (defined($hash{'conditions_'.$resid})) {
361: $uricond=$captured{$hash{'conditions_'.$resid}};
362: }
363: if (defined($acchash{'acc.res.'.$short.'.'.$uripath})) {
364: if ($acchash{'acc.res.'.$short.'.'.$uripath}=~
365: /(\&$urifile\:[^\&]*)/) {
366: my $replace=$1;
367: my $regexp=$replace;
368: $regexp=~s/\|/\\\|/g;
369: $acchash{'acc.res.'.$short.'.'.$uripath}
370: =~s/$regexp/$replace\|$uricond/;
371: } else {
372: $acchash{'acc.res.'.$short.'.'.$uripath}.=
373: $urifile.':'.$uricond.'&';
374: }
375: } else {
376: $acchash{'acc.res.'.$short.'.'.$uripath}=
377: '&'.$urifile.':'.$uricond.'&';
378: }
379: }
380: }
381: }
382: }
383: $acchash{'acc.res.'.$short.'.'}='&:0&';
384: my $courseuri=$uri;
385: $courseuri=~s/^\/res\///;
386: &Apache::lonnet::delenv('(acc\.|httpref\.)');
387: &Apache::lonnet::appenv(%acchash,
388: "request.course.id" => $short,
389: "request.course.fn" => $fn,
390: "request.course.uri" => $courseuri);
391: }
392:
393: # ------------------------------------- Selectively delete from randompick maps
394:
395: sub pickrandom {
396: my $randomoutentry='';
397: foreach my $rid (keys %randompick) {
398: my $rndpick=$randompick{$rid};
399: my $mpc=$hash{'map_pc_'.$hash{'src_'.$rid}};
400: # ------------------------------------------- put existing resources into array
401: my @currentrids=();
402: foreach (keys %hash) {
403: if ($_=~/^src_($mpc\.\d+)/) {
404: if ($hash{'src_'.$1}) { push @currentrids, $1; }
405: }
406: }
407: next if ($#currentrids<$rndpick);
408: # -------------------------------- randomly eliminate the ones that should stay
409: srand(&Apache::lonnet::rndseed($rid)); # use rid instead of symb
410: for (my $i=1;$i<=$rndpick;$i++) {
411: while (1) {
412: my $randomidx=int(rand($#currentrids+1));
413: if ($currentrids[$randomidx]) {
414: $currentrids[$randomidx]='';
415: last;
416: }
417: }
418: }
419: # -------------------------------------------------------- delete the leftovers
420: for (my $k=0; $k<=$#currentrids; $k++) {
421: if ($currentrids[$k]) {
422: $hash{'randomout_'.$currentrids[$k]}=1;
423: my ($mapid,$resid)=split(/\./,$currentrids[$k]);
424: $randomoutentry.='&'.
425: &Apache::lonnet::symbclean(
426: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
427: '___'.$resid.'___'.
428: &Apache::lonnet::declutter($hash{'src_'.$currentrids[$k]})
429: ).'&';
430: }
431: }
432: }
433: if ($randomoutentry) {
434: &Apache::lonnet::appenv('acc.randomout' => $randomoutentry);
435: }
436: }
437:
438: # ---------------------------------------------------- Read map and all submaps
439:
440: sub readmap {
441: my $short=shift;
442: $short=~s/^\///;
443: my %cenv=&Apache::lonnet::coursedescription($short);
444: my $fn=$cenv{'fn'};
445: my $uri;
446: $short=~s/\//\_/g;
447: unless ($uri=$cenv{'url'}) {
448: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
449: "Could not load course $short.</font>");
450: return 'No course data available.';
451: }
452: @cond=('true:normal');
453: unlink($fn.'.db');
454: unlink($fn.'_symb.db');
455: unlink($fn.'.state');
456: unlink($fn.'parms.db');
457: undef %randompick;
458: $retfurl='';
459: if ((tie(%hash,'GDBM_File',"$fn.db",&GDBM_WRCREAT(),0640)) &&
460: (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_WRCREAT(),0640))) {
461: %hash=();
462: %parmhash=();
463: $errtext='';
464: $pc=0;
465: my $furi=&Apache::lonnet::clutter($uri);
466: $hash{'src_0.0'}=$furi;
467: $hash{'title_0.0'}=&Apache::lonnet::metadata($uri,'title');
468: $hash{'ids_'.$furi}='0.0';
469: $hash{'is_map_0.0'}=1;
470: loadmap($uri);
471: if (defined($hash{'map_start_'.$uri})) {
472: &traceroute('0',$hash{'map_start_'.$uri},'&');
473: &accinit($uri,$short,$fn);
474: &pickrandom();
475: }
476: unless ((untie(%hash)) && (untie(%parmhash))) {
477: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
478: "Could not untie coursemap $fn for $uri.</font>");
479: }
480: {
481: my $cfh;
482: if ($cfh=Apache::File->new(">$fn.state")) {
483: print $cfh join("\n",@cond);
484: } else {
485: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
486: "Could not write statemap $fn for $uri.</font>");
487: }
488: }
489: } else {
490: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
491: "Could not tie coursemap $fn for $uri.</font>");
492: }
493: &Apache::lonmsg::author_res_msg($ENV{'request.course.uri'},$errtext);
494: return ($retfurl,$errtext);
495: }
496:
497: # ------------------------------------------------------- Evaluate state string
498:
499: sub evalstate {
500:
501: my $fn=$ENV{'request.course.fn'}.'.state';
502: my $state='2';
503: if (-e $fn) {
504: my @conditions=();
505: {
506: my $fh=Apache::File->new($fn);
507: @conditions=<$fh>;
508: }
509: my $safeeval = new Safe;
510: my $safehole = new Safe::Hole;
511: $safeeval->permit("entereval");
512: $safeeval->permit(":base_math");
513: $safeeval->deny(":base_io");
514: $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
515: foreach (@conditions) {
516: my $line=$_;
517: chomp($line);
518: my ($condition,$weight)=split(/\:/,$_);
519: if ($safeeval->reval($condition)) {
520: if ($weight eq 'force') {
521: $state.='3';
522: } else {
523: $state.='2';
524: }
525: } else {
526: if ($weight eq 'stop') {
527: $state.='0';
528: } else {
529: $state.='1';
530: }
531: }
532: }
533: }
534: &Apache::lonnet::appenv('user.state.'.$ENV{'request.course.id'} => $state);
535: return $state;
536: }
537:
538: 1;
539: __END__
540:
541: =head1 NAME
542:
543: Apache::lonuserstate - Construct and maintain state and binary representation
544: of course for user
545:
546: =head1 SYNOPSIS
547:
548: Invoked by lonroles.pm.
549:
550: &Apache::lonuserstate::readmap($cdom.'/'.$cnum);
551:
552: =head1 INTRODUCTION
553:
554: This module constructs and maintains state and binary representation
555: of course for user.
556:
557: This is part of the LearningOnline Network with CAPA project
558: described at http://www.lon-capa.org.
559:
560: =head1 HANDLER SUBROUTINE
561:
562: There is no handler subroutine.
563:
564: =head1 OTHER SUBROUTINES
565:
566: =over 4
567:
568: =item *
569:
570: loadmap() : Loads map from disk
571:
572: =item *
573:
574: simplify() : Simplify expression
575:
576: =item *
577:
578: traceroute() : Build condition hash
579:
580: =item *
581:
582: accinit() : Cascading conditions, quick access, parameters
583:
584: =item *
585:
586: readmap() : Read map and all submaps
587:
588: =item *
589:
590: evalstate() : Evaluate state string
591:
592: =back
593:
594: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonuserstate.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / rat