1: # The LearningOnline Network with CAPA
2: # Construct and maintain state and binary representation of course for user
3: #
4: # $Id: lonuserstate.pm,v 1.75 2004/04/23 19:39:25 www Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: ###
29:
30: package Apache::lonuserstate;
31:
32: # ------------------------------------------------- modules used by this module
33: use strict;
34: use Apache::Constants qw(:common :http);
35: use Apache::File;
36: use HTML::TokeParser;
37: use Apache::lonnet();
38: use Apache::loncommon();
39: use GDBM_File;
40: use Apache::lonmsg;
41: use Safe;
42: use Safe::Hole;
43: use Opcode;
44: use Apache::lonenc;
45:
46: # ---------------------------------------------------- Globals for this package
47:
48: my $pc; # Package counter
49: my %hash; # The big tied hash
50: my %parmhash;# The hash with the parameters
51: my @cond; # Array with all of the conditions
52: my $errtext; # variable with all errors
53: my $retfurl; # variable with the very first URL in the course
54: my %randompick; # randomly picked resources
55: my %randompickseed; # optional seed for randomly picking resources
56: my %encurl; # URLs in this folder are supposed to be encrypted
57: my %hiddenurl; # this URL (or complete folder) is supposed to be hidden
58:
59: # ----------------------------------- Remove version from URL and store in hash
60:
61: sub versiontrack {
62: my $uri=shift;
63: if ($uri=~/\.(\d+)\.\w+$/) {
64: my $version=$1;
65: $uri=~s/\.\d+\.(\w+)$/\.$1/;
66: unless ($hash{'version_'.$uri}) {
67: $hash{'version_'.$uri}=$version;
68: }
69: }
70: return $uri;
71: }
72:
73: # -------------------------------------------------------------- Put in version
74:
75: sub putinversion {
76: my $uri=shift;
77: if ($hash{'version_'.$uri}) {
78: my $version=$hash{'version_'.$uri};
79: if ($version eq 'mostrecent') { return $uri; }
80: if ($version eq &Apache::lonnet::getversion(
81: &Apache::lonnet::filelocation('',$uri)))
82: { return $uri; }
83: $uri=~s/\.(\w+)$/\.$version\.$1/;
84: }
85: return $uri;
86: }
87:
88: # ----------------------------------------- Processing versions file for course
89:
90: sub processversionfile {
91: my %cenv=@_;
92: my %versions=&Apache::lonnet::dump('resourceversions',
93: $cenv{'domain'},
94: $cenv{'num'});
95: foreach (keys %versions) {
96: if ($_=~/^error\:/) { return; }
97: $hash{'version_'.$_}=$versions{$_};
98: }
99: }
100:
101: # --------------------------------------------------------- Loads map from disk
102:
103: sub loadmap {
104: my $uri=shift;
105: if ($hash{'map_pc_'.$uri}) { return OK; }
106:
107: $pc++;
108: my $lpc=$pc;
109: $hash{'map_pc_'.$uri}=$lpc;
110: $hash{'map_id_'.$lpc}=$uri;
111:
112: # Determine and check filename
113: my $fn=&Apache::lonnet::filelocation('',&putinversion($uri));
114:
115: my $ispage=($fn=~/\.page$/);
116:
117: unless (($fn=~/\.sequence$/) ||
118: ($fn=~/\.page$/)) {
119: $errtext.="Invalid map: $fn\n";
120: return OK;
121: }
122:
123: my $instr=&Apache::lonnet::getfile($fn);
124:
125: unless ($instr eq -1) {
126:
127: # Successfully got file, parse it
128:
129: my $parser = HTML::TokeParser->new(\$instr);
130: my $token;
131:
132: my $linkpc=0;
133:
134: $fn=~/\.(\w+)$/;
135:
136: $hash{'map_type_'.$lpc}=$1;
137:
138: while ($token = $parser->get_token) {
139: if ($token->[0] eq 'S') {
140: if ($token->[1] eq 'resource') {
141: # -------------------------------------------------------------------- Resource
142:
143: my $rid=$lpc.'.'.$token->[2]->{'id'};
144:
145: $hash{'kind_'.$rid}='res';
146: $hash{'title_'.$rid}=$token->[2]->{'title'};
147: my $turi=&versiontrack($token->[2]->{'src'});
148: if ($token->[2]->{'version'}) {
149: unless ($hash{'version_'.$turi}) {
150: $hash{'version_'.$turi}=$1;
151: }
152: }
153: &Apache::lonnet::do_cache(\%Apache::lonnet::titlecache,
154: &Apache::lonnet::encode_symb($uri,$token->[2]->{'id'},
155: $turi),
156: $token->[2]->{'title'},'title');
157: unless ($ispage) {
158: $turi=~/\.(\w+)$/;
159: my $embstyle=&Apache::loncommon::fileembstyle($1);
160: if ($token->[2]->{'external'} eq 'true') { # external
161: $turi=~s/^http\:\/\//\/adm\/wrapper\/ext\//;
162: } elsif ($turi=~/^\/*uploaded\//) { # uploaded
163: if (($embstyle eq 'img') || ($embstyle eq 'emb')
164: || ($embstyle eq 'ssi')) {
165: unless ($turi =~/\.page$/) {
166: $turi='/adm/wrapper'.$turi;
167: }
168: } elsif ($turi!~/\.(sequence|page)$/) {
169: $turi='/adm/coursedocs/showdoc'.$turi;
170: }
171: } elsif ($turi=~/\S/) { # normal non-empty internal resource
172: my $mapdir=$uri;
173: $mapdir=~s/[^\/]+$//;
174: $turi=&Apache::lonnet::hreflocation($mapdir,$turi);
175: if (($embstyle eq 'img') || ($embstyle eq 'emb')) {
176: $turi='/adm/wrapper'.$turi;
177: }
178: }
179: }
180: # Store reverse lookup, remove query string
181: my $idsuri=$turi;
182: $idsuri=~s/\?.+$//;
183: if (defined($hash{'ids_'.$idsuri})) {
184: $hash{'ids_'.$idsuri}.=','.$rid;
185: } else {
186: $hash{'ids_'.$idsuri}=''.$rid;
187: }
188:
189: if
190: ($turi=~/\/(syllabus|aboutme|navmaps|smppg|bulletinboard)$/) {
191: $turi.='?register=1';
192: }
193:
194: $hash{'src_'.$rid}=$turi;
195:
196: if ($token->[2]->{'external'} eq 'true') {
197: $hash{'ext_'.$rid}='true:';
198: } else {
199: $hash{'ext_'.$rid}='false:';
200: }
201: if ($token->[2]->{'type'}) {
202: $hash{'type_'.$rid}=$token->[2]->{'type'};
203: if ($token->[2]->{'type'} eq 'start') {
204: $hash{'map_start_'.$uri}="$rid";
205: }
206: if ($token->[2]->{'type'} eq 'finish') {
207: $hash{'map_finish_'.$uri}="$rid";
208: }
209: } else {
210: $hash{'type_'.$rid}='normal';
211: }
212:
213: if (($turi=~/\.sequence$/) ||
214: ($turi=~/\.page$/)) {
215: $hash{'is_map_'.$rid}=1;
216: &loadmap($turi);
217: }
218:
219: } elsif ($token->[1] eq 'condition') {
220: # ------------------------------------------------------------------- Condition
221:
222: my $rid=$lpc.'.'.$token->[2]->{'id'};
223:
224: $hash{'kind_'.$rid}='cond';
225: $cond[$#cond+1]=$token->[2]->{'value'};
226: $hash{'condid_'.$rid}=$#cond;
227: if ($token->[2]->{'type'}) {
228: $cond[$#cond].=':'.$token->[2]->{'type'};
229: } else {
230: $cond[$#cond].=':normal';
231: }
232:
233: } elsif ($token->[1] eq 'link') {
234: # ----------------------------------------------------------------------- Links
235:
236: $linkpc++;
237: my $linkid=$lpc.'.'.$linkpc;
238:
239: my $goesto=$lpc.'.'.$token->[2]->{'to'};
240: my $comesfrom=$lpc.'.'.$token->[2]->{'from'};
241: my $undercond=0;
242:
243: if ($token->[2]->{'condition'}) {
244: $undercond=$lpc.'.'.$token->[2]->{'condition'};
245: }
246:
247: $hash{'goesto_'.$linkid}=$goesto;
248: $hash{'comesfrom_'.$linkid}=$comesfrom;
249: $hash{'undercond_'.$linkid}=$undercond;
250:
251: if (defined($hash{'to_'.$comesfrom})) {
252: $hash{'to_'.$comesfrom}.=','.$linkid;
253: } else {
254: $hash{'to_'.$comesfrom}=''.$linkid;
255: }
256: if (defined($hash{'from_'.$goesto})) {
257: $hash{'from_'.$goesto}.=','.$linkid;
258: } else {
259: $hash{'from_'.$goesto}=''.$linkid;
260: }
261: } elsif ($token->[1] eq 'param') {
262: # ------------------------------------------------------------------- Parameter
263:
264: my $referid=$lpc.'.'.$token->[2]->{'to'};
265: my $name=$token->[2]->{'name'};
266: my $part;
267: if ($name=~/^parameter_(.*)_/) {
268: $part=$1;
269: } else {
270: $part=0;
271: }
272: $name=~s/^.*_([^_]*)$/$1/;
273: my $newparam=
274: &Apache::lonnet::escape($token->[2]->{'type'}).':'.
275: &Apache::lonnet::escape($part.'.'.$name).'='.
276: &Apache::lonnet::escape($token->[2]->{'value'});
277: if (defined($hash{'param_'.$referid})) {
278: $hash{'param_'.$referid}.='&'.$newparam;
279: } else {
280: $hash{'param_'.$referid}=''.$newparam;
281: }
282: if ($token->[2]->{'name'}=~/^parameter_(0_)*mapalias$/) {
283: $hash{'mapalias_'.$token->[2]->{'value'}}=$referid;
284: }
285: if ($token->[2]->{'name'}=~/^parameter_(0_)*randompick$/) {
286: $randompick{$referid}=$token->[2]->{'value'};
287: }
288: if ($token->[2]->{'name'}=~/^parameter_(0_)*randompickseed$/) {
289: $randompick{$referid}=$token->[2]->{'value'};
290: }
291: if ($token->[2]->{'name'}=~/^parameter_(0_)*encrypturl$/) {
292: if ($token->[2]->{'value'}=~/^yes$/i) {
293: $encurl{$referid}=1;
294: }
295: }
296: if ($token->[2]->{'name'}=~/^parameter_(0_)*hiddenresource$/) {
297: if ($token->[2]->{'value'}=~/^yes$/i) {
298: $hiddenurl{$referid}=1;
299: }
300: }
301: }
302:
303: }
304: }
305:
306: } else {
307: $errtext.='Map not loaded: The file does not exist. ';
308: }
309: }
310:
311: # --------------------------------------------------------- Simplify expression
312:
313: sub simplify {
314: my $expression=shift;
315: # (8)=8
316: $expression=~s/\((\d+)\)/$1/g;
317: # 8&8=8
318: $expression=~s/(\D)(\d+)\&\2(\D)/$1$2$3/g;
319: # 8|8=8
320: $expression=~s/(\D)(\d+)\|\2(\D)/$1$2$3/g;
321: # (5&3)&4=5&3&4
322: $expression=~s/\((\d+)((?:\&\d+)+)\)\&(\d+\D)/$1$2\&$3/g;
323: # (((5&3)|(4&6)))=((5&3)|(4&6))
324: $expression=~
325: s/\((\(\(\d+(?:\&\d+)*\)(?:\|\(\d+(?:\&\d+)*\))+\))\)/$1/g;
326: # ((5&3)|(4&6))|(1&2)=(5&3)|(4&6)|(1&2)
327: $expression=~
328: s/\((\(\d+(?:\&\d+)*\))((?:\|\(\d+(?:\&\d+)*\))+)\)\|(\(\d+(?:\&\d+)*\))/\($1$2\|$3\)/g;
329: return $expression;
330: }
331:
332: # -------------------------------------------------------- Build condition hash
333:
334: sub traceroute {
335: my ($sofar,$rid,$beenhere)=@_;
336: $sofar=simplify($sofar);
337: unless ($beenhere=~/\&$rid\&/) {
338: $beenhere.=$rid.'&';
339: if (($retfurl eq '') && ($hash{'src_'.$rid})
340: && ($hash{'src_'.$rid}!~/\.sequence$/)) {
341: my ($mapid,$resid)=split(/\./,$rid);
342: $retfurl=$hash{'src_'.$rid}.
343: (($hash{'src_'.$rid}=~/\?/)?'&':'?').'symb='.
344: &Apache::lonnet::symbclean(
345: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
346: '___'.$resid.'___'.
347: &Apache::lonnet::declutter($hash{'src_'.$rid}));
348: }
349: if (defined($hash{'conditions_'.$rid})) {
350: $hash{'conditions_'.$rid}=simplify(
351: '('.$hash{'conditions_'.$rid}.')|('.$sofar.')');
352: } else {
353: $hash{'conditions_'.$rid}=$sofar;
354: }
355: if (defined($hash{'is_map_'.$rid})) {
356: if (defined($hash{'map_start_'.$hash{'src_'.$rid}})) {
357: &traceroute($sofar,$hash{'map_start_'.$hash{'src_'.$rid}},'&');
358: if (defined($hash{'map_finish_'.$hash{'src_'.$rid}})) {
359: $sofar=
360: $hash{'conditions_'.$hash{'map_finish_'.$hash{'src_'.$rid}}};
361: }
362: }
363: }
364: if (defined($hash{'to_'.$rid})) {
365: foreach (split(/\,/,$hash{'to_'.$rid})) {
366: my $further=$sofar;
367: if ($hash{'undercond_'.$_}) {
368: if (defined($hash{'condid_'.$hash{'undercond_'.$_}})) {
369: $further=simplify('('.$further.')&('.
370: $hash{'condid_'.$hash{'undercond_'.$_}}.')');
371: } else {
372: $errtext.='Undefined condition ID: '
373: .$hash{'undercond_'.$_}.'. ';
374: }
375: }
376: &traceroute($further,$hash{'goesto_'.$_},$beenhere);
377: }
378: }
379: }
380: }
381:
382: # ------------------------------ Cascading conditions, quick access, parameters
383:
384: sub accinit {
385: my ($uri,$short,$fn)=@_;
386: my %acchash=();
387: my %captured=();
388: my $condcounter=0;
389: $acchash{'acc.cond.'.$short.'.0'}=0;
390: foreach (keys %hash) {
391: if ($_=~/^conditions/) {
392: my $expr=$hash{$_};
393: foreach ($expr=~m/(\(\(\d+(?:\&\d+)+\)(?:\|\(\d+(?:\&\d+)+\))+\))/g) {
394: my $sub=$_;
395: my $orig=$_;
396: $sub=~/\(\((\d+\&(:?\d+\&)*)(?:\d+\&*)+\)(?:\|\(\1(?:\d+\&*)+\))+\)/;
397: my $factor=$1;
398: $sub=~s/$factor//g;
399: $sub=~s/^\(/\($factor\(/;
400: $sub.=')';
401: $sub=simplify($sub);
402: $orig=~s/(\W)/\\$1/g;
403: $expr=~s/$orig/$sub/;
404: }
405: $hash{$_}=$expr;
406: unless (defined($captured{$expr})) {
407: $condcounter++;
408: $captured{$expr}=$condcounter;
409: $acchash{'acc.cond.'.$short.'.'.$condcounter}=$expr;
410: }
411: } elsif ($_=~/^param_(\d+)\.(\d+)/) {
412: my $prefix=&Apache::lonnet::declutter($hash{'map_id_'.$1}).
413: '___'.$2.'___'.&Apache::lonnet::declutter($hash{'src_'.$1.'.'.$2});
414: foreach (split(/\&/,$hash{$_})) {
415: my ($typename,$value)=split(/\=/,$_);
416: my ($type,$name)=split(/\:/,$typename);
417: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name)}=
418: &Apache::lonnet::unescape($value);
419: $parmhash{$prefix.'.'.&Apache::lonnet::unescape($name).'.type'}=
420: &Apache::lonnet::unescape($type);
421: }
422: }
423: }
424: foreach (keys %hash) {
425: if ($_=~/^ids/) {
426: foreach (split(/\,/,$hash{$_})) {
427: my $resid=$_;
428: my $uri=$hash{'src_'.$resid};
429: $uri=~s/^\/adm\/wrapper//;
430: $uri=&Apache::lonnet::declutter($uri);
431: my @uriparts=split(/\//,$uri);
432: my $urifile=$uriparts[$#uriparts];
433: $#uriparts--;
434: my $uripath=join('/',@uriparts);
435: if ($uripath) {
436: my $uricond='0';
437: if (defined($hash{'conditions_'.$resid})) {
438: $uricond=$captured{$hash{'conditions_'.$resid}};
439: }
440: if (defined($acchash{'acc.res.'.$short.'.'.$uripath})) {
441: if ($acchash{'acc.res.'.$short.'.'.$uripath}=~
442: /(\&\Q$urifile\E\:[^\&]*)/) {
443: my $replace=$1;
444: my $regexp=$replace;
445: $regexp=~s/\|/\\\|/g;
446: $acchash{'acc.res.'.$short.'.'.$uripath}
447: =~s/$regexp/$replace\|$uricond/;
448: } else {
449: $acchash{'acc.res.'.$short.'.'.$uripath}.=
450: $urifile.':'.$uricond.'&';
451: }
452: } else {
453: $acchash{'acc.res.'.$short.'.'.$uripath}=
454: '&'.$urifile.':'.$uricond.'&';
455: }
456: }
457: }
458: }
459: }
460: $acchash{'acc.res.'.$short.'.'}='&:0&';
461: my $courseuri=$uri;
462: $courseuri=~s/^\/res\///;
463: &Apache::lonnet::delenv('(acc\.|httpref\.)');
464: &Apache::lonnet::appenv(%acchash,
465: "request.course.id" => $short,
466: "request.course.fn" => $fn,
467: "request.course.uri" => $courseuri);
468: }
469:
470: # ---------------- Selectively delete from randompick maps and hidden url parms
471:
472: sub hiddenurls {
473: my $randomoutentry='';
474: foreach my $rid (keys %randompick) {
475: my $rndpick=$randompick{$rid};
476: my $mpc=$hash{'map_pc_'.$hash{'src_'.$rid}};
477: # ------------------------------------------- put existing resources into array
478: my @currentrids=();
479: foreach (sort(keys(%hash))) {
480: if ($_=~/^src_($mpc\.\d+)/) {
481: if ($hash{'src_'.$1}) { push @currentrids, $1; }
482: }
483: }
484: # rids are number.number and we want to numercially sort on
485: # the second number
486: @currentrids=sort {
487: my (undef,$aid)=split(/\./,$a);
488: my (undef,$bid)=split(/\./,$b);
489: $aid <=> $bid;
490: } @currentrids;
491: next if ($#currentrids<$rndpick);
492: # -------------------------------- randomly eliminate the ones that should stay
493: my (undef,$id)=split(/\./,$rid);
494: if ($randompickseed{$rid}) { $id=$randompickseed{$rid}; }
495: my $rndseed=&Apache::lonnet::rndseed($id); # use id instead of symb
496: &Apache::lonnet::setup_random_from_rndseed($rndseed);
497: my @whichids=&Math::Random::random_permuted_index($#currentrids+1);
498: for (my $i=1;$i<=$rndpick;$i++) { $currentrids[$whichids[$i]]=''; }
499: #&Apache::lonnet::logthis("$id,$rndseed,".join(':',@whichids));
500: # -------------------------------------------------------- delete the leftovers
501: for (my $k=0; $k<=$#currentrids; $k++) {
502: if ($currentrids[$k]) {
503: $hash{'randomout_'.$currentrids[$k]}=1;
504: my ($mapid,$resid)=split(/\./,$currentrids[$k]);
505: $randomoutentry.='&'.
506: &Apache::lonnet::symbclean(
507: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
508: '___'.$resid.'___'.
509: &Apache::lonnet::declutter($hash{'src_'.$currentrids[$k]})
510: ).'&';
511: }
512: }
513: }
514: # ------------------------------ take care of explicitly hidden urls or folders
515: foreach my $rid (keys %hiddenurl) {
516: $hash{'randomout_'.$rid}=1;
517: my ($mapid,$resid)=split(/\./,$rid);
518: $randomoutentry.='&'.
519: &Apache::lonnet::symbclean(
520: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
521: '___'.$resid.'___'.
522: &Apache::lonnet::declutter($hash{'src_'.$rid})
523: ).'&';
524: }
525: # --------------------------------------- append randomout entry to environment
526: if ($randomoutentry) {
527: &Apache::lonnet::appenv('acc.randomout' => $randomoutentry);
528: }
529: }
530:
531: # ---------------------------------------------------- Read map and all submaps
532:
533: sub readmap {
534: my $short=shift;
535: $short=~s/^\///;
536: my %cenv=&Apache::lonnet::coursedescription($short);
537: my $fn=$cenv{'fn'};
538: my $uri;
539: $short=~s/\//\_/g;
540: unless ($uri=$cenv{'url'}) {
541: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
542: "Could not load course $short.</font>");
543: return 'No course data available.';
544: }
545: @cond=('true:normal');
546: unlink($fn.'.db');
547: unlink($fn.'_symb.db');
548: unlink($fn.'.state');
549: unlink($fn.'parms.db');
550: undef %randompick;
551: undef %hiddenurl;
552: undef %encurl;
553: $retfurl='';
554: if ((tie(%hash,'GDBM_File',"$fn.db",&GDBM_WRCREAT(),0640)) &&
555: (tie(%parmhash,'GDBM_File',$fn.'_parms.db',&GDBM_WRCREAT(),0640))) {
556: %hash=();
557: %parmhash=();
558: $errtext='';
559: $pc=0;
560: &processversionfile(%cenv);
561: my $furi=&Apache::lonnet::clutter($uri);
562: $hash{'src_0.0'}=&versiontrack($furi);
563: $hash{'title_0.0'}=&Apache::lonnet::metadata($uri,'title');
564: $hash{'ids_'.$furi}='0.0';
565: $hash{'is_map_0.0'}=1;
566: loadmap($uri);
567: if (defined($hash{'map_start_'.$uri})) {
568: &traceroute('0',$hash{'map_start_'.$uri},'&');
569: &accinit($uri,$short,$fn);
570: &hiddenurls();
571: }
572: # ------------------------------------------------------- Put versions into src
573: foreach (keys %hash) {
574: if ($_=~/^src\_/) {
575: $hash{$_}=&putinversion($hash{$_});
576: }
577: }
578: # ---------------------------------------------------------------- Encrypt URLs
579: foreach (keys %encurl) {
580: $hash{'src_'.$_}=&Apache::lonenc::encrypted($hash{'src_'.$_});
581: }
582: # ----------------------------------------------- Close hashes to finally store
583: # --------------------------------- Routine must pass this point, no early outs
584: unless ((untie(%hash)) && (untie(%parmhash))) {
585: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
586: "Could not untie coursemap $fn for $uri.</font>");
587: }
588: # ---------------------------------------------------- Store away initial state
589: {
590: my $cfh;
591: if ($cfh=Apache::File->new(">$fn.state")) {
592: print $cfh join("\n",@cond);
593: } else {
594: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
595: "Could not write statemap $fn for $uri.</font>");
596: }
597: }
598: } else {
599: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
600: "Could not tie coursemap $fn for $uri.</font>");
601: }
602: &Apache::lonmsg::author_res_msg($ENV{'request.course.uri'},$errtext);
603: # ------------------------------------------------- Check for critical messages
604:
605: my @what=&Apache::lonnet::dump('critical',$ENV{'user.domain'},
606: $ENV{'user.name'});
607: if ($what[0]) {
608: if (($what[0] ne 'con_lost') && ($what[0]!~/^error\:/)) {
609: $retfurl='/adm/email?critical=display';
610: }
611: }
612: return ($retfurl,$errtext);
613: }
614:
615: # ------------------------------------------------------- Evaluate state string
616:
617: sub evalstate {
618:
619: my $fn=$ENV{'request.course.fn'}.'.state';
620: my $state='2';
621: if (-e $fn) {
622: my @conditions=();
623: {
624: my $fh=Apache::File->new($fn);
625: @conditions=<$fh>;
626: }
627: my $safeeval = new Safe;
628: my $safehole = new Safe::Hole;
629: $safeeval->permit("entereval");
630: $safeeval->permit(":base_math");
631: $safeeval->deny(":base_io");
632: $safehole->wrap(\&Apache::lonnet::EXT,$safeeval,'&EXT');
633: foreach (@conditions) {
634: my $line=$_;
635: chomp($line);
636: my ($condition,$weight)=split(/\:/,$_);
637: if ($safeeval->reval($condition)) {
638: if ($weight eq 'force') {
639: $state.='3';
640: } else {
641: $state.='2';
642: }
643: } else {
644: if ($weight eq 'stop') {
645: $state.='0';
646: } else {
647: $state.='1';
648: }
649: }
650: }
651: }
652: &Apache::lonnet::appenv('user.state.'.$ENV{'request.course.id'} => $state);
653: return $state;
654: }
655:
656: 1;
657: __END__
658:
659: =head1 NAME
660:
661: Apache::lonuserstate - Construct and maintain state and binary representation
662: of course for user
663:
664: =head1 SYNOPSIS
665:
666: Invoked by lonroles.pm.
667:
668: &Apache::lonuserstate::readmap($cdom.'/'.$cnum);
669:
670: =head1 INTRODUCTION
671:
672: This module constructs and maintains state and binary representation
673: of course for user.
674:
675: This is part of the LearningOnline Network with CAPA project
676: described at http://www.lon-capa.org.
677:
678: =head1 HANDLER SUBROUTINE
679:
680: There is no handler subroutine.
681:
682: =head1 OTHER SUBROUTINES
683:
684: =over 4
685:
686: =item *
687:
688: loadmap() : Loads map from disk
689:
690: =item *
691:
692: simplify() : Simplify expression
693:
694: =item *
695:
696: traceroute() : Build condition hash
697:
698: =item *
699:
700: accinit() : Cascading conditions, quick access, parameters
701:
702: =item *
703:
704: readmap() : Read map and all submaps
705:
706: =item *
707:
708: evalstate() : Evaluate state string
709:
710: =back
711:
712: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>