Return to lonenc.pm CVS log

Up to [LON-CAPA] / loncom

BUG#3736

# The LearningOnline Network
# URL translation for encrypted filenames
#
# $Id: lonenc.pm,v 1.8 2004/12/17 21:44:19 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#

package Apache::lonenc;

use strict;
use Apache::Constants qw(:common :remotehost);
use Apache::lonnet();
use Apache::File();
use Apache::loncommon;
use Crypt::IDEA;

sub handler {
    my $r = shift;
    my %cookies=CGI::Cookie->parse($r->header_in('Cookie'));
    my $lonid=$cookies{'lonID'};
    my $cookie;
    if ($lonid) {
	my $handle=$lonid->value;
        $handle=~s/\W//g;
        my $lonidsdir=$r->dir_config('lonIDsDir');
	$ENV{'request.enc'}=1;
        if ((-e "$lonidsdir/$handle.id") && ($handle ne '')) {
# Initialize Environment
            &Apache::lonnet::transfer_profile_to_env($lonidsdir,$handle);
# Decrypt URL and redirect
	    my $redirect=&unencrypted($r->uri);
	    if ($r->args) { $redirect.='?'.$r->args; }
	    $r->internal_redirect($redirect);
	    return OK;
	} 
    }
    return FORBIDDEN;
}

sub encryptseed {
    my $seed=$ENV{'course.'.$ENV{'request.course.id'}.'.internal.encseed'};
    $seed=~s/[^0-9a-f]/0/g;
    $seed.='0123456789abcdef';
    $seed=substr($seed.$seed,0,32);
    return pack("H32",$seed);
}

sub unencrypted {
    my $uri=shift;
    $uri=~s/^\/enc\/(\d+)\///;
    my $cmdlength=$1;
    my $seed=&encryptseed();
    unless ($seed) {
	return '/'.$uri;
    }
    $uri=&Apache::lonnet::unescape($uri);
    my $cipher=new IDEA $seed;
    my $decuri='';
    for (my $encidx=0;$encidx<length($uri);$encidx+=16) {
	$decuri.=$cipher->decrypt(
				  pack("H16",substr($uri,$encidx,16))
				  );
    }
    $ENV{'request.enc'}=1;
    return substr($decuri,0,$cmdlength);
}

sub encrypted {
    my $uri=shift;
    if ($ENV{'request.role.adv'}) { return($uri); }
    my $seed=&encryptseed();
    unless ($seed) {
	return $uri;
    }
    my $cmdlength=length($uri);
    $uri.='00000000';
    my $encuri='';
    my $cipher=new IDEA $seed;
    for (my $encidx=0;$encidx<=$cmdlength;$encidx+=8) {
	$encuri.=unpack("H16",
			$cipher->encrypt(substr($uri,$encidx,8)));
    }
    return '/enc/'.$cmdlength.'/'.&Apache::lonnet::escape($encuri);
}

sub check_encrypt {
    my $str=shift;
    if ($ENV{'request.enc'}) { return &Apache::lonenc::encrypted($str); }
    return $str;
}

sub check_decrypt {
    my ($str)=@_;
    if (ref($str)) {
	if ($$str=~m|^/enc/|) { $$str=&Apache::lonenc::unencrypted($$str); }
	return;
    }
    if ($str=~m|^/enc/|) { return &Apache::lonenc::unencrypted($str); }
    return $str;
}

1;
__END__