1: #!/usr/bin/perl
2: # The LearningOnline Network
3: # searchcat.pl "Search Catalog" batch script
4: #
5: # $Id: searchcat.pl,v 1.46 2003/12/24 20:41:32 www Exp $
6: #
7: # Copyright Michigan State University Board of Trustees
8: #
9: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
10: #
11: # LON-CAPA is free software; you can redistribute it and/or modify
12: # it under the terms of the GNU General Public License as published by
13: # the Free Software Foundation; either version 2 of the License, or
14: # (at your option) any later version.
15: #
16: # LON-CAPA is distributed in the hope that it will be useful,
17: # but WITHOUT ANY WARRANTY; without even the implied warranty of
18: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19: # GNU General Public License for more details.
20: #
21: # You should have received a copy of the GNU General Public License
22: # along with LON-CAPA; if not, write to the Free Software
23: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
24: #
25: # /home/httpd/html/adm/gpl.txt
26: #
27: # http://www.lon-capa.org/
28: #
29: ###
30:
31: =pod
32:
33: =head1 NAME
34:
35: B<searchcat.pl> - put authoritative filesystem data into sql database.
36:
37: =head1 SYNOPSIS
38:
39: Ordinarily this script is to be called from a loncapa cron job
40: (CVS source location: F<loncapa/loncom/cron/loncapa>; typical
41: filesystem installation location: F</etc/cron.d/loncapa>).
42:
43: Here is the cron job entry.
44:
45: C<# Repopulate and refresh the metadata database used for the search catalog.>
46: C<10 1 * * 7 www /home/httpd/perl/searchcat.pl>
47:
48: This script only allows itself to be run as the user C<www>.
49:
50: =head1 DESCRIPTION
51:
52: This script goes through a loncapa resource directory and gathers metadata.
53: The metadata is entered into a SQL database.
54:
55: This script also does general database maintenance such as reformatting
56: the C<loncapa:metadata> table if it is deprecated.
57:
58: This script evaluates dynamic metadata from the authors'
59: F<nohist_resevaldata.db> database file in order to store it in MySQL, as
60: well as to compress the filesize (add up all "count"-type metadata).
61:
62: This script is playing an increasingly important role for a loncapa
63: library server. The proper operation of this script is critical for a smooth
64: and correct user experience.
65:
66: =cut
67:
68: use strict;
69:
70: use lib '/home/httpd/lib/perl/';
71: use LONCAPA::Configuration;
72:
73: use IO::File;
74: use HTML::TokeParser;
75: use DBI;
76: use GDBM_File;
77: use POSIX qw(strftime mktime);
78:
79: require "find.pl";
80:
81: my @metalist;
82:
83: my $simplestatus='';
84: my %countext=();
85:
86: # ----------------------------------------------------- write out simple status
87: sub writesimple {
88: open(SMP,'>/home/httpd/html/lon-status/mysql.txt');
89: print SMP $simplestatus."\n";
90: close(SMP);
91: }
92:
93: sub writecount {
94: open(RSMP,'>/home/httpd/html/lon-status/rescount.txt');
95: foreach (keys %countext) {
96: print RSMP $_.'='.$countext{$_}.'&';
97: }
98: print RSMP 'time='.time."\n";
99: close(RSMP);
100: }
101:
102: # -------------------------------------- counts files with different extensions
103: sub count {
104: my $file=shift;
105: $file=~/\.(\w+)$/;
106: my $ext=lc($1);
107: if (defined($countext{$ext})) {
108: $countext{$ext}++;
109: } else {
110: $countext{$ext}=1;
111: }
112: }
113: # ----------------------------------------------------- Un-Escape Special Chars
114:
115: sub unescape {
116: my $str=shift;
117: $str =~ s/%([a-fA-F0-9][a-fA-F0-9])/pack("C",hex($1))/eg;
118: return $str;
119: }
120:
121: # -------------------------------------------------------- Escape Special Chars
122:
123: sub escape {
124: my $str=shift;
125: $str =~ s/(\W)/"%".unpack('H2',$1)/eg;
126: return $str;
127: }
128:
129: # ------------------------------------------- Code to evaluate dynamic metadata
130:
131: sub dynamicmeta {
132: my $url=&declutter(shift);
133: $url=~s/\.meta$//;
134: my %returnhash=();
135: my ($adomain,$aauthor)=($url=~/^(\w+)\/(\w+)\//);
136: my $prodir=&propath($adomain,$aauthor);
137:
138: # Get metadata except counts
139: if (tie(my %evaldata,'GDBM_File',
140: $prodir.'/nohist_resevaldata.db',&GDBM_READER(),0640)) {
141: my %sum=();
142: my %cnt=();
143: my %concat=();
144: my %listitems=(
145: 'course' => 'add',
146: 'goto' => 'add',
147: 'comefrom' => 'add',
148: 'avetries' => 'avg',
149: 'stdno' => 'add',
150: 'difficulty' => 'avg',
151: 'clear' => 'avg',
152: 'technical' => 'avg',
153: 'helpful' => 'avg',
154: 'correct' => 'avg',
155: 'depth' => 'avg',
156: 'comments' => 'app',
157: 'usage' => 'cnt'
158: );
159:
160: my $regexp=$url;
161: $regexp=~s/(\W)/\\$1/g;
162: $regexp='___'.$regexp.'___([a-z]+)$';
163: while (my ($esckey,$value)=each %evaldata) {
164: my $key=&unescape($esckey);
165: if ($key=~/$regexp/) {
166: my ($item,$purl,$cat)=split(/___/,$key);
167: if (defined($cnt{$cat})) { $cnt{$cat}++; } else { $cnt{$cat}=1; }
168: unless ($listitems{$cat} eq 'app') {
169: if (defined($sum{$cat})) {
170: $sum{$cat}+=$evaldata{$esckey};
171: $concat{$cat}.=','.$item;
172: } else {
173: $sum{$cat}=$evaldata{$esckey};
174: $concat{$cat}=$item;
175: }
176: } else {
177: if (defined($sum{$cat})) {
178: if ($evaldata{$esckey}=~/\w/) {
179: $sum{$cat}.='<hr>'.$evaldata{$esckey};
180: }
181: } else {
182: $sum{$cat}=''.$evaldata{$esckey};
183: }
184: }
185: }
186: }
187: untie(%evaldata);
188: # transfer gathered data to returnhash, calculate averages where applicable
189: while (my $cat=each(%cnt)) {
190: if ($listitems{$cat} eq 'avg') {
191: $returnhash{$cat}=int(($sum{$cat}/$cnt{$cat})*100.0+0.5)/100.0;
192: } elsif ($listitems{$cat} eq 'cnt') {
193: $returnhash{$cat}=$cnt{$cat};
194: } else {
195: $returnhash{$cat}=$sum{$cat};
196: }
197: $returnhash{$cat.'_list'}=$concat{$cat};
198: }
199: }
200: # get count
201: if (tie(my %evaldata,'GDBM_File',
202: $prodir.'/nohist_accesscount.db',&GDBM_READER(),0640)) {
203: my $escurl=&escape($url);
204: if (! exists($evaldata{$escurl})) {
205: $returnhash{'count'}=0;
206: } else {
207: $returnhash{'count'}=$evaldata{$escurl};
208: }
209: untie %evaldata;
210: }
211: return %returnhash;
212: }
213:
214: # --------------- Read loncapa_apache.conf and loncapa.conf and get variables
215: my $perlvarref=LONCAPA::Configuration::read_conf('loncapa.conf');
216: my %perlvar=%{$perlvarref};
217: undef $perlvarref; # remove since sensitive and not needed
218: delete $perlvar{'lonReceipt'}; # remove since sensitive and not needed
219:
220: # ------------------------------------- Only run if machine is a library server
221: exit unless $perlvar{'lonRole'} eq 'library';
222:
223: # ----------------------------- Make sure this process is running from user=www
224:
225: my $wwwid=getpwnam('www');
226: if ($wwwid!=$<) {
227: my $emailto="$perlvar{'lonAdmEMail'},$perlvar{'lonSysEMail'}";
228: my $subj="LON: $perlvar{'lonHostID'} User ID mismatch";
229: system("echo 'User ID mismatch. searchcat.pl must be run as user www.' |\
230: mailto $emailto -s '$subj' > /dev/null");
231: exit 1;
232: }
233:
234:
235: # ---------------------------------------------------------- We are in business
236:
237: open(LOG,'>'.$perlvar{'lonDaemons'}.'/logs/searchcat.log');
238: print LOG '==== Searchcat Run '.localtime()."====\n\n";
239: $simplestatus='time='.time.'&';
240: my $dbh;
241: # ------------------------------------- Make sure that database can be accessed
242: {
243: unless (
244: $dbh = DBI->connect("DBI:mysql:loncapa","www",$perlvar{'lonSqlAccess'},{ RaiseError =>0,PrintError=>0})
245: ) {
246: print LOG "Cannot connect to database!\n";
247: $simplestatus.='mysql=defunct';
248: &writesimple();
249: exit;
250: }
251:
252: # Create table for static metadata, unless exists
253: my $make_metadata_table = "CREATE TABLE IF NOT EXISTS metadata (".
254: "title TEXT, author TEXT, subject TEXT, url TEXT, keywords TEXT, ".
255: "version TEXT, notes TEXT, abstract TEXT, mime TEXT, language TEXT, ".
256: "creationdate DATETIME, lastrevisiondate DATETIME, owner TEXT, ".
257: "copyright TEXT, FULLTEXT idx_title (title), ".
258: "FULLTEXT idx_author (author), FULLTEXT idx_subject (subject), ".
259: "FULLTEXT idx_url (url), FULLTEXT idx_keywords (keywords), ".
260: "FULLTEXT idx_version (version), FULLTEXT idx_notes (notes), ".
261: "FULLTEXT idx_abstract (abstract), FULLTEXT idx_mime (mime), ".
262: "FULLTEXT idx_language (language), FULLTEXT idx_owner (owner), ".
263: "FULLTEXT idx_copyright (copyright)) TYPE=MYISAM";
264: # It would sure be nice to have some logging mechanism.
265: $dbh->do($make_metadata_table);
266:
267: # Create table for dynamic metadata, unless exists
268: my $make_dynmetadata_table = "CREATE TABLE IF NOT EXISTS dynmetadata (".
269: "url TEXT, count INTEGER UNSIGNED, ".
270: "course INTEGER UNSIGNED, course_list TEXT, ".
271: "goto INTEGER UNSIGNED, goto_list TEXT, ".
272: "comefrom INTEGER UNSIGNED, comefrom_list TEXT, ".
273: "usage INTEGER UNSIGNED, usage_list TEXT, ".
274: "stdno INTEGER UNSIGNED, stdno_list TEXT, ".
275: "avetries FLOAT, avetries_list TEXT, ".
276: "difficulty FLOAT, difficulty_list TEXT ".
277: "TYPE=MYISAM";
278: # It would sure be nice to have some logging mechanism.
279: #### $dbh->do($make_dynmetadata_table);
280:
281: }
282:
283: # ------------------------------------------------------------- get .meta files
284: opendir(RESOURCES,"$perlvar{'lonDocRoot'}/res/$perlvar{'lonDefDomain'}");
285: my @homeusers = grep {
286: &ishome("$perlvar{'lonDocRoot'}/res/$perlvar{'lonDefDomain'}/$_")
287: } grep {!/^\.\.?$/} readdir(RESOURCES);
288: closedir RESOURCES;
289:
290: #
291: # Create the statement handlers we need
292: my $delete_sth = $dbh->prepare
293: ("DELETE FROM metadata WHERE url LIKE BINARY ?");
294:
295: my $insert_sth = $dbh->prepare
296: ("INSERT INTO metadata VALUES (".
297: "?,". # title
298: "?,". # author
299: "?,". # subject
300: "?,". # m2???
301: "?,". # version
302: "?,". # current
303: "?,". # notes
304: "?,". # abstract
305: "?,". # mime
306: "?,". # language
307: "?,". # creationdate
308: "?,". # revisiondate
309: "?,". # owner
310: "?)" # copyright
311: );
312:
313: foreach my $user (@homeusers) {
314: print LOG "\n=== User: ".$user."\n\n";
315:
316: my $prodir=&propath($perlvar{'lonDefDomain'},$user);
317: # Use find.pl
318: undef @metalist;
319: @metalist=();
320: &find("$perlvar{'lonDocRoot'}/res/$perlvar{'lonDefDomain'}/$user");
321: # -- process each file to get metadata and put into search catalog SQL
322: # database. Also, check to see if already there.
323: # I could just delete (without searching first), but this works for now.
324: foreach my $m (@metalist) {
325: print LOG "- ".$m."\n";
326: my $ref=&metadata($m);
327: my $m2='/res/'.&declutter($m);
328: $m2=~s/\.meta$//;
329: if ($ref->{'obsolete'}) { print LOG "obsolete\n"; next; }
330: if ($ref->{'copyright'} eq 'private') { print LOG "private\n"; next; }
331: &dynamicmeta($m2);
332: &count($m2);
333: $delete_sth->execute($m2);
334: $insert_sth->execute($ref->{'title'},
335: $ref->{'author'},
336: $ref->{'subject'},
337: $m2,
338: $ref->{'keywords'},
339: 'current',
340: $ref->{'notes'},
341: $ref->{'abstract'},
342: $ref->{'mime'},
343: $ref->{'language'},
344: sqltime($ref->{'creationdate'}),
345: sqltime($ref->{'lastrevisiondate'}),
346: $ref->{'owner'},
347: $ref->{'copyright'});
348: # if ($dbh->err()) {
349: # print STDERR "Error:".$dbh->errstr()."\n";
350: # }
351: $ref = undef;
352: }
353:
354: # --------------------------------------------------- Clean up database
355: # Need to, perhaps, remove stale SQL database records.
356: # ... not yet implemented
357:
358: }
359: # --------------------------------------------------- Close database connection
360: $dbh->disconnect;
361: print LOG "\n==== Searchcat completed ".localtime()." ====\n";
362: close(LOG);
363: &writesimple();
364: &writecount();
365: exit 0;
366:
367:
368:
369: # =============================================================================
370:
371: # ---------------------------------------------------------------- Get metadata
372: # significantly altered from subroutine present in lonnet
373: sub metadata {
374: my ($uri,$what)=@_;
375: my %metacache;
376: $uri=&declutter($uri);
377: my $filename=$uri;
378: $uri=~s/\.meta$//;
379: $uri='';
380: unless ($metacache{$uri.'keys'}) {
381: unless ($filename=~/\.meta$/) { $filename.='.meta'; }
382: my $metastring=&getfile($perlvar{'lonDocRoot'}.'/res/'.$filename);
383: my $parser=HTML::TokeParser->new(\$metastring);
384: my $token;
385: while ($token=$parser->get_token) {
386: if ($token->[0] eq 'S') {
387: my $entry=$token->[1];
388: my $unikey=$entry;
389: if (defined($token->[2]->{'part'})) {
390: $unikey.='_'.$token->[2]->{'part'};
391: }
392: if (defined($token->[2]->{'name'})) {
393: $unikey.='_'.$token->[2]->{'name'};
394: }
395: if ($metacache{$uri.'keys'}) {
396: $metacache{$uri.'keys'}.=','.$unikey;
397: } else {
398: $metacache{$uri.'keys'}=$unikey;
399: }
400: map {
401: $metacache{$uri.''.$unikey.'.'.$_}=$token->[2]->{$_};
402: } @{$token->[3]};
403: unless (
404: $metacache{$uri.''.$unikey}=$parser->get_text('/'.$entry)
405: ) { $metacache{$uri.''.$unikey}=
406: $metacache{$uri.''.$unikey.'.default'};
407: }
408: }
409: }
410: }
411: return \%metacache;
412: }
413:
414: # ------------------------------------------------------------ Serves up a file
415: # returns either the contents of the file or a -1
416: sub getfile {
417: my $file=shift;
418: if (! -e $file ) { return -1; };
419: my $fh=IO::File->new($file);
420: my $a='';
421: while (<$fh>) { $a .=$_; }
422: return $a;
423: }
424:
425: # ------------------------------------------------------------- Declutters URLs
426: sub declutter {
427: my $thisfn=shift;
428: $thisfn=~s/^$perlvar{'lonDocRoot'}//;
429: $thisfn=~s/^\///;
430: $thisfn=~s/^res\///;
431: return $thisfn;
432: }
433:
434: # --------------------------------------- Is this the home server of an author?
435: # (copied from lond, modification of the return value)
436: sub ishome {
437: my $author=shift;
438: $author=~s/\/home\/httpd\/html\/res\/([^\/]*)\/([^\/]*).*/$1\/$2/;
439: my ($udom,$uname)=split(/\//,$author);
440: my $proname=propath($udom,$uname);
441: if (-e $proname) {
442: return 1;
443: } else {
444: return 0;
445: }
446: }
447:
448: # -------------------------------------------- Return path to profile directory
449: # (copied from lond)
450: sub propath {
451: my ($udom,$uname)=@_;
452: $udom=~s/\W//g;
453: $uname=~s/\W//g;
454: my $subdir=$uname.'__';
455: $subdir =~ s/(.)(.)(.).*/$1\/$2\/$3/;
456: my $proname="$perlvar{'lonUsersDir'}/$udom/$subdir/$uname";
457: return $proname;
458: }
459:
460: # ---------------------------- convert 'time' format into a datetime sql format
461: sub sqltime {
462: my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
463: localtime(&unsqltime(@_[0]));
464: $mon++; $year+=1900;
465: return "$year-$mon-$mday $hour:$min:$sec";
466: }
467:
468: sub maketime {
469: my %th=@_;
470: return POSIX::mktime(($th{'seconds'},$th{'minutes'},$th{'hours'},
471: $th{'day'},$th{'month'}-1,
472: $th{'year'}-1900,0,0,$th{'dlsav'}));
473: }
474:
475:
476: #########################################
477: #
478: # Retro-fixing of un-backward-compatible time format
479:
480: sub unsqltime {
481: my $timestamp=shift;
482: if ($timestamp=~/^(\d+)\-(\d+)\-(\d+)\s+(\d+)\:(\d+)\:(\d+)$/) {
483: $timestamp=&maketime('year'=>$1,'month'=>$2,'day'=>$3,
484: 'hours'=>$4,'minutes'=>$5,'seconds'=>$6);
485: }
486: return $timestamp;
487: }
488:
489: # ----------------- Code to enable 'find' subroutine listing of the .meta files
490:
491: no strict "vars";
492:
493: sub wanted {
494: (($dev,$ino,$mode,$nlink,$uid,$gid) = lstat($_)) &&
495: -f _ &&
496: /^.*\.meta$/ && !/^.+\.\d+\.[^\.]+\.meta$/ &&
497: push(@metalist,"$dir/$_");
498: }
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/back.gif){kind=icon}
Return to searchcat.pl CVS log ![[TXT]](/icons/text.gif){kind=icon}
![[DIR]](/icons/dir.gif){kind=icon}
Up to [LON-CAPA] / loncom / metadata_database