1: # The LearningOnline Network with CAPA
2: # Construct and maintain state and binary representation of course for user
3: #
4: # $Id: lonuserstate.pm,v 1.35 2002/07/25 16:55:53 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Server for RAT Maps
29: #
30: # (Edit Handler for RAT Maps
31: # (TeX Content Handler
32: #
33: # YEAR=2000
34: # 05/29/00,05/30 Gerd Kortemeyer)
35: # 7/1 Gerd Kortemeyer)
36: # 7/1,7/3,7/4,7/7,7/8,7/10 Gerd Kortemeyer)
37: #
38: # 7/15,7/17,7/18,8/1,8/2,8/4,8/5,8/21,8/22,8/23,8/30,
39: # 9/2,9/4,9/29,9/30,10/2,10/11,10/30,10/31,
40: # 11/1,11/2,11/14,11/16,11/22,12/28,
41: # YEAR=2001
42: # 07/05/01,08/30,08/31 Gerd Kortemeyer
43: # 12/16 Scott Harrison
44: #
45: ###
46:
47: package Apache::lonuserstate;
48:
49: # ------------------------------------------------- modules used by this module
50: use strict;
51: use Apache::Constants qw(:common :http);
52: use Apache::File;
53: use HTML::TokeParser;
54: use Apache::lonnet();
55: use Apache::loncommon();
56: use GDBM_File;
57: use Apache::lonmsg;
58: use Safe;
59: use Safe::Hole;
60: use Opcode;
61:
62: # ---------------------------------------------------- Globals for this package
63:
64: my $pc; # Package counter
65: my %hash; # The big tied hash
66: my %parmhash;# The hash with the parameters
67: my @cond; # Array with all of the conditions
68: my $errtext; # variable with all errors
69: my $retfurl; # variable with the very first URL in the course
70: my %randompick; # randomly picked resources
71: # --------------------------------------------------------- Loads map from disk
72:
73: sub loadmap {
74: my $uri=shift;
75: if ($hash{'map_pc_'.$uri}) { return OK; }
76:
77: $pc++;
78: my $lpc=$pc;
79: $hash{'map_pc_'.$uri}=$lpc;
80: $hash{'map_id_'.$lpc}=$uri;
81:
82: my $fn='/home/httpd/html'.$uri;
83:
84: unless (($fn=~/\.sequence$/) ||
85: ($fn=~/\.page$/)) {
86: $errtext.="Invalid map: $fn\n";
87: return OK;
88: }
89:
90: my $ispage=($fn=~/\.page$/);
91:
92: unless (-e $fn) {
93: my $returned=Apache::lonnet::repcopy($fn);
94: unless ($returned eq OK) {
95: $errtext.="Could not import: $fn - ";
96: if ($returned eq HTTP_SERVICE_UNAVAILABLE) {
97: $errtext.="Server unavailable\n";
98: }
99: if ($returned eq HTTP_NOT_FOUND) {
100: $errtext.="File not found\n";
101: }
102: if ($returned eq FORBIDDEN) {
103: $errtext.="Access forbidden\n";
104: }
105: return OK;
106: }
107: }
108:
109: if (-e $fn) {
110: my @content;
111: {
112: my $fh=Apache::File->new($fn);
113: @content=<$fh>;
114: }
115: my $instr=join('',@content);
116: my $parser = HTML::TokeParser->new(\$instr);
117: my $token;
118:
119: my $linkpc=0;
120:
121: $fn=~/\.(\w+)$/;
122:
123: $hash{'map_type_'.$lpc}=$1;
124:
125: while ($token = $parser->get_token) {
126: if ($token->[0] eq 'S') {
127: if ($token->[1] eq 'resource') {
128: # -------------------------------------------------------------------- Resource
129:
130: my $rid=$lpc.'.'.$token->[2]->{'id'};
131:
132: $hash{'kind_'.$rid}='res';
133: $hash{'title_'.$rid}=$token->[2]->{'title'};
134: my $turi=$token->[2]->{'src'};
135: unless ($ispage) {
136: $turi=~/\.(\w+)$/;
137: my $embstyle=&Apache::loncommon::fileembstyle($1);
138: if ($token->[2]->{'external'} eq 'true') {
139: $turi=~s/^http\:\/\//\/adm\/wrapper\/ext\//;
140: } else {
141: my $embstyle=&Apache::loncommon::fileembstyle($1);
142: if (($embstyle eq 'img') || ($embstyle eq 'emb')) {
143: $turi='/adm/wrapper'.$turi;
144: }
145: }
146: }
147: $hash{'src_'.$rid}=$turi;
148:
149: if (defined($hash{'ids_'.$turi})) {
150: $hash{'ids_'.$turi}.=','.$rid;
151: } else {
152: $hash{'ids_'.$turi}=''.$rid;
153: }
154:
155: if ($token->[2]->{'external'} eq 'true') {
156: $hash{'ext_'.$rid}='true:';
157: } else {
158: $hash{'ext_'.$rid}='false:';
159: }
160: if ($token->[2]->{'type'}) {
161: $hash{'type_'.$rid}=$token->[2]->{'type'};
162: if ($token->[2]->{'type'} eq 'start') {
163: $hash{'map_start_'.$uri}="$rid";
164: }
165: if ($token->[2]->{'type'} eq 'finish') {
166: $hash{'map_finish_'.$uri}="$rid";
167: }
168: } else {
169: $hash{'type_'.$rid}='normal';
170: }
171:
172: if (($turi=~/\.sequence$/) ||
173: ($turi=~/\.page$/)) {
174: $hash{'is_map_'.$rid}=1;
175: &loadmap($turi);
176: }
177:
178: } elsif ($token->[1] eq 'condition') {
179: # ------------------------------------------------------------------- Condition
180:
181: my $rid=$lpc.'.'.$token->[2]->{'id'};
182:
183: $hash{'kind_'.$rid}='cond';
184: $cond[$#cond+1]=$token->[2]->{'value'};
185: $hash{'condid_'.$rid}=$#cond;
186: if ($token->[2]->{'type'}) {
187: $cond[$#cond].=':'.$token->[2]->{'type'};
188: } else {
189: $cond[$#cond].=':normal';
190: }
191:
192: } elsif ($token->[1] eq 'link') {
193: # ----------------------------------------------------------------------- Links
194:
195: $linkpc++;
196: my $linkid=$lpc.'.'.$linkpc;
197:
198: my $goesto=$lpc.'.'.$token->[2]->{'to'};
199: my $comesfrom=$lpc.'.'.$token->[2]->{'from'};
200: my $undercond=0;
201:
202: if ($token->[2]->{'condition'}) {
203: $undercond=$lpc.'.'.$token->[2]->{'condition'};
204: }
205:
206: $hash{'goesto_'.$linkid}=$goesto;
207: $hash{'comesfrom_'.$linkid}=$comesfrom;
208: $hash{'undercond_'.$linkid}=$undercond;
209:
210: if (defined($hash{'to_'.$comesfrom})) {
211: $hash{'to_'.$comesfrom}.=','.$linkid;
212: } else {
213: $hash{'to_'.$comesfrom}=''.$linkid;
214: }
215: if (defined($hash{'from_'.$goesto})) {
216: $hash{'from_'.$goesto}.=','.$linkid;
217: } else {
218: $hash{'from_'.$goesto}=''.$linkid;
219: }
220: } elsif ($token->[1] eq 'param') {
221: # ------------------------------------------------------------------- Parameter
222:
223: my $referid=$lpc.'.'.$token->[2]->{'to'};
224: my $part=$token->[2]->{'part'};
225: unless ($part) { $part=0; }
226: my $newparam=
227: &Apache::lonnet::escape($token->[2]->{'type'}).':'.
228: &Apache::lonnet::escape($part.'.'.
229: $token->[2]->{'name'}).'='.
230: &Apache::lonnet::escape($token->[2]->{'value'});
231: if (defined($hash{'param_'.$referid})) {
232: $hash{'param_'.$referid}.='&'.$newparam;
233: } else {
234: $hash{'param_'.$referid}=''.$newparam;
235: }
236: if ($token->[2]->{'name'} eq 'parameter_mapalias') {
237: $hash{'mapalias_'.$token->[2]->{'value'}}=$referid;
238: }
239: if ($token->[2]->{'name'} eq 'parameter_randompick') {
240: $randompick{$referid}=$token->[2]->{'value'};
241: }
242: }
243:
244: }
245: }
246:
247: } else {
248: $errtext.='Map not loaded: The file does not exist. ';
249: }
250: }
251:
252: # --------------------------------------------------------- Simplify expression
253:
254: sub simplify {
255: my $expression=shift;
256: # (8)=8
257: $expression=~s/\((\d+)\)/$1/g;
258: # 8&8=8
259: $expression=~s/(\D)(\d+)\&\2(\D)/$1$2$3/g;
260: # 8|8=8
261: $expression=~s/(\D)(\d+)\|\2(\D)/$1$2$3/g;
262: # (5&3)&4=5&3&4
263: $expression=~s/\((\d+)((?:\&\d+)+)\)\&(\d+\D)/$1$2\&$3/g;
264: # (((5&3)|(4&6)))=((5&3)|(4&6))
265: $expression=~
266: s/\((\(\(\d+(?:\&\d+)*\)(?:\|\(\d+(?:\&\d+)*\))+\))\)/$1/g;
267: # ((5&3)|(4&6))|(1&2)=(5&3)|(4&6)|(1&2)
268: $expression=~
269: s/\((\(\d+(?:\&\d+)*\))((?:\|\(\d+(?:\&\d+)*\))+)\)\|(\(\d+(?:\&\d+)*\))/\($1$2\|$3\)/g;
270: return $expression;
271: }
272:
273: # -------------------------------------------------------- Build condition hash
274:
275: sub traceroute {
276: my ($sofar,$rid,$beenhere)=@_;
277: $sofar=simplify($sofar);
278: unless ($beenhere=~/\&$rid\&/) {
279: $beenhere.=$rid.'&';
280: if (($retfurl eq '') && ($hash{'src_'.$rid})) {
281: my ($mapid,$resid)=split(/\./,$rid);
282: $retfurl=$hash{'src_'.$rid}.
283: (($hash{'src_'.$rid}=~/\?/)?'&':'?').'symb='.
284: &Apache::lonnet::symbclean(
285: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
286: '___'.$resid.'___'.
287: &Apache::lonnet::declutter($hash{'src_'.$rid}));
288: }
289: if (defined($hash{'conditions_'.$rid})) {
290: $hash{'conditions_'.$rid}=simplify(
291: '('.$hash{'conditions_'.$rid}.')|('.$sofar.')');
292: } else {
293: $hash{'conditions_'.$rid}=$sofar;
294: }
295: if (defined($hash{'is_map_'.$rid})) {
296: if (defined($hash{'map_start_'.$hash{'src_'.$rid}})) {
297: &traceroute($sofar,$hash{'map_start_'.$hash{'src_'.$rid}},'&');
298: if (defined($hash{'map_finish_'.$hash{'src_'.$rid}})) {
299: $sofar=
300: $hash{'conditions_'.$hash{'map_finish_'.$hash{'src_'.$rid}}};
301: }
302: }
303: }
304: if (defined($hash{'to_'.$rid})) {
305: foreach (split(/\,/,$hash{'to_'.$rid})) {
306: my $further=$sofar;
307: if ($hash{'undercond_'.$_}) {
308: if (defined($hash{'condid_'.$hash{'undercond_'.$_}})) {
309: $further=simplify('('.$further.')&('.
310: $hash{'condid_'.$hash{'undercond_'.$_}}.')');
311: } else {
312: $errtext.='Undefined condition ID: '
313: .$hash{'undercond_'.$_}.'. ';
314: }
315: }
316: &traceroute($further,$hash{'goesto_'.$_},$beenhere);
317: }
318: }
319: }
320: }
321:
322: # ------------------------------ Cascading conditions, quick access, parameters
323:
324: sub accinit {
325: my ($uri,$short,$fn)=@_;
326: my %acchash=();
327: my %captured=();
328: my $condcounter=0;
329: $acchash{'acc.cond.'.$short.'.0'}=0;
330: foreach (keys %hash) {
331: if ($_=~/^conditions/) {
332: my $expr=$hash{$_};
333: foreach ($expr=~m/(\(\(\d+(?:\&\d+)+\)(?:\|\(\d+(?:\&\d+)+\))+\))/g) {
334: my $sub=$_;
335: my $orig=$_;
336: $sub=~/\(\((\d+\&(:?\d+\&)*)(?:\d+\&*)+\)(?:\|\(\1(?:\d+\&*)+\))+\)/;
337: my $factor=$1;
338: $sub=~s/$factor//g;
339: $sub=~s/^\(/\($factor\(/;
340: $sub.=')';
341: $sub=simplify($sub);
342: $orig=~s/(\W)/\\$1/g;
343: $expr=~s/$orig/$sub/;
344: }
345: $hash{$_}=$expr;
346: unless (defined($captured{$expr})) {
347: $condcounter++;
348: $captured{$expr}=$condcounter;
349: $acchash{'acc.cond.'.$short.'.'.$condcounter}=$expr;
350: }
351: } elsif ($_=~/^param_(\d+)\.(\d+)/) {
352: my $prefix=&Apache::lonnet::declutter($hash{'map_id_'.$1}).
353: '___'.$2.'___'.&Apache::lonnet::declutter($hash{'src_'.$1.'.'.$2});
354: foreach (split(/\&/,$hash{$_})) {
355: my ($typename,$value)=split(/\=/,$_);
356: my ($type,$name)=split(/\:/,$typename);
357: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name)}=
358: &Apache::lonnet::unescape($value);
359: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name).'.type'}=
360: &Apache::lonnet::unescape($type);
361: }
362: }
363: }
364: foreach (keys %hash) {
365: if ($_=~/^ids/) {
366: foreach (split(/\,/,$hash{$_})) {
367: my $resid=$_;
368: my $uri=$hash{'src_'.$resid};
369: $uri=~s/^\/adm\/wrapper//;
370: my @uriparts=split(/\//,$uri);
371: my $urifile=$uriparts[$#uriparts];
372: $#uriparts--;
373: my $uripath=join('/',@uriparts);
374: $uripath=~s/^\/res\///;
375: if ($uripath) {
376: my $uricond='0';
377: if (defined($hash{'conditions_'.$resid})) {
378: $uricond=$captured{$hash{'conditions_'.$resid}};
379: }
380: if (defined($acchash{'acc.res.'.$short.'.'.$uripath})) {
381: if ($acchash{'acc.res.'.$short.'.'.$uripath}=~
382: /(\&$urifile\:[^\&]*)/) {
383: my $replace=$1;
384: my $regexp=$replace;
385: $regexp=~s/\|/\\\|/g;
386: $acchash{'acc.res.'.$short.'.'.$uripath}
387: =~s/$regexp/$replace\|$uricond/;
388: } else {
389: $acchash{'acc.res.'.$short.'.'.$uripath}.=
390: $urifile.':'.$uricond.'&';
391: }
392: } else {
393: $acchash{'acc.res.'.$short.'.'.$uripath}=
394: '&'.$urifile.':'.$uricond.'&';
395: }
396: }
397: }
398: }
399: }
400: $acchash{'acc.res.'.$short.'.'}='&:0&';
401: my $courseuri=$uri;
402: $courseuri=~s/^\/res\///;
403: &Apache::lonnet::delenv('(acc\.|httpref\.)');
404: &Apache::lonnet::appenv(%acchash,
405: "request.course.id" => $short,
406: "request.course.fn" => $fn,
407: "request.course.uri" => $courseuri);
408: }
409:
410: # ------------------------------------- Selectively delete from randompick maps
411:
412: sub pickrandom {
413: my $randomoutentry='';
414: foreach my $rid (keys %randompick) {
415: my $rndpick=$randompick{$rid};
416: my $mpc=$hash{'map_pc_'.$hash{'src_'.$rid}};
417: # ------------------------------------------- put existing resources into array
418: my @currentrids=();
419: foreach (keys %hash) {
420: if ($_=~/^src_($mpc\.\d+)/) {
421: if ($hash{'src_'.$1}) { push @currentrids, $1; }
422: }
423: }
424: next if ($#currentrids<$rndpick);
425: # -------------------------------- randomly eliminate the ones that should stay
426: srand(&Apache::lonnet::rndseed($rid)); # use rid instead of symb
427: for (my $i=1;$i<=$rndpick;$i++) {
428: while (1) {
429: my $randomidx=int(rand($#currentrids+1));
430: if ($currentrids[$randomidx]) {
431: $currentrids[$randomidx]='';
432: last;
433: }
434: }
435: }
436: # -------------------------------------------------------- delete the leftovers
437: for (my $k=0; $k<=$#currentrids; $k++) {
438: if ($currentrids[$k]) {
439: $hash{'randomout_'.$currentrids[$k]}=1;
440: my ($mapid,$resid)=split(/\./,$currentrids[$k]);
441: $randomoutentry.='&'.
442: &Apache::lonnet::symbclean(
443: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
444: '___'.$resid.'___'.
445: &Apache::lonnet::declutter($hash{'src_'.$currentrids[$k]})
446: ).'&';
447: }
448: }
449: }
450: if ($randomoutentry) {
451: &Apache::lonnet::appenv('acc.randomout' => $randomoutentry);
452: }
453: }
454:
455: # ---------------------------------------------------- Read map and all submaps
456:
457: sub readmap {
458: my $short=shift;
459: $short=~s/^\///;
460: my %cenv=&Apache::lonnet::coursedescription($short);
461: my $fn=$cenv{'fn'};
462: my $uri;
463: $short=~s/\//\_/g;
464: unless ($uri=$cenv{'url'}) {
465: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
466: "Could not load course $short.</font>");
467: return 'No course data available.';
468: }
469: @cond=('true:normal');
470: unlink($fn.'.db');
471: unlink($fn.'_symb.db');
472: unlink($fn.'.state');
473: unlink($fn.'parms.db');
474: undef %randompick;
475: $retfurl='';
476: if ((tie(%hash,'GDBM_File',"$fn.db",&GDBM_WRCREAT,0640)) &&
477: (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_WRCREAT,0640))) {
478: %hash=();
479: %parmhash=();
480: $errtext='';
481: $pc=0;
482: my $furi='/res/'.&Apache::lonnet::declutter($uri);
483: $hash{'src_0.0'}=$furi;
484: $hash{'title_0.0'}=&Apache::lonnet::metadata($uri,'title');
485: $hash{'ids_'.$furi}='0.0';
486: $hash{'is_map_0.0'}=1;
487: loadmap($uri);
488: if (defined($hash{'map_start_'.$uri})) {
489: &traceroute('0',$hash{'map_start_'.$uri},'&');
490: &accinit($uri,$short,$fn);
491: &pickrandom();
492: }
493: unless ((untie(%hash)) && (untie(%parmhash))) {
494: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
495: "Could not untie coursemap $fn for $uri.</font>");
496: }
497: {
498: my $cfh;
499: if ($cfh=Apache::File->new(">$fn.state")) {
500: print $cfh join("\n",@cond);
501: } else {
502: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
503: "Could not write statemap $fn for $uri.</font>");
504: }
505: }
506: } else {
507: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
508: "Could not tie coursemap $fn for $uri.</font>");
509: }
510: &Apache::lonmsg::author_res_msg($ENV{'request.course.uri'},$errtext);
511: return ($retfurl,$errtext);
512: }
513:
514: # ------------------------------------------------------- Evaluate state string
515:
516: sub evalstate {
517:
518: my $fn=$ENV{'request.course.fn'}.'.state';
519: my $state='2';
520: if (-e $fn) {
521: my @conditions=();
522: {
523: my $fh=Apache::File->new($fn);
524: @conditions=<$fh>;
525: }
526: my $safeeval = new Safe;
527: my $safehole = new Safe::Hole;
528: $safeeval->permit("entereval");
529: $safeeval->permit(":base_math");
530: $safeeval->deny(":base_io");
531: $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
532: foreach (@conditions) {
533: my $line=$_;
534: chomp($line);
535: my ($condition,$weight)=split(/\:/,$_);
536: if ($safeeval->reval($condition)) {
537: if ($weight eq 'force') {
538: $state.='3';
539: } else {
540: $state.='2';
541: }
542: } else {
543: if ($weight eq 'stop') {
544: $state.='0';
545: } else {
546: $state.='1';
547: }
548: }
549: }
550: }
551: &Apache::lonnet::appenv('user.state.'.$ENV{'request.course.id'} => $state);
552: return $state;
553: }
554:
555: 1;
556: __END__
557:
558: =head1 NAME
559:
560: Apache::lonuserstate - Construct and maintain state and binary representation
561: of course for user
562:
563: =head1 SYNOPSIS
564:
565: Invoked by lonroles.pm.
566:
567: &Apache::lonuserstate::readmap($cdom.'/'.$cnum);
568:
569: =head1 INTRODUCTION
570:
571: This module constructs and maintains state and binary representation
572: of course for user.
573:
574: This is part of the LearningOnline Network with CAPA project
575: described at http://www.lon-capa.org.
576:
577: =head1 HANDLER SUBROUTINE
578:
579: There is no handler subroutine.
580:
581: =head1 OTHER SUBROUTINES
582:
583: =over 4
584:
585: =item *
586:
587: loadmap() : Loads map from disk
588:
589: =item *
590:
591: simplify() : Simplify expression
592:
593: =item *
594:
595: traceroute() : Build condition hash
596:
597: =item *
598:
599: accinit() : Cascading conditions, quick access, parameters
600:
601: =item *
602:
603: readmap() : Read map and all submaps
604:
605: =item *
606:
607: evalstate() : Evaluate state string
608:
609: =back
610:
611: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonuserstate.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / rat