1: # The LearningOnline Network with CAPA
2: # Page Handler
3: #
4: # $Id: lonpage.pm,v 1.42 2002/06/27 18:48:30 sakharuk Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28: # (TeX Content Handler
29: #
30: # YEAR=2000
31: # 05/29/00,05/30 Gerd Kortemeyer)
32: # 08/30,08/31,09/06,09/14,09/15,09/16,09/19,09/20,09/21,09/23,
33: # 10/02,10/10,10/14,10/16,10/18,10/19,10/31,11/6,11/14,11/16,
34: # YEAR=2001
35: # 08/13/01,08/30,10/1 Gerd Kortemeyer
36: # 12/16 Scott Harrison
37: # YEAR=2002
38: # 03/19 Gerd Kortemeyer
39: #
40: ###
41:
42: package Apache::lonpage;
43:
44: use strict;
45: use Apache::Constants qw(:common :http);
46: use Apache::lonnet();
47: use Apache::loncommon();
48: use Apache::lonxml();
49: use HTML::TokeParser;
50: use GDBM_File;
51: use Apache::lonsequence;
52:
53: # -------------------------------------------------------------- Module Globals
54: my %hash;
55: my @rows;
56:
57: # ------------------------------------------------------------------ Euclid gcd
58:
59: sub euclid {
60: my ($e,$f)=@_;
61: my $a; my $b; my $r;
62: if ($e>$f) { $b=$e; $r=$f; } else { $r=$e; $b=$f; }
63: while ($r!=0) {
64: $a=$b; $b=$r;
65: $r=$a%$b;
66: }
67: return $b;
68: }
69:
70: # ------------------------------------------------------------ Build page table
71:
72: sub tracetable {
73: my ($sofar,$rid,$beenhere)=@_;
74: my $further=$sofar;
75: unless ($beenhere=~/\&$rid\&/) {
76: $beenhere.=$rid.'&';
77:
78: if (defined($hash{'is_map_'.$rid})) {
79: if ((defined($hash{'map_start_'.$hash{'src_'.$rid}})) &&
80: (defined($hash{'map_finish_'.$hash{'src_'.$rid}}))) {
81: my $frid=$hash{'map_finish_'.$hash{'src_'.$rid}};
82: $sofar=
83: &tracetable($sofar,$hash{'map_start_'.$hash{'src_'.$rid}},
84: '&'.$frid.'&');
85: $sofar++;
86: if ($hash{'src_'.$frid}) {
87: my $brepriv=&Apache::lonnet::allowed('bre',$hash{'src_'.$frid});
88: if (($brepriv eq '2') || ($brepriv eq 'F')) {
89: if (defined($rows[$sofar])) {
90: $rows[$sofar].='&'.$frid;
91: } else {
92: $rows[$sofar]=$frid;
93: }
94: }
95: }
96: }
97: } else {
98: $sofar++;
99: if ($hash{'src_'.$rid}) {
100: my $brepriv=&Apache::lonnet::allowed('bre',$hash{'src_'.$rid});
101: if (($brepriv eq '2') || ($brepriv eq 'F')) {
102: if (defined($rows[$sofar])) {
103: $rows[$sofar].='&'.$rid;
104: } else {
105: $rows[$sofar]=$rid;
106: }
107: }
108: }
109: }
110:
111: if (defined($hash{'to_'.$rid})) {
112: my $mincond=1;
113: my $next='';
114: foreach (split(/\,/,$hash{'to_'.$rid})) {
115: my $thiscond=
116: &Apache::lonnet::directcondval($hash{'condid_'.$hash{'undercond_'.$_}});
117: if ($thiscond>=$mincond) {
118: if ($next) {
119: $next.=','.$_.':'.$thiscond;
120: } else {
121: $next=$_.':'.$thiscond;
122: }
123: if ($thiscond>$mincond) { $mincond=$thiscond; }
124: }
125: }
126: foreach (split(/\,/,$next)) {
127: my ($linkid,$condval)=split(/\:/,$_);
128: if ($condval>=$mincond) {
129: my $now=&tracetable($sofar,$hash{'goesto_'.$linkid},$beenhere);
130: if ($now>$further) { $further=$now; }
131: }
132: }
133:
134: }
135: }
136: return $further;
137: }
138:
139: # ================================================================ Main Handler
140:
141: sub handler {
142: my $r=shift;
143:
144: # ------------------------------------------- Set document type for header only
145:
146: if ($r->header_only) {
147: if ($ENV{'browser.mathml'}) {
148: $r->content_type('text/xml');
149: } else {
150: $r->content_type('text/html');
151: }
152: $r->send_http_header;
153: return OK;
154: }
155:
156: &Apache::loncommon::get_unprocessed_cgi($ENV{'QUERY_STRING'},
157: ['forceselect','launch']);
158:
159: my $requrl=$r->uri;
160: my $target = $ENV{'form.grade_target'};
161: # ----------------------------------------------------------------- Tie db file
162: if (($ENV{'request.course.fn'}) && (!$ENV{'form.forceselect'})) {
163: my $fn=$ENV{'request.course.fn'};
164: if (-e "$fn.db") {
165: if (tie(%hash,'GDBM_File',"$fn.db",&GDBM_READER,0640)) {
166: # ------------------------------------------------------------------- Hash tied
167: my $firstres=$hash{'map_start_'.$requrl};
168: my $lastres=$hash{'map_finish_'.$requrl};
169: if (($firstres) && ($lastres)) {
170: # ----------------------------------------------------------------- Render page
171:
172: @rows=();
173:
174: &tracetable(0,$firstres,'&'.$lastres.'&');
175: if ($hash{'src_'.$lastres}) {
176: my $brepriv=
177: &Apache::lonnet::allowed('bre',$hash{'src_'.$lastres});
178: if (($brepriv eq '2') || ($brepriv eq 'F')) {
179: $rows[$#rows+1]=''.$lastres;
180: }
181: }
182:
183: # ------------------------------------------------------------ Add to symb list
184:
185: my $i;
186: my %symbhash=();
187: for ($i=0;$i<=$#rows;$i++) {
188: if ($rows[$i]) {
189: my @colcont=split(/\&/,$rows[$i]);
190: foreach (@colcont) {
191: $symbhash{$hash{'src_'.$_}}='';
192: }
193: }
194: }
195: &Apache::lonnet::symblist($requrl,%symbhash);
196:
197: # ------------------------------------------------------------------ Page parms
198:
199: my $number_of_columns = 1;
200: my $j;
201: my $lcm=1;
202: my $contents=0;
203: my $nforms=0;
204:
205: my %ssibody=();
206: my %ssibgcolor=();
207: my %ssitext=();
208: my %ssilink=();
209: my %ssivlink=();
210: my %ssialink=();
211:
212: my %metalink=();
213:
214: my %cellemb=();
215:
216: my $allscript='';
217: my $allmeta='';
218:
219: my $isxml=0;
220: my $xmlheader='';
221: my $xmlbody='';
222:
223: # --------------------------------------------- Get SSI output, post parameters
224:
225: for ($i=0;$i<=$#rows;$i++) {
226: if ($rows[$i]) {
227: $contents++;
228: my @colcont=split(/\&/,$rows[$i]);
229: $lcm*=($#colcont+1)/euclid($lcm,($#colcont+1));
230: foreach (@colcont) {
231: my $src=$hash{'src_'.$_};
232: $src=~/\.(\w+)$/;
233: $metalink{$_}=$src.'.meta';
234: $cellemb{$_}=Apache::loncommon::fileembstyle($1);
235: if ($cellemb{$_} eq 'ssi') {
236: # --------------------------------------------------------- This is an SSI cell
237: my $prefix=$_.'_';
238: my %posthash=('request.prefix' => $prefix);
239: if (($ENV{'form.'.$prefix.'submit'})
240: || ($ENV{'form.all_submit'})) {
241: foreach (keys %ENV) {
242: if ($_=~/^form.$prefix/) {
243: my $name=$_;
244: $name=~s/^form.$prefix//;
245: $posthash{$name}=$ENV{$_};
246: }
247: }
248: }
249: my $output=Apache::lonnet::ssi($src,%posthash);
250: my $parser=HTML::TokeParser->new(\$output);
251: my $token;
252: my $thisdir=$src;
253: my $bodydef=0;
254: my $thisxml=0;
255: my @rlinks=();
256: if ($output=~/\?xml/) {
257: $isxml=1;
258: $thisxml=1;
259: $output=~
260: /((?:\<(?:\?xml|\!DOC|html)[^\>]*(?:\>|\>\]\>)\s*)+)\<body[^\>]*\>/si;
261: $xmlheader=$1;
262: }
263: while ($token=$parser->get_token) {
264: if ($token->[0] eq 'S') {
265: if ($token->[1] eq 'a') {
266: if ($token->[2]->{'href'}) {
267: $rlinks[$#rlinks+1]=
268: $token->[2]->{'href'};
269: }
270: } elsif ($token->[1] eq 'img') {
271: $rlinks[$#rlinks+1]=
272: $token->[2]->{'src'};
273: } elsif ($token->[1] eq 'embed') {
274: $rlinks[$#rlinks+1]=
275: $token->[2]->{'src'};
276: } elsif ($token->[1] eq 'base') {
277: $thisdir=$token->[2]->{'href'};
278: } elsif ($token->[1] eq 'body') {
279: $bodydef=1;
280: $ssibgcolor{$_}=$token->[2]->{'bgcolor'};
281: $ssitext{$_}=$token->[2]->{'text'};
282: $ssilink{$_}=$token->[2]->{'link'};
283: $ssivlink{$_}=$token->[2]->{'vlink'};
284: $ssialink{$_}=$token->[2]->{'alink'};
285: if ($thisxml) {
286: $xmlbody=$token->[4];
287: }
288: } elsif ($token->[1] eq 'meta') {
289: if ($token->[4] !~ m:/>$:) {
290: $allmeta.="\n".$token->[4].'</meta>';
291: } else {
292: $allmeta.="\n".$token->[4];
293: }
294: } elsif (($token->[1] eq 'script') &&
295: ($bodydef==0)) {
296: $allscript.="\n\n"
297: .$parser->get_text('/script');
298: }
299: }
300: }
301: if ($output=~/\<body[^\>]*\>(.*)/si) {
302: $output=$1;
303: }
304: $output=~s/\<\/body\>.*//si;
305: if ($output=~/\<form/si) {
306: $nforms++;
307: $output=~s/\<form[^\>]*\>//gsi;
308: $output=~s/\<\/form[^\>]*\>//gsi;
309: $output=~
310: s/\<((?:input|select|button|textarea)[^\>]+)name\s*\=\s*[\'\"]*([\w\.\:]+)[\'\"]*([^\>]*)\>/\<$1 name="$prefix$2" $3\>/gsi;
311: }
312: $thisdir=~s/\/[^\/]*$//;
313: foreach (@rlinks) {
314: unless (($_=~/^http:\/\//i) ||
315: ($_=~/^\//) ||
316: ($_=~/^javascript:/i) ||
317: ($_=~/^mailto:/i) ||
318: ($_=~/^\#/)) {
319: my $newlocation=
320: &Apache::lonnet::hreflocation($thisdir,$_);
321: $output=~s/(\"|\'|\=\s*)$_(\"|\'|\s|\>)/$1$newlocation$2/;
322: }
323: }
324: # -------------------------------------------------- Deal with Applet codebases
325: $output=~s/(\<applet[^\>]+)(codebase\=[^\S\>]+)*([^\>]*)\>/$1.($2?$2:' codebase="'.$thisdir.'"').$3.'>'/gei;
326: $ssibody{$_}=$output;
327: # ---------------------------------------------------------------- End SSI cell
328: }
329: }
330: }
331: }
332: unless ($contents) {
333: $r->content_type('text/html');
334: $r->send_http_header;
335: $r->print('<html><body>Empty page.</body></html>');
336: } else {
337: # ------------------------------------------------------------------ Build page
338:
339: # ---------------------------------------------------------------- Send headers
340: unless ($target eq 'tex') {
341: if ($isxml) {
342: $r->content_type('text/xml');
343: $r->send_http_header;
344: $r->print($xmlheader);
345: } else {
346: $r->content_type('text/html');
347: $r->send_http_header;
348: $r->print('<html>');
349: }
350: # ------------------------------------------------------------------------ Head
351: $r->print("\n<head>\n".$allmeta);
352: $allscript=~
353: s/\/\/ BEGIN LON\-CAPA Internal.+\/\/ END LON\-CAPA Internal\s//gs;
354: if ($allscript) {
355: $r->print("\n<script language='JavaScript'>\n".
356: $allscript."\n</script>\n");
357: }
358: $r->print(&Apache::lonxml::registerurl(1,undef));
359: $r->print("\n</head>\n");
360: # ------------------------------------------------------------------ Start body
361: if ($isxml) {
362: $r->print($xmlbody);
363: } else {
364: $r->print('<body bgcolor="#FFFFFF" onLoad="'.&Apache::lonxml::loadevents.'" onUnload="'.&Apache::lonxml::unloadevents.'">');
365: }
366: # ------------------------------------------------------------------ Start form
367: if ($nforms) {
368: $r->print('<form method="post" action="'.
369: $requrl.'">');
370: }
371: } else {
372: $r->print('\documentclass[letterpaper]{article}
373: \newcommand{\keephidden}[1]{}
374: \usepackage[dvips]{graphicx}
375: \usepackage{epsfig}
376: \usepackage{calc}
377: \usepackage{longtable}
378: \begin{document}');
379: }
380: # ----------------------------------------------------------------- Start table
381: if ($target eq 'tex') {
382: $r->print('\begin{longtable}INSERTTHEHEADOFLONGTABLE\endfirsthead\endhead ');
383: } else {
384: $r->print('<table cols="'.$lcm.'" border="0">');
385: }
386: for ($i=0;$i<=$#rows;$i++) {
387: if ($rows[$i]) {
388: unless ($target eq 'tex') {
389: $r->print("\n<tr>");
390: }
391: my @colcont=split(/\&/,$rows[$i]);
392: my $avespan=$lcm/($#colcont+1);
393: for ($j=0;$j<=$#colcont;$j++) {
394: my $rid=$colcont[$j];
395: my $metainfo='<a href="'.
396: $metalink{$rid}.'" target="LONcatInfo">'.
397: '<img src="/adm/lonMisc/cat_button.gif" border=0>'.
398: '</img></a><a href="/adm/evaluate?postdata='.
399: &Apache::lonnet::escape(&Apache::lonnet::declutter($hash{'src_'.$rid}))
400: .'" target="LONcatInfo">'.
401: '<img src="/adm/lonMisc/eval_button.gif" border=0>'.
402: '</img></a>';
403: if (
404: ($hash{'src_'.$rid}=~/\.(problem|exam|quiz|assess|survey|form)$/) &&
405: (&Apache::lonnet::allowed('mgr',$ENV{'request.course.id'}))) {
406: my ($mapid,$resid)=split(/\./,$rid);
407: my $symb=
408: &Apache::lonnet::declutter($hash{'map_id_'.$mapid}).
409: '___'.$resid.'___'.
410: &Apache::lonnet::declutter($hash{'src_'.$rid});
411: $metainfo.=
412: '<a href="/adm/grades?symb='.&Apache::lonnet::escape($symb).
413: '&command=submission" target="LONcatInfo">'.
414: '<img src="/adm/lonMisc/subm_button.gif" border=0>'.
415: '</img></a>'.
416: '<a href="/adm/grades?symb='.&Apache::lonnet::escape($symb).
417: '&command=gradingmenu" target="LONcatInfo">'.
418: '<img src="/adm/lonMisc/pgrd_button.gif" border=0>'.
419: '</img></a>'.
420: '<a href="/adm/parmset?symb='.&Apache::lonnet::escape($symb).
421: '" target="LONcatInfo">'.
422: '<img src="/adm/lonMisc/pprm_button.gif" border=0>'.
423: '</img></a>';
424: }
425: $metainfo.='<br></br>';
426: unless ($target eq 'tex') {
427: $r->print('<td colspan="'.$avespan.'"');
428: }
429: if ($cellemb{$rid} eq 'ssi') {
430: unless ($target eq 'tex') {
431: if ($ssibgcolor{$rid}) {
432: $r->print(' bgcolor="'.
433: $ssibgcolor{$rid}.'"');
434: }
435: $r->print('>'.$metainfo.'<font');
436:
437: if ($ssitext{$rid}) {
438: $r->print(' text="'.$ssitext{$rid}.'"');
439: }
440: if ($ssilink{$rid}) {
441: $r->print(' link="'.$ssilink{$rid}.'"');
442: }
443: if ($ssitext{$rid}) {
444: $r->print(' vlink="'.$ssivlink{$rid}.'"');
445: }
446: if ($ssialink{$rid}) {
447: $r->print(' alink="'.$ssialink{$rid}.'"');
448: }
449: $r->print('>');
450: }
451: $r->print($ssibody{$rid});
452: unless ($target eq 'tex') {
453: $r->print('</font>');
454: }
455: if ($ENV{'course.'.
456: $ENV{'request.course.id'}.
457: '.pageseparators'} eq 'yes') {
458: unless($target eq 'tex') {
459: $r->print('<hr />');
460: } else {
461: $r->print('\hline');
462: }
463: }
464: } elsif ($cellemb{$rid} eq 'img') {
465: $r->print('>'.$metainfo.'<img src="'.
466: $hash{'src_'.$rid}.'"></img>');
467: } elsif ($cellemb{$rid} eq 'emb') {
468: $r->print('>'.$metainfo.'<embed src="'.
469: $hash{'src_'.$rid}.'"></embed>');
470: }
471: unless ($target eq 'tex') {
472: $r->print('</td>');
473: } else {
474: $number_of_columns++;
475: $r->print(' & ');
476: }
477: }
478: unless ($target eq 'tex') {
479: $r->print('</tr>');
480: } else {
481: $number_of_columns = 1;
482: $r->print('REMOVETHEHEADOFLONGTABLE\\\\');
483: }
484: }
485: }
486: unless ($target eq 'tex') {
487: $r->print("\n</table>");
488: } else {
489: $r->print('\end{longtable}');
490: }
491: # ---------------------------------------------------------------- Submit, etc.
492: if ($nforms) {
493: $r->print(
494: '<input name="all_submit" value="Submit All" type="'.
495: (($nforms>1)?'submit':'hidden').'"></input></form>');
496: }
497: unless ($target eq 'tex') {
498: $r->print('</body>'.&Apache::lonxml::xmlend());
499: } else {
500: $r->print('\end{document}'.$number_of_columns);
501: }
502: # -------------------------------------------------------------------- End page
503: }
504: # ------------------------------------------------------------- End render page
505: } else {
506: $r->content_type('text/html');
507: $r->send_http_header;
508: &Apache::lonsequence::viewmap($r,$requrl);
509: }
510: # ------------------------------------------------------------------ Untie hash
511: unless (untie(%hash)) {
512: &Apache::lonnet::logthis("<font color=blue>WARNING: ".
513: "Could not untie coursemap $fn (browse).</font>");
514: }
515: # -------------------------------------------------------------------- All done
516: return OK;
517: # ----------------------------------------------- Errors, hash could no be tied
518: }
519: }
520: }
521: $r->content_type('text/html');
522: $r->send_http_header;
523: &Apache::lonsequence::viewmap($r,$requrl);
524: return OK;
525: }
526:
527: 1;
528: __END__
529:
530: =head1 NAME
531:
532: Apache::lonpage - Page Handler
533:
534: =head1 SYNOPSIS
535:
536: Invoked by /etc/httpd/conf/srm.conf:
537:
538: <LocationMatch "^/res/.*\.page$>
539: SetHandler perl-script
540: PerlHandler Apache::lonpage
541: </LocationMatch>
542:
543: =head1 INTRODUCTION
544:
545: This module renders a .page resource.
546:
547: This is part of the LearningOnline Network with CAPA project
548: described at http://www.lon-capa.org.
549:
550: =head1 HANDLER SUBROUTINE
551:
552: This routine is called by Apache and mod_perl.
553:
554: =over 4
555:
556: =item *
557:
558: set document type for header only
559:
560: =item *
561:
562: tie db file
563:
564: =item *
565:
566: render page
567:
568: =item *
569:
570: add to symb list
571:
572: =item *
573:
574: page parms
575:
576: =item *
577:
578: Get SSI output, post parameters
579:
580: =item *
581:
582: SSI cell rendering
583:
584: =item *
585:
586: Deal with Applet codebases
587:
588: =item *
589:
590: Build page
591:
592: =item *
593:
594: send headers
595:
596: =item *
597:
598: start body
599:
600: =item *
601:
602: start form
603:
604: =item *
605:
606: start table
607:
608: =item *
609:
610: submit element, etc, render page, untie hash
611:
612: =back
613:
614: =head1 OTHER SUBROUTINES
615:
616: =over 4
617:
618: =item *
619:
620: euclid() : Euclid's method for determining the greatest common denominator.
621:
622: =item *
623:
624: tracetable() : Build page table.
625:
626: =back
627:
628: =cut
629:
630:
631:
632:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>