1: # The LearningOnline Network with CAPA
2: # Edit Handler for RAT Maps
3: #
4: # $Id: lonratedt.pm,v 1.107 2012/12/16 16:10:25 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29:
30: package Apache::lonratedt;
31:
32: use strict;
33: use Apache::Constants qw(:common);
34: use Apache::lonnet;
35: use Apache::lonsequence();
36: use Apache::loncommon();
37: use Apache::lonlocal;
38: use LONCAPA::map();
39: use File::Copy;
40: use LONCAPA;
41: use HTML::Entities();
42:
43: # --------------------------------------------------------- Build up RAT screen
44: sub ratedt {
45: my ($r,$url)=@_;
46: my %layout = ('border' => "0",
47: 'rows' => "1,250,*");
48: my $js ='
49: <script type="text/javascript">
50: var flag=0;
51: </script>';
52:
53: my $start_page =
54: &Apache::loncommon::start_page('Edit Sequence',$js,
55: {'frameset' => 1,
56: 'add_entries' => \%layout});
57:
58: my $end_page =
59: &Apache::loncommon::end_page({'frameset' => 1});
60:
61: $r->print(<<ENDDOCUMENT);
62: $start_page
63: <frame name="server" src="$url/loadonly/ratserver" noresize="noresize"
64: noscroll="noscroll" />
65: <frame name="code" src="$url/loadonly/adveditmenu" />
66: <frame name="mapout" src="/adm/rat/map.html" />
67: $end_page
68: ENDDOCUMENT
69: }
70:
71: # ---------------------------------------------------------------- Make buttons
72:
73: sub buttons {
74: my $adv=shift;
75: my $output='<form method="post" action="">';
76: if ($adv==1) {
77: $output.=
78: '<input type="submit" name="forceadv"'
79: .' value="'.&mt('Edit').'" />'
80: .&Apache::loncommon::help_open_topic(
81: 'Sequence_Advanced_Editor_Creation');
82: } else {
83: unless ($adv==2) {
84: $output.=
85: '<input type="submit" name="forcesmp"'
86: .' value="'.&mt('Simple Edit').'" />'
87: .&Apache::loncommon::help_open_topic(
88: 'Sequence_Simple_Editor_Creation')
89: .' ';
90: }
91: $output.=
92: '<input type="submit" name="forceadv"'
93: .' value="'.&mt('Advanced Edit').'" />'
94: .&Apache::loncommon::help_open_topic(
95: 'Sequence_Advanced_Editor_Creation');
96: }
97: return $output.'</form>';
98: }
99:
100: # ----------------------------------------------------------------- Edit script
101: sub editscript {
102: my $mode=shift;
103: my $resurl=
104: &Apache::loncommon::escape_single(&Apache::loncommon::lastresurl());
105: return(<<ENDSCRIPT);
106: var srch;
107: var srchflag=-1; // 1 means currently open
108: // 0 means closed (but has been open)
109: // -1 means never yet opened/defined
110: var srchmode='';
111:
112: var idx;
113: var idxflag=-1; // 1 means currently open
114: // 0 means closed (but has been open)
115: // -1 means never yet opened/defined
116: var idxmode='';
117:
118: // ------------------------------------------------------ Clears indexer window
119: function idxclear() {
120: idx.document.clear();
121: }
122:
123: // ------------------------------------------------------- Clears search window
124: function srchclear() {
125: srch.document.clear();
126: }
127:
128: // ------------------------------------------------------ Closes indexer window
129: function idxclose() {
130: if (idx && !idx.closed) {
131: idxflag=0;
132: idx.close();
133: }
134: }
135:
136: // ------------------------------------------------------- Closes search window
137: function srchclose() {
138: if (srch && !srch.closed) {
139: srchflag=0;
140: srch.close();
141: }
142: }
143:
144: // -------------------------------------------------------- Open indexer window
145: function idxopen(mode) {
146: var options="scrollbars=1,resizable=1,menubar=0,location=1,toolbar=1";
147: idxmode=mode;
148: idxflag=1;
149: idx=open('$resurl/?inhibitmenu=yes&launch=1&mode=$mode&catalogmode='+mode,'idxout',options);
150: idx.focus();
151: }
152:
153: // ------------------------------------------------------ Open groupsort window
154: function groupopen(url,recover) {
155: var options="scrollbars=1,resizable=1,menubar=0";
156: idxflag=1;
157: idx=open("/adm/groupsort?inhibitmenu=yes&mode=$mode&recover="+recover+"&readfile="+url,"idxout",options);
158: idx.focus();
159: }
160:
161: // --------------------------------------------------------- Open search window
162: function srchopen(mode) {
163: var options="scrollbars=1,resizable=1,menubar=0";
164: srchmode=mode;
165: srchflag=1;
166: srch=open("/adm/searchcat?inhibitmenu=yes&launch=1&mode=$mode&catalogmode="+mode,"srchout",options);
167: srch.focus();
168: }
169: // ----------------------------------------------------- launch indexer browser
170: function groupsearch() {
171: srchcheck('import');
172: }
173:
174: function groupimport() {
175: idxcheck('import');
176: }
177:
178: // ------------------------------------------------------- Do srch status check
179: function srchcheck(mode) {
180: if (!srch || srch.closed || srchmode!=mode) {
181: srchopen(mode);
182: }
183: srch.focus();
184: }
185:
186: // -------------------------------------------------------- Do idx status check
187: function idxcheck(mode) {
188: if (!idx || idx.closed || idxmode!=mode) {
189: idxopen(mode);
190: }
191: idx.focus();
192: }
193:
194:
195: var editbrowser;
196: function openbrowser(formname,elementname,only,omit) {
197: var url = '$resurl/?';
198: if (editbrowser == null) {
199: url += 'launch=1&';
200: }
201: url += 'inhibitmenu=yes&';
202: url += 'catalogmode=interactive&';
203: url += 'mode=edit&';
204: url += 'form=' + formname + '&';
205: if (only != null) {
206: url += 'only=' + only + '&';
207: }
208: if (omit != null) {
209: url += 'omit=' + omit + '&';
210: }
211: url += 'element=' + elementname + '';
212: var title = 'Browser';
213: var options = 'scrollbars=1,resizable=1,menubar=0,toolbar=1,location=1';
214: options += ',width=700,height=600';
215: editbrowser = open(url,title,options,'1');
216: editbrowser.focus();
217: }
218: ENDSCRIPT
219: }
220: # ------------------------------------------------------- Simple edit processor
221:
222: sub smpedt {
223: my ($r,$url,$errtext)=@_;
224: my $tmpfn=&Apache::lonnet::filelocation('',$url).'.tmp';
225: my $targetmsg='';
226: if ($env{'form.save'}) {
227: copy($tmpfn,&Apache::lonnet::filelocation('',$url));
228: unlink($tmpfn);
229: my ($errtext,$fatal)=
230: &LONCAPA::map::mapread(&Apache::lonnet::filelocation('',$url),'');
231: unless ($fatal) {
232: $targetmsg='<b>'.&mt('Saved.').'</b><br />';
233: } else {
234: $targetmsg='<b>'.&mt('An error occurred while saving.').'</b><br />';
235: }
236: }
237: if ($env{'form.revert'}) {
238: $targetmsg='<b>'.&mt('Reverted.').'</b><br />';
239: unlink($tmpfn);
240: my ($errtext,$fatal)=
241: &LONCAPA::map::mapread(&Apache::lonnet::filelocation('',$url),'');
242: }
243: if (-e $tmpfn) {
244: $targetmsg=
245: '<span class="LC_warning">'.&mt('You are working with an unsaved version of your map.').'</span><br />';
246: my ($errtext,$fatal)=&LONCAPA::map::mapread($tmpfn,'');
247: }
248: # ---------------------------------------------------------- Process form input
249:
250: my @importselect=&Apache::loncommon::get_env_multiple('form.importsel');
251: my @targetselect=&Apache::loncommon::get_env_multiple('form.target');
252: # ============================================================ Process commands
253:
254: my $targetdetail=$env{'form.targetdetail'};
255: my $importdetail=$env{'form.curimpdetail'};
256:
257: # ---------------------------------------------------- Importing from groupsort
258: if (($env{'form.importdetail'}) && (!$env{'form.impfortarget'})) {
259:
260: $importdetail='';
261: my @curimport=split(/\&/,$env{'form.curimpdetail'});
262:
263: my $lastsel;
264:
265: if (defined($importselect[-1])) {
266: $lastsel=$importselect[-1];
267: } else {
268: $lastsel=$#curimport;
269: }
270:
271: for (my $i=0;$i<=$lastsel;$i++) {
272: my ($name,$url)=split(/\=/,$curimport[$i]);
273: if ($url) {
274: $importdetail.='&'.$name.'='.$url;
275: }
276: }
277:
278: $importdetail.='&'.$env{'form.importdetail'};
279:
280: for (my $i=$lastsel+1;$i<=$#curimport;$i++) {
281: my ($name,$url)=split(/\=/,$curimport[$i]);
282: if ($url) {
283: $importdetail.='&'.$name.'='.$url;
284: }
285: }
286: $importdetail=~s/\&+/\&/g;
287: $importdetail=~s/^\&//;
288:
289: # ------------------------------------------------------------------- Clear all
290: } elsif ($env{'form.clear'}) {
291: $importdetail='';
292: # ------------------------------------------------------------ Discard selected
293: } elsif ($env{'form.discard'}) {
294: $importdetail='';
295: my @curimport=split(/\&/,$env{'form.curimpdetail'});
296: foreach (@importselect) {
297: $curimport[$_]='';
298: }
299: for (my $i=0;$i<=$#curimport;$i++) {
300: my ($name,$url)=split(/\=/,$curimport[$i]);
301: if ($url) {
302: $importdetail.='&'.$name.'='.$url;
303: }
304: }
305: # --------------------------------------------------------- Loading another map
306: } elsif ($env{'form.loadmap'}) {
307: $importdetail='';
308: my @curimport=split(/\&/,$env{'form.curimpdetail'});
309:
310: my $lastsel;
311:
312: if (defined($importselect[-1])) {
313: $lastsel=$importselect[-1];
314: } else {
315: $lastsel=$#curimport;
316: }
317:
318: for (my $i=0;$i<=$lastsel;$i++) {
319: my ($name,$url)=split(/\=/,$curimport[$i]);
320: if ($url) {
321: $importdetail.='&'.$name.'='.$url;
322: }
323: }
324:
325: foreach (
326: &Apache::lonsequence::attemptread(&Apache::lonnet::filelocation('',$env{'form.importmap'}))) {
327: my ($name,$url)=split(/\:/,$_);
328: if ($url) {
329: $importdetail.='&'.&escape($name).'='.
330: &escape($url);
331: }
332: }
333:
334: for (my $i=$lastsel+1;$i<=$#curimport;$i++) {
335: my ($name,$url)=split(/\=/,$curimport[$i]);
336: if ($url) {
337: $importdetail.='&'.$name.'='.$url;
338: }
339: }
340: $importdetail=~s/\&+/\&/g;
341: $importdetail=~s/^\&//;
342:
343: # ------------------------------------------------ Groupimport/search to target
344: } elsif ($env{'form.importdetail'}) {
345: my $lastsel;
346: if (defined($targetselect[-1])) {
347: $lastsel=$targetselect[-1];
348: } else {
349: $lastsel=$#LONCAPA::map::order+1;
350: }
351: &LONCAPA::map::pastetarget($lastsel,split(/\&/,$env{'form.importdetail'}));
352: &LONCAPA::map::storemap(&Apache::lonnet::filelocation('',$url));
353: # ------------------------------------------------------------------------- Cut
354: } elsif (($env{'form.cut'}) || ($env{'form.copy'})) {
355: $importdetail='';
356: my @curimport=split(/\&/,$env{'form.curimpdetail'});
357:
358: my $lastsel;
359:
360: if (defined($importselect[-1])) {
361: $lastsel=$importselect[-1];
362: } else {
363: $lastsel=$#curimport;
364: }
365:
366: for (my $i=0;$i<=$lastsel;$i++) {
367: my ($name,$url)=split(/\=/,$curimport[$i]);
368: if ($url) {
369: $importdetail.='&'.$name.'='.$url;
370: }
371: }
372:
373: foreach (@targetselect) {
374: my ($name,$url)=split(/\:/,$LONCAPA::map::resources[$LONCAPA::map::order[$_-1]]);
375: if ($url) {
376: $importdetail.='&'.&escape($name).'='.
377: &escape($url);
378: }
379: }
380:
381: for (my $i=$lastsel+1;$i<=$#curimport;$i++) {
382: my ($name,$url)=split(/\=/,$curimport[$i]);
383: if ($url) {
384: $importdetail.='&'.$name.'='.$url;
385: }
386: }
387: $importdetail=~s/\&+/\&/g;
388: $importdetail=~s/^\&//;
389:
390: if ($env{'form.cut'}) {
391: my @neworder=();
392: for (my $i=0;$i<=$#LONCAPA::map::order;$i++) {
393: my $include=1;
394: foreach (@targetselect) {
395: if ($_-1==$i) { $include=0; }
396: }
397: if ($include) {
398: $neworder[$#neworder+1]=$LONCAPA::map::order[$i];
399: } else {
400: &LONCAPA::map::makezombie($LONCAPA::map::order[$i]);
401: }
402: }
403: @LONCAPA::map::order=@neworder;
404: &LONCAPA::map::storemap(&Apache::lonnet::filelocation('',$url));
405: }
406:
407: # ----------------------------------------------------------------------- Paste
408: } elsif ($env{'form.paste'}) {
409: my $lastsel;
410: if (defined($targetselect[-1])) {
411: $lastsel=$targetselect[-1];
412: } else {
413: $lastsel=$#LONCAPA::map::order+1;
414: }
415: my @newsequence;
416: my @curimport=split(/\&/,$env{'form.curimpdetail'});
417: foreach (@importselect) {
418: $newsequence[$#newsequence+1]=$curimport[$_];
419: }
420: &LONCAPA::map::pastetarget($lastsel,@newsequence);
421: &LONCAPA::map::storemap(&Apache::lonnet::filelocation('',$url));
422: # -------------------------------------------------------------------- Move up
423: } elsif ($env{'form.moveup'}) {
424: foreach (sort @targetselect) {
425: if ($_-1>0) {
426: my $movethis=$LONCAPA::map::order[$_-1];
427: $LONCAPA::map::order[$_-1]=$LONCAPA::map::order[$_-2];
428: $LONCAPA::map::order[$_-2]=$movethis;
429: }
430: }
431: &LONCAPA::map::storemap(&Apache::lonnet::filelocation('',$url));
432: # ------------------------------------------------------------------ Move down
433: } elsif ($env{'form.movedown'}) {
434: foreach (reverse sort @targetselect) {
435: if ($_-1<$#LONCAPA::map::order) {
436: my $movethis=$LONCAPA::map::order[$_-1];
437: $LONCAPA::map::order[$_-1]=$LONCAPA::map::order[$_];
438: $LONCAPA::map::order[$_]=$movethis;
439: }
440: }
441: &LONCAPA::map::storemap(&Apache::lonnet::filelocation('',$url));
442: # --------------------------------------------------------------------- Rename
443: } elsif ($env{'form.renameres'}) {
444: my $residx=$LONCAPA::map::order[$env{'form.renameidx'}-1];
445: my ($name,@resrest)=split(/\:/,$LONCAPA::map::resources[$residx]);
446: $name=$env{'form.renametitle'};
447: $name=~s/\:/\&colon\;/g;
448: $LONCAPA::map::resources[$residx]=$name.':'.join(':',@resrest);
449: &LONCAPA::map::storemap(&Apache::lonnet::filelocation('',$url));
450: }
451: # ------------------------------------------------------------ Assemble windows
452:
453: my $idx=-1;
454: $importdetail='&'.$importdetail;
455: $importdetail=~s/^\&+/\&/;
456: my $importwindow=
457: '<option value="-1"> ---- '.&mt('Import and Paste Area').' ---- </option>'.
458: join("\n",map {
459: $idx++;
460: if ($_) {
461: my ($name,$url)=split(/\=/,$_);
462: unless ($name) { $name=(split(/\//,$url))[-1]; }
463: unless ($name) { $name='EMPTY'; }
464: '<option value="'.$idx.'">'.&unescape($name).
465: '</option>';
466: }
467: } split(/\&/,$importdetail));
468:
469: $idx=0;
470: $targetdetail='';
471: my $targetwindow=
472: '<option value="0"> ------- '.&mt('Target Edit Map').' ------- </option>'.
473: join("\n",map {
474: my ($name,$url)=split(/\:/,$LONCAPA::map::resources[$_]);
475: unless ($name) { $name=(split(/\//,$url))[-1]; }
476: unless ($name) { $name='EMPTY'; }
477: $name = &LONCAPA::map::qtescape($name);
478: $url = &LONCAPA::map::qtescape($url);
479: $targetdetail.='&'.&escape($name).'='.
480: &escape($url);
481: $idx++;
482: $name = &HTML::Entities::encode($name,'\'"<>&');
483: '<option value="'.$idx.'">'.$name.'</option>';
484: } @LONCAPA::map::order);
485:
486: # ----------------------------------------------------- Start simple RAT screen
487: my $editscript=&editscript('simple');
488:
489: my %lt=&Apache::lonlocal::texthash(
490: 'sa' => 'Save',
491: 'nt' => 'New Title',
492: 'se' => 'Search',
493: 'im' => 'Import',
494: 'wl' => 'Import from Stored Links',
495: 'vi' => 'View',
496: 'lm' => 'Load Map',
497: 'ds' => 'Discard Selected',
498: 'ca' => 'Clear All',
499: 'ta' => 'Temporary Assembly Workspace',
500: 'rv' => 'Revert to Last Saved',
501: 'sa' => 'Save',
502: 'mu' => 'Move Up',
503: 'md' => 'Move Down',
504: 're' => 'Rename',
505: 'as' => 'after selected',
506: 'cs' => 'Cut selected',
507: 'ps' => 'Copy selected',
508: 'pas' => 'Paste after selected',
509: 'reco' => 'Recover Deleted'
510: );
511: my $js=<<ENDJS;
512: <script type="text/javascript">
513:
514: $editscript
515:
516: function openview(entry) {
517: var url=unescape((entry.split('='))[1]);
518: var parts=new Array;
519: if (url) { open(url,'cat'); }
520: }
521:
522: function viewtarget() {
523: openview((document.forms.simpleedit.targetdetail.value.split('&'))
524: [document.forms.simpleedit.target.selectedIndex]);
525: }
526:
527: function viewimport() {
528: openview((document.forms.simpleedit.curimpdetail.value.split('&'))
529: [document.forms.simpleedit.importsel.selectedIndex]);
530: }
531:
532: function renametarget() {
533: var selidx=document.forms.simpleedit.target.selectedIndex;
534: var entry=(document.forms.simpleedit.targetdetail.value.split('&'))
535: [selidx];
536: var oldname=unescape((entry.split('='))[0]);
537: newtitle=prompt('$lt{'nt'}',oldname);
538: if (newtitle) {
539: document.forms.simpleedit.renameres.value=1;
540: document.forms.simpleedit.renameidx.value=selidx;
541: document.forms.simpleedit.renametitle.value=newtitle;
542: document.forms.simpleedit.submit();
543: }
544: }
545:
546: </script>
547: ENDJS
548:
549: &Apache::lonhtmlcommon::clear_breadcrumbs();
550: &Apache::lonhtmlcommon::add_breadcrumb({
551: text => 'Construction Space',
552: href => &Apache::loncommon::authorspace($url),
553: faq => 6,
554: bug => 'RAT',
555: help => 'Sequence_Simple_Editor_Creation',});
556: &Apache::lonhtmlcommon::add_breadcrumb({
557: text => 'RAT',
558: title => 'Resource Assembly Tool',
559: href => '',});
560: &Apache::lonhtmlcommon::add_breadcrumb({
561: text => 'Editor',
562: title => 'Simple Editor',
563: href => '',});
564:
565: # Breadcrumbs are included by &start_page
566: my $start_page = &Apache::loncommon::start_page('Construction Space',$js)
567: .&Apache::loncommon::head_subbox(
568: &Apache::loncommon::CSTR_pageheader()
569: .&buttons(2));
570: my $end_page = &Apache::loncommon::end_page();
571:
572: $r->print(<<ENDSMPHEAD);
573: $start_page
574: <span class="LC_error">$errtext</span>
575: <form name="simpleedit" method="post" action="">
576: <input type="hidden" name="forcesmp" value="1" />
577: <input type="hidden" name="renameres" value="0" />
578: <input type="hidden" name="renametitle" value="" />
579: <input type="hidden" name="renameidx" value="0" />
580: <table>
581: <tr><th width="40%">$lt{'ta'}</th>
582: <th> </th>
583: <th width="40%">File: $url</th></tr>
584: <tr><td bgcolor="#FFFFCC">
585: <input type="button" onclick="javascript:groupsearch()" value="$lt{'se'}" />
586: <input type="button" onclick="javascript:groupimport();" value="$lt{'im'}" />
587: $lt{'as'}
588: <hr />
589: <input type="text" size="20" name="importmap" />
590: <input type="button"
591: onclick="javascript:openbrowser('simpleedit','importmap','sequence,page','')"
592: value="Select Map" /><input type="submit" name="loadmap" value="$lt{'lm'}" /><hr />
593: <input type="submit" name="discard" value="$lt{'ds'}" />
594: <input type="submit" name="clear" value="$lt{'ca'}" />
595: <input type="button" onclick="javascript:viewimport()" value="$lt{'vi'}" />
596:
597: </td><td> </td><td bgcolor="#FFFFCC">
598:
599: <input type="button" onclick=
600: "javascript:impfortarget.value=1;groupsearch()" value="$lt{'se'}" />
601: <input type="button" onclick=
602: "javascript:impfortarget.value=1;groupimport();" value="$lt{'im'}" />
603: <input type="button" onclick=
604: "javascript:impfortarget.value=1;open_StoredLinks_Import('simple');" value="$lt{'wl'}" />
605: <input type="button" onclick=
606: "javascript:impfortarget.value=1;groupopen('$url',1);" value="$lt{'reco'}" />
607: $lt{'as'}
608: <hr />
609: <input type="submit" name="moveup" value="$lt{'mu'}" />
610: <input type="submit" name="movedown" value="$lt{'md'}" />
611: <input type="button" onclick="javascript:renametarget()" value="$lt{'re'}" />
612: <hr />$targetmsg
613: <input type="submit" name="revert" value="$lt{'rv'}" />
614: <input type="submit" name="save" value="$lt{'sa'}" />
615: <input type="button" onclick="javascript:viewtarget()" value="$lt{'vi'}" />
616: </td></tr>
617:
618: <tr><td bgcolor="#FFFFCC"><select name="importsel" size="10" multiple="multiple">
619: $importwindow
620: </select>
621: </td>
622: <td bgcolor="#FFFFAA" align="center">
623: $lt{'cs'}<br />
624: <input type="submit" name="cut" value="<<<" /><p>
625: <hr />
626: $lt{'ps'}<br />
627: <input type="submit" name="copy" value="<--" /><p>
628: <h /r>
629: $lt{'pas'}<br />
630: <input type="submit" name="paste" value="-->" />
631: </td>
632: <td bgcolor="#FFFFCC"><select name="target" size="10" multiple="multiple">
633: $targetwindow
634: </select>
635: </table>
636: <input type="hidden" name="importdetail" value="" />
637: <input type="hidden" name="curimpdetail" value="$importdetail" />
638: <input type="hidden" name="targetdetail" value="$targetdetail" />
639: <input type="hidden" name="impfortarget" value="0" />
640: </form>
641: $end_page
642: ENDSMPHEAD
643: }
644:
645: # ----------------------------------------------------------------- No such dir
646: sub nodir {
647: my ($r,$dir)=@_;
648: my $londocroot = $r->dir_config('lonDocRoot');
649: my ($path) = ($dir =~ m{^\Q$londocroot\E?(/priv/[^/]+/[^/]+/)});
650: $dir=~s{^\Q$londocroot/priv/\E[^/]+/[^/]+}{};
651: my $brcrum = [{'href' => &Apache::loncommon::authorspace($path),
652: 'text' => 'Construction Space'}];
653: # {'href' => '',
654: # 'text' => 'No such directory'}];
655: $r->print(&Apache::loncommon::start_page('Construction Space',
656: undef,
657: {'bread_crumbs' => $brcrum,})
658: .&Apache::loncommon::head_subbox(
659: &Apache::loncommon::CSTR_pageheader())
660: .'<p class="LC_error">'
661: .&mt('No such directory: [_1]','<span class="LC_filename">'.$dir.'</span>'
662: .'</p>'
663: .&Apache::loncommon::end_page())
664: );
665: }
666:
667: # ---------------------------------------------------------------- View Handler
668:
669: sub viewmap {
670: my ($r,$url,$adv,$errtext)=@_;
671:
672: &Apache::lonhtmlcommon::clear_breadcrumbs();
673: &Apache::lonhtmlcommon::add_breadcrumb({
674: text => 'Construction Space',
675: href => &Apache::loncommon::authorspace($url),
676: faq => 6,
677: bug => 'RAT',
678: help => 'Sequence_Simple_Editor_Creation',});
679: &Apache::lonhtmlcommon::add_breadcrumb({
680: text => 'RAT',
681: title => 'Resource Assembly Tool',
682: href => '',});
683:
684: # Breadcrumbs are included by &start_page
685: $r->print(&Apache::loncommon::start_page('Edit Content of a Map')
686: .&Apache::loncommon::head_subbox(
687: &Apache::loncommon::CSTR_pageheader()
688: .&buttons($adv))
689: );
690: if ($errtext) {
691: $r->print('<div class="LC_error">'
692: .$errtext
693: .'</div>'
694: .'<hr />'
695: );
696: }
697: my $idx=0;
698: $r->print('<p><span class="LC_filename">'.$url.'</span></p>');
699: if ($adv) {
700: $r->print('<p class="LC_warning">'
701: .&mt('Map contents are not shown in order.')
702: .'</p><br />'
703: );
704: }
705: $r->print(&Apache::loncommon::start_data_table()
706: .&Apache::loncommon::start_data_table_header_row()
707: .'<th>'.&mt('Type').'</th>'
708: .'<th>'.&mt('Title in map').'</th>'
709: .'<th>'.&mt('Filename of resource').'</th>'
710: .'<th>'.&mt('Link to published resource').'</th>'
711: .'<th>'.&mt('Link to resource in Construction Space').'</th>'
712: .&Apache::loncommon::end_data_table_header_row()
713: );
714: foreach (&LONCAPA::map::attemptread(&Apache::lonnet::filelocation('',$url))) {
715: if (defined($_)) {
716: $idx++;
717: my ($title,$url,$cond)=split(/\:/,$_);
718: if ($cond eq 'cond') { next; }
719: $title= &LONCAPA::map::qtescape($title);
720: $url = &LONCAPA::map::qtescape($url);
721: unless ($title) { $title=(split(/\//,$url))[-1] };
722: unless ($title) { $title='<i>'.&mt('Empty').'</i>'; }
723: my $resurl = $url;
724: my $resfilepath = $Apache::lonnet::perlvar{'lonDocRoot'}.$resurl;
725: my $filename;
726: if ($resurl =~ m#/([^/]+)$#) {
727: $filename = $1;
728: }
729: my $cstrurl = $resurl;
730: $cstrurl =~ s{^/res/}{/priv/};
731: $r->print(&Apache::loncommon::start_data_table_row()
732: .'<td>'
733: .'<img src="'.&Apache::loncommon::icon($resfilepath).'" alt="" />'
734: .'</td>'
735: .'<td>'
736: .&HTML::Entities::encode(&LONCAPA::map::qtescape($title))
737: .'</td>'
738: .'<td>'.$filename.'</td>'
739: .'<td>'
740: );
741: if ($url) {
742: $r->print('<a href="'.$resurl.'">'.&mt('Resource space').'</a>');
743: } else {
744: $r->print(' ');
745: }
746: $r->print('</td><td>');
747: if ($url) {
748: $r->print('<a href="'.$cstrurl.'">'.
749: &mt('Construction space').'</a>');
750: } else {
751: $r->print(' ');
752: }
753: $r->print('</td>'
754: .&Apache::loncommon::end_data_table_row()
755: );
756: }
757: }
758: $r->print(&Apache::loncommon::end_data_table());
759: $r->print(&Apache::loncommon::end_page());
760: }
761:
762: # ================================================================ Main Handler
763:
764: sub handler {
765: my $r=shift;
766: &Apache::loncommon::content_type($r,'text/html');
767: $r->send_http_header;
768:
769: return OK if $r->header_only;
770: my $target = $env{'form.grade_target'};
771: if ($target eq 'meta') {
772: &Apache::loncommon::content_type($r,'text/html');
773: $r->send_http_header;
774: return OK;
775: }
776:
777: my $url=$r->uri;
778: my $fn=&Apache::lonnet::filelocation('',$url);
779:
780: my ($dir)=($fn=~/^(.+)\/[^\/]+$/);
781: unless (-e $dir) {
782: &nodir($r,$dir);
783: return OK;
784: }
785:
786: # ------------------------------------------- Determine which tools can be used
787: my $adv=0;
788:
789: unless ($env{'form.forcesmp'}) {
790: if ($env{'form.forceadv'}) {
791: $adv=1;
792: } elsif (my $fh=Apache::File->new($fn)) {
793: my $allmap=join('',<$fh>);
794: $adv=($allmap=~/\<map[^\>]+mode\s*\=\s*(\'|\")rat/is);
795: }
796: }
797:
798: my $errtext='';
799: my $fatal=0;
800:
801: # -------------------------------------------------------------------- Load map
802: ($errtext,$fatal)=&LONCAPA::map::mapread($fn,$errtext);
803:
804: if ($fatal==1) { $adv=1; }
805:
806: # ----------------------------------- adv==1 now means "graphical MUST be used"
807:
808: if ($env{'form.forceadv'}) {
809: &ratedt($r,$url);
810: } elsif ($env{'form.forcesmp'}) {
811: &smpedt($r,$url,$errtext);
812: } else {
813: &viewmap($r,$url,$adv,$errtext);
814: }
815: return OK;
816: }
817:
818: 1;
819: __END__
820:
821:
822:
823: =pod
824:
825: =head1 NAME
826:
827: Apache::lonratedt: simple resource assembly tool
828:
829: =head1 SYNOPSIS
830:
831: lonratedt provides the routines and the handler for the Advanced
832: Resource Assembly Tool (RAT), and ties the various pieces together
833: with Javascript.
834:
835: =head1 OVERVIEW
836:
837: =head2 Map Representation
838:
839: =begin latex
840:
841: %
842: \begin{figure}
843: \begin{center}\includegraphics[%
844: width=0.55\paperwidth,bb = 0 0 200 100, draft, type=eps]{Map_Example}\end{center}
845:
846:
847: \caption{\label{Map_In_Advanced_Editor}Example of a Map in the Advanced Editor}
848: \end{figure}
849: %
850: \begin{figure}
851: \begin{lyxcode}
852: <map>
853:
854: ~~<resource~id=\char`\"{}1\char`\"{}
855:
856: ~~~~src=\char`\"{}/res/msu/korte/phy231welcome.html\char`\"{}
857:
858: ~~~~type=\char`\"{}start\char`\"{}
859:
860: ~~~~title=\char`\"{}Start\char`\"{}>
861:
862: ~~~~</resource>
863:
864: ~~<resource~id=\char`\"{}2\char`\"{}
865:
866: ~~~~src=\char`\"{}\char`\"{}~type=\char`\"{}finish\char`\"{}
867:
868: ~~~~title=\char`\"{}Finish\char`\"{}>
869:
870: ~~~~</resource>
871:
872: ~~<resource~id=\char`\"{}6\char`\"{}
873:
874: ~~~~src=\char`\"{}/res/msu/korte/tests/units.problem\char`\"{}
875:
876: ~~~~type=\char`\"{}mandatory\char`\"{}
877:
878: ~~~~title=\char`\"{}Physical~Units~Test\char`\"{}>
879:
880: ~~~~</resource>
881:
882: ~~<resource~id=\char`\"{}9\char`\"{}
883:
884: ~~~~src=\char`\"{}/res/msu/korte/chapters/onedim.sequence\char`\"{}
885:
886: ~~~~title=\char`\"{}Motion~in~One~Dimension\char`\"{}>
887:
888: ~~~~</resource>
889:
890: ~~<resource~id=\char`\"{}11\char`\"{}
891:
892: ~~~~src=\char`\"{}/res/msu/bauer/bridges/units.sequence\char`\"{}
893:
894: ~~~~title=\char`\"{}Physical~Units~Refresher\char`\"{}>
895:
896: ~~~~</resource>
897:
898: ~~<condition~id=\char`\"{}19\char`\"{}
899:
900: ~~~~type=\char`\"{}stop\char`\"{}
901:
902: ~~~~value=\char`\"{}user.assessments{[}this./res/msu/korte/tests/units.problem{]}.status=solved\char`\"{}>
903:
904: ~~~~</condition>
905:
906: ~~<link~from=\char`\"{}1\char`\"{}~to=\char`\"{}6\char`\"{}></link>
907:
908: ~~<link~from=\char`\"{}6\char`\"{}~to=\char`\"{}9\char`\"{}~condition=\char`\"{}19\char`\"{}></link>
909:
910: ~~<link~from=\char`\"{}6\char`\"{}~to=\char`\"{}11\char`\"{}></link>
911:
912: ~~<link~from=\char`\"{}11\char`\"{}~to=\char`\"{}6\char`\"{}></link>
913:
914: ~~</map>
915: \end{lyxcode}
916:
917: \caption{\label{XML}XML for Map in Figure \ref{Map_In_Advanced_Editor}}
918: \end{figure}
919:
920: =end latex
921:
922: Fig. "XML for Map in Figure" shows the XML representation of the
923: resource map shown in Fig. "Example of a Map in the Advanced Editor",
924: which is the format in which maps are stored. In the figure, however,
925: additional graphical map layout information generated by the Advanced
926: Resource Assembly Tool is not displayed. This graphical information is
927: optional to re-generate the same graphical layout when the map is
928: brought up again in the Resource Assembly Tool, and is not needed for
929: any other system functionality.
930:
931: Maps can be generated by tools other than the Resource Assembly
932: Tool. In particular, an author might have some other representation of
933: a course sequence, which can be converted into a map using scripts. If
934: this map then were to be brought up in the Resource Assembly Tool, the
935: Tool would automatically generate a graphical layout for it. Each
936: entry of the map (resources, conditions and links) is stored in a
937: separate tag.
938:
939: Resources and conditionsX<conditions> have to have unique ID
940: numbers. These numbers are automatically generated by the Resource
941: Assembly Tool when the entry is first created, or added to the entries
942: when a map generated outside the Resource Assembly Tool is first
943: retrieved. They can also be assigned by custom scripts or added in by
944: hand.
945:
946: In the XML example, entry 1 is the start resource of the map. When
947: this map is accessed, the source (src) URL of this tag will be the
948: first resource rendered. Entry 2 is the finish resource of this
949: map. This resource will be the last resource in the sequence of
950: resources. Entry 6 is a problem resource with the given URL and title,
951: as well as the priority "mandatory". Entry 19 is a condition, which is
952: used by the link between entries 6, the problem, and 9, a
953: sequence. I<The final syntax for conditions has not yet been
954: determined.>
955:
956: =cut
957:
958:
959:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>