1: # The LearningOnline Network with CAPA
2: # Construct and maintain state and binary representation of course for user
3: #
4: # $Id: lonuserstate.pm,v 1.29 2002/06/24 14:09:49 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (Server for RAT Maps
29: #
30: # (Edit Handler for RAT Maps
31: # (TeX Content Handler
32: #
33: # YEAR=2000
34: # 05/29/00,05/30 Gerd Kortemeyer)
35: # 7/1 Gerd Kortemeyer)
36: # 7/1,7/3,7/4,7/7,7/8,7/10 Gerd Kortemeyer)
37: #
38: # 7/15,7/17,7/18,8/1,8/2,8/4,8/5,8/21,8/22,8/23,8/30,
39: # 9/2,9/4,9/29,9/30,10/2,10/11,10/30,10/31,
40: # 11/1,11/2,11/14,11/16,11/22,12/28,
41: # YEAR=2001
42: # 07/05/01,08/30,08/31 Gerd Kortemeyer
43: # 12/16 Scott Harrison
44: #
45: ###
46:
47: package Apache::lonuserstate;
48:
49: # ------------------------------------------------- modules used by this module
50: use strict;
51: use Apache::Constants qw(:common :http);
52: use Apache::File;
53: use HTML::TokeParser;
54: use Apache::lonnet();
55: use Apache::loncommon();
56: use GDBM_File;
57: use Apache::lonmsg;
58: use Safe;
59: use Safe::Hole;
60: use Opcode;
61:
62: # ---------------------------------------------------- Globals for this package
63:
64: my $pc; # Package counter
65: my %hash; # The big tied hash
66: my %parmhash;# The hash with the parameters
67: my @cond; # Array with all of the conditions
68: my $errtext; # variable with all errors
69: my $retfurl; # variable with the very first URL in the course
70: my %randompick; # randomly picked resources
71: # --------------------------------------------------------- Loads map from disk
72:
73: sub loadmap {
74: my $uri=shift;
75: if ($hash{'map_pc_'.$uri}) { return OK; }
76:
77: $pc++;
78: my $lpc=$pc;
79: $hash{'map_pc_'.$uri}=$lpc;
80: $hash{'map_id_'.$lpc}=$uri;
81:
82: my $fn='/home/httpd/html'.$uri;
83:
84: unless (($fn=~/\.sequence$/) ||
85: ($fn=~/\.page$/)) {
86: $errtext.="Invalid map: $fn\n";
87: return OK;
88: }
89:
90: my $ispage=($fn=~/\.page$/);
91:
92: unless (-e $fn) {
93: my $returned=Apache::lonnet::repcopy($fn);
94: unless ($returned eq OK) {
95: $errtext.="Could not import: $fn - ";
96: if ($returned eq HTTP_SERVICE_UNAVAILABLE) {
97: $errtext.="Server unavailable\n";
98: }
99: if ($returned eq HTTP_NOT_FOUND) {
100: $errtext.="File not found\n";
101: }
102: if ($returned eq FORBIDDEN) {
103: $errtext.="Access forbidden\n";
104: }
105: return OK;
106: }
107: }
108:
109: if (-e $fn) {
110: my @content;
111: {
112: my $fh=Apache::File->new($fn);
113: @content=<$fh>;
114: }
115: my $instr=join('',@content);
116: my $parser = HTML::TokeParser->new(\$instr);
117: my $token;
118:
119: my $linkpc=0;
120:
121: $fn=~/\.(\w+)$/;
122:
123: $hash{'map_type_'.$lpc}=$1;
124:
125: while ($token = $parser->get_token) {
126: if ($token->[0] eq 'S') {
127: if ($token->[1] eq 'resource') {
128: # -------------------------------------------------------------------- Resource
129:
130: my $rid=$lpc.'.'.$token->[2]->{'id'};
131:
132: $hash{'kind_'.$rid}='res';
133: $hash{'title_'.$rid}=$token->[2]->{'title'};
134: my $turi=$token->[2]->{'src'};
135: unless ($ispage) {
136: $turi=~/\.(\w+)$/;
137: my $embstyle=&Apache::loncommon::fileembstyle($1);
138: if ($token->[2]->{'external'} eq 'true') {
139: $turi=~s/^http\:\/\//\/adm\/wrapper\/ext\//;
140: } else {
141: my $embstyle=&Apache::loncommon::fileembstyle($1);
142: if (($embstyle eq 'img') || ($embstyle eq 'emb')) {
143: $turi='/adm/wrapper'.$turi;
144: }
145: }
146: }
147: $hash{'src_'.$rid}=$turi;
148:
149: if (defined($hash{'ids_'.$turi})) {
150: $hash{'ids_'.$turi}.=','.$rid;
151: } else {
152: $hash{'ids_'.$turi}=''.$rid;
153: }
154:
155: if ($token->[2]->{'external'} eq 'true') {
156: $hash{'ext_'.$rid}='true:';
157: } else {
158: $hash{'ext_'.$rid}='false:';
159: }
160: if ($token->[2]->{'type'}) {
161: $hash{'type_'.$rid}=$token->[2]->{'type'};
162: if ($token->[2]->{'type'} eq 'start') {
163: $hash{'map_start_'.$uri}="$rid";
164: }
165: if ($token->[2]->{'type'} eq 'finish') {
166: $hash{'map_finish_'.$uri}="$rid";
167: }
168: } else {
169: $hash{'type_'.$rid}='normal';
170: }
171:
172: if (($turi=~/\.sequence$/) ||
173: ($turi=~/\.page$/)) {
174: $hash{'is_map_'.$rid}=1;
175: &loadmap($turi);
176: }
177:
178: } elsif ($token->[1] eq 'condition') {
179: # ------------------------------------------------------------------- Condition
180:
181: my $rid=$lpc.'.'.$token->[2]->{'id'};
182:
183: $hash{'kind_'.$rid}='cond';
184: $cond[$#cond+1]=$token->[2]->{'value'};
185: $hash{'condid_'.$rid}=$#cond;
186: if ($token->[2]->{'type'}) {
187: $cond[$#cond].=':'.$token->[2]->{'type'};
188: } else {
189: $cond[$#cond].=':normal';
190: }
191:
192: } elsif ($token->[1] eq 'link') {
193: # ----------------------------------------------------------------------- Links
194:
195: $linkpc++;
196: my $linkid=$lpc.'.'.$linkpc;
197:
198: my $goesto=$lpc.'.'.$token->[2]->{'to'};
199: my $comesfrom=$lpc.'.'.$token->[2]->{'from'};
200: my $undercond=0;
201:
202: if ($token->[2]->{'condition'}) {
203: $undercond=$lpc.'.'.$token->[2]->{'condition'};
204: }
205:
206: $hash{'goesto_'.$linkid}=$goesto;
207: $hash{'comesfrom_'.$linkid}=$comesfrom;
208: $hash{'undercond_'.$linkid}=$undercond;
209:
210: if (defined($hash{'to_'.$comesfrom})) {
211: $hash{'to_'.$comesfrom}.=','.$linkid;
212: } else {
213: $hash{'to_'.$comesfrom}=''.$linkid;
214: }
215: if (defined($hash{'from_'.$goesto})) {
216: $hash{'from_'.$goesto}.=','.$linkid;
217: } else {
218: $hash{'from_'.$goesto}=''.$linkid;
219: }
220: } elsif ($token->[1] eq 'param') {
221: # ------------------------------------------------------------------- Parameter
222:
223: my $referid=$lpc.'.'.$token->[2]->{'to'};
224: my $part=$token->[2]->{'part'};
225: unless ($part) { $part=0; }
226: my $newparam=
227: &Apache::lonnet::escape($token->[2]->{'type'}).':'.
228: &Apache::lonnet::escape($part.'.'.
229: $token->[2]->{'name'}).'='.
230: &Apache::lonnet::escape($token->[2]->{'value'});
231: if (defined($hash{'param_'.$referid})) {
232: $hash{'param_'.$referid}.='&'.$newparam;
233: } else {
234: $hash{'param_'.$referid}=''.$newparam;
235: }
236: if ($token->[2]->{'name'} eq 'parameter_mapalias') {
237: $hash{'mapalias_'.$token->[2]->{'value'}}=$referid;
238: }
239: if ($token->[2]->{'name'} eq 'parameter_randompick') {
240: $randompick{$referid}=$token->[2]->{'value'};
241: }
242: }
243:
244: }
245: }
246:
247: } else {
248: $errtext.='Map not loaded: The file does not exist. ';
249: }
250: }
251:
252: # --------------------------------------------------------- Simplify expression
253:
254: sub simplify {
255: my $expression=shift;
256: # (8)=8
257: $expression=~s/\((\d+)\)/$1/g;
258: # 8&8=8
259: $expression=~s/(\D)(\d+)\&\2(\D)/$1$2$3/g;
260: # 8|8=8
261: $expression=~s/(\D)(\d+)\|\2(\D)/$1$2$3/g;
262: # (5&3)&4=5&3&4
263: $expression=~s/\((\d+)((?:\&\d+)+)\)\&(\d+\D)/$1$2\&$3/g;
264: # (((5&3)|(4&6)))=((5&3)|(4&6))
265: $expression=~
266: s/\((\(\(\d+(?:\&\d+)*\)(?:\|\(\d+(?:\&\d+)*\))+\))\)/$1/g;
267: # ((5&3)|(4&6))|(1&2)=(5&3)|(4&6)|(1&2)
268: $expression=~
269: s/\((\(\d+(?:\&\d+)*\))((?:\|\(\d+(?:\&\d+)*\))+)\)\|(\(\d+(?:\&\d+)*\))/\($1$2\|$3\)/g;
270: return $expression;
271: }
272:
273: # -------------------------------------------------------- Build condition hash
274:
275: sub traceroute {
276: my ($sofar,$rid,$beenhere)=@_;
277: $sofar=simplify($sofar);
278: unless ($beenhere=~/\&$rid\&/) {
279: $beenhere.=$rid.'&';
280: if ($retfurl eq '') {
281: my ($mapid,$resid)=split(/\./,$rid);
282: $retfurl=$hash{'src_'.$rid}.'?symb='.
283: &Apache::lonnet::symbclean(
284: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
285: '___'.$resid.'___'.
286: &Apache::lonnet::declutter($hash{'src_'.$rid}));
287: }
288: if (defined($hash{'conditions_'.$rid})) {
289: $hash{'conditions_'.$rid}=simplify(
290: '('.$hash{'conditions_'.$rid}.')|('.$sofar.')');
291: } else {
292: $hash{'conditions_'.$rid}=$sofar;
293: }
294: if (defined($hash{'is_map_'.$rid})) {
295: if (defined($hash{'map_start_'.$hash{'src_'.$rid}})) {
296: &traceroute($sofar,$hash{'map_start_'.$hash{'src_'.$rid}},'&');
297: if (defined($hash{'map_finish_'.$hash{'src_'.$rid}})) {
298: $sofar=
299: $hash{'conditions_'.$hash{'map_finish_'.$hash{'src_'.$rid}}};
300: }
301: }
302: }
303: if (defined($hash{'to_'.$rid})) {
304: foreach (split(/\,/,$hash{'to_'.$rid})) {
305: my $further=$sofar;
306: if ($hash{'undercond_'.$_}) {
307: if (defined($hash{'condid_'.$hash{'undercond_'.$_}})) {
308: $further=simplify('('.$further.')&('.
309: $hash{'condid_'.$hash{'undercond_'.$_}}.')');
310: } else {
311: $errtext.='Undefined condition ID: '
312: .$hash{'undercond_'.$_}.'. ';
313: }
314: }
315: &traceroute($further,$hash{'goesto_'.$_},$beenhere);
316: }
317: }
318: }
319: }
320:
321: # ------------------------------ Cascading conditions, quick access, parameters
322:
323: sub accinit {
324: my ($uri,$short,$fn)=@_;
325: my %acchash=();
326: my %captured=();
327: my $condcounter=0;
328: $acchash{'acc.cond.'.$short.'.0'}=0;
329: foreach (keys %hash) {
330: if ($_=~/^conditions/) {
331: my $expr=$hash{$_};
332: foreach ($expr=~m/(\(\(\d+(?:\&\d+)+\)(?:\|\(\d+(?:\&\d+)+\))+\))/g) {
333: my $sub=$_;
334: my $orig=$_;
335: $sub=~/\(\((\d+\&(:?\d+\&)*)(?:\d+\&*)+\)(?:\|\(\1(?:\d+\&*)+\))+\)/;
336: my $factor=$1;
337: $sub=~s/$factor//g;
338: $sub=~s/^\(/\($factor\(/;
339: $sub.=')';
340: $sub=simplify($sub);
341: $orig=~s/(\W)/\\$1/g;
342: $expr=~s/$orig/$sub/;
343: }
344: $hash{$_}=$expr;
345: unless (defined($captured{$expr})) {
346: $condcounter++;
347: $captured{$expr}=$condcounter;
348: $acchash{'acc.cond.'.$short.'.'.$condcounter}=$expr;
349: }
350: } elsif ($_=~/^param_(\d+)\.(\d+)/) {
351: my $prefix=&Apache::lonnet::declutter($hash{'map_id_'.$1}).
352: '___'.$2.'___'.&Apache::lonnet::declutter($hash{'src_'.$1.'.'.$2});
353: foreach (split(/\&/,$hash{$_})) {
354: my ($typename,$value)=split(/\=/,$_);
355: my ($type,$name)=split(/\:/,$typename);
356: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name)}=
357: &Apache::lonnet::unescape($value);
358: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name).'.type'}=
359: &Apache::lonnet::unescape($type);
360: }
361: }
362: }
363: foreach (keys %hash) {
364: if ($_=~/^ids/) {
365: foreach (split(/\,/,$hash{$_})) {
366: my $resid=$_;
367: my $uri=$hash{'src_'.$resid};
368: $uri=~s/^\/adm\/wrapper//;
369: my @uriparts=split(/\//,$uri);
370: my $urifile=$uriparts[$#uriparts];
371: $#uriparts--;
372: my $uripath=join('/',@uriparts);
373: $uripath=~s/^\/res\///;
374: if ($uripath) {
375: my $uricond='0';
376: if (defined($hash{'conditions_'.$resid})) {
377: $uricond=$captured{$hash{'conditions_'.$resid}};
378: }
379: if (defined($acchash{'acc.res.'.$short.'.'.$uripath})) {
380: if ($acchash{'acc.res.'.$short.'.'.$uripath}=~
381: /(\&$urifile\:[^\&]*)/) {
382: my $replace=$1;
383: my $regexp=$replace;
384: $regexp=~s/\|/\\\|/g;
385: $acchash{'acc.res.'.$short.'.'.$uripath}
386: =~s/$regexp/$replace\|$uricond/;
387: } else {
388: $acchash{'acc.res.'.$short.'.'.$uripath}.=
389: $urifile.':'.$uricond.'&';
390: }
391: } else {
392: $acchash{'acc.res.'.$short.'.'.$uripath}=
393: '&'.$urifile.':'.$uricond.'&';
394: }
395: }
396: }
397: }
398: }
399: $acchash{'acc.res.'.$short.'.'}='&:0&';
400: my $courseuri=$uri;
401: $courseuri=~s/^\/res\///;
402: &Apache::lonnet::delenv('(acc\.|httpref\.)');
403: &Apache::lonnet::appenv(%acchash,
404: "request.course.id" => $short,
405: "request.course.fn" => $fn,
406: "request.course.uri" => $courseuri);
407: }
408:
409: # ------------------------------------- Selectively delete from randompick maps
410:
411: sub pickrandom {
412: foreach my $rid (keys %randompick) {
413: my $rndpick=$randompick{$rid};
414: my $mpc=$hash{'map_pc_'.$hash{'src_'.$rid}};
415: # ------------------------------------------- put existing resources into array
416: my @currentrids=();
417: foreach (keys %hash) {
418: if ($_=~/^src_($mpc\.\d+)/) {
419: if ($hash{'src_'.$1}) { push @currentrids, $1; }
420: }
421: }
422: next if ($#currentrids<$rndpick);
423: # -------------------------------- randomly eliminate the ones that should stay
424: srand(&Apache::lonnet::rndseed($rid)); # use rid instead of symb
425: for (my $i=1;$i<=$#currentrids+1-$rndpick;$i++) {
426: while (1) {
427: my $randomidx=int(rand($#currentrids+1));
428: if ($currentrids[$randomidx]) {
429: $currentrids[$randomidx]='';
430: last;
431: }
432: }
433: }
434: # -------------------------------------------------------- delete the leftovers
435: for (my $k=0; $k<=$#currentrids; $k++) {
436: if ($currentrids[$k]) {
437: $hash{'randomout_'.$currentrids[$k]}=1;
438: }
439: }
440: }
441: }
442:
443: # ---------------------------------------------------- Read map and all submaps
444:
445: sub readmap {
446: my $short=shift;
447: $short=~s/^\///;
448: my %cenv=&Apache::lonnet::coursedescription($short);
449: my $fn=$cenv{'fn'};
450: my $uri;
451: $short=~s/\//\_/g;
452: unless ($uri=$cenv{'url'}) {
453: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
454: "Could not load course $short.</font>");
455: return 'No course data available.';
456: }
457: @cond=('true:normal');
458: unlink($fn.'.db');
459: unlink($fn.'_symb.db');
460: unlink($fn.'.state');
461: unlink($fn.'parms.db');
462: undef %randompick;
463: $retfurl='';
464: if ((tie(%hash,'GDBM_File',"$fn.db",&GDBM_WRCREAT,0640)) &&
465: (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_WRCREAT,0640))) {
466: %hash=();
467: %parmhash=();
468: $errtext='';
469: $pc=0;
470: loadmap($uri);
471: if (defined($hash{'map_start_'.$uri})) {
472: &traceroute('0',$hash{'map_start_'.$uri},'&');
473: &accinit($uri,$short,$fn);
474: &pickrandom();
475: }
476: unless ((untie(%hash)) && (untie(%parmhash))) {
477: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
478: "Could not untie coursemap $fn for $uri.</font>");
479: }
480: {
481: my $cfh;
482: if ($cfh=Apache::File->new(">$fn.state")) {
483: print $cfh join("\n",@cond);
484: } else {
485: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
486: "Could not write statemap $fn for $uri.</font>");
487: }
488: }
489: } else {
490: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
491: "Could not tie coursemap $fn for $uri.</font>");
492: }
493: &Apache::lonmsg::author_res_msg($ENV{'request.course.uri'},$errtext);
494: return ($retfurl,$errtext);
495: }
496:
497: # ------------------------------------------------------- Evaluate state string
498:
499: sub evalstate {
500:
501: my $fn=$ENV{'request.course.fn'}.'.state';
502: my $state='2';
503: if (-e $fn) {
504: my @conditions=();
505: {
506: my $fh=Apache::File->new($fn);
507: @conditions=<$fh>;
508: }
509: my $safeeval = new Safe;
510: my $safehole = new Safe::Hole;
511: $safeeval->permit("entereval");
512: $safeeval->permit(":base_math");
513: $safeeval->deny(":base_io");
514: $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
515: foreach (@conditions) {
516: my $line=$_;
517: chomp($line);
518: my ($condition,$weight)=split(/\:/,$_);
519: if ($safeeval->reval($condition)) {
520: if ($weight eq 'force') {
521: $state.='3';
522: } else {
523: $state.='2';
524: }
525: } else {
526: if ($weight eq 'stop') {
527: $state.='0';
528: } else {
529: $state.='1';
530: }
531: }
532: }
533: }
534: &Apache::lonnet::appenv('user.state.'.$ENV{'request.course.id'} => $state);
535: return $state;
536: }
537:
538: 1;
539: __END__
540:
541: =head1 NAME
542:
543: Apache::lonuserstate - Construct and maintain state and binary representation
544: of course for user
545:
546: =head1 SYNOPSIS
547:
548: Invoked by lonroles.pm.
549:
550: &Apache::lonuserstate::readmap($cdom.'/'.$cnum);
551:
552: =head1 INTRODUCTION
553:
554: This module constructs and maintains state and binary representation
555: of course for user.
556:
557: This is part of the LearningOnline Network with CAPA project
558: described at http://www.lon-capa.org.
559:
560: =head1 HANDLER SUBROUTINE
561:
562: There is no handler subroutine.
563:
564: =head1 OTHER SUBROUTINES
565:
566: =over 4
567:
568: =item *
569:
570: loadmap() : Loads map from disk
571:
572: =item *
573:
574: simplify() : Simplify expression
575:
576: =item *
577:
578: traceroute() : Build condition hash
579:
580: =item *
581:
582: accinit() : Cascading conditions, quick access, parameters
583:
584: =item *
585:
586: readmap() : Read map and all submaps
587:
588: =item *
589:
590: evalstate() : Evaluate state string
591:
592: =back
593:
594: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to lonuserstate.pm CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / rat