Return to classcalc.pm CVS log

Up to [LON-CAPA] / loncom / interface / spreadsheet

Added output selector and implemented excel output.

Moved $spreadsheet->display() to Spreadsheet.pm instead of having it reside
    three times in the descendents of the spreadsheet object.
Moved $spreadsheet->outsheet_excel() to Spreadsheet.pm for the same reason.
Created Spreadsheet::output_selector, which allows the user to select the
    output mode they desire.
Created $spreadsheet->excel_output_row which takes care of writing a row
    to an excel worksheet.
classcalc.pm, studentcalc.pm, and assesscalc.pm each had the same work done
on them:
  Created &excel_rows(), which writes the body of the spreadsheets to
     an excel file.
  Rewrote &get_title to return an array of title lines.
  Created &get_html_title to return an HTML version of the results of
     &get_title.

classcalc.pm and Spreadsheet.pm each have the following change:
    Created &html_header to return appropriate HTML for the spreadsheet.

#
# $Id: classcalc.pm,v 1.3 2003/05/23 19:36:04 matthew Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# The LearningOnline Network with CAPA
# Spreadsheet/Grades Display Handler
#
# POD required stuff:

=head1 NAME

classcalc

=head1 SYNOPSIS

=head1 DESCRIPTION

=over 4

=cut

###################################################
###                 CourseSheet                 ###
###################################################
package Apache::classcalc;

use strict;
use Apache::Constants qw(:common :http);
use Apache::loncoursedata();
use Apache::lonhtmlcommon();
use Apache::Spreadsheet;
use Apache::studentcalc;
use HTML::Entities();
use Spreadsheet::WriteExcel;
use Apache::lonnet;
use Time::HiRes;

@Apache::classcalc::ISA = ('Apache::Spreadsheet');

sub html_header {
    my $self = shift;
    my ($toprow,$bottomrow);
    foreach (['Sections','Section selector goes here'],
             ['Enrollment Status',&Apache::lonhtmlcommon::StatusOptions(undef,undef,3)],
             ['Output Format',&Apache::Spreadsheet::output_selector()]) {
        my ($name,$selector) = @{$_};
        $toprow .= '<th align="center"><b>'.$name.'</b></th>';
        $bottomrow .= '<td>'.$selector.'</td>';
    }
    return "<p>\n<table>\n".
        "<tr>".$toprow."</tr>\n".
        "<tr>".$bottomrow."</tr>\n".
        "</table>\n</p>";
}

sub get_classlist {
    my $self = shift;
    # Retrieve the classlist
    my @Students = ();
    my ($classlist,$field_names) = &Apache::loncoursedata::get_classlist
        ($self->{'cid'},$self->{'cdom'},$self->{'cnum'});
    while (my ($student,$student_data) = each (%$classlist)) {
        my $studenthash = ();
        for (my $i=0; $i< scalar(@$field_names);$i++) {
            my $field = $field_names->[$i];
            $studenthash->{$field}=$student_data->[$i];
        }
        # This is where we can skip students because they are in 
        # the wrong section, have expired or pending roles, whatever...
        push (@Students,$studenthash);
    }
    my @SortedStudents = sort { $a->{'fullname'} cmp $b->{'fullname'} } @Students;
    return @SortedStudents;
}

sub get_title {
    my $self = shift;
    # Section info should be included
    my @title = ($self->{'coursedesc'}, scalar(localtime(time)) );
    return @title;
}

sub get_html_title {
    my $self = shift;
    my ($classcalc_title,$time) = $self->get_title();
    my $title = '<h1>'.$classcalc_title."</h1>\n".'<h3>'.$time."</h3>\n";
    return $title;
}

sub parent_link {
    return '';
}

sub outsheet_html {
    my $self = shift;
    my ($r) = @_;
    ###################################
    # Determine table structure
    ###################################
    my $num_uneditable = 26;
    my $num_left = 52-$num_uneditable;
    my $tableheader =<<"END";
<p>
<table border="2">
<tr>
  <th colspan="2" rowspan="2"><font size="+2">Course</font></th>
  <td bgcolor="#FFDDDD" colspan="$num_uneditable">
      <b><font size="+1">Import</font></b></td>
  <td colspan="$num_left">
      <b><font size="+1">Calculations</font></b></td>
</tr><tr>
END
    my $label_num = 0;
    foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
        if ($label_num<$num_uneditable) { 
            $tableheader.='<th bgcolor="#FFDDDD">';
        } else {
            $tableheader.='<th>';
        }
        $tableheader.="<b><font size=+1>$_</font></b></th>";
        $label_num++;
    }
    $tableheader.="</tr>\n";
    #
    $r->print($tableheader);
    #
    # Print out template row
    $r->print('<tr><td>Template</td><td>&nbsp;</td>'.
	      $self->html_template_row($num_uneditable)."</tr>\n");
    #
    # Print out summary/export row
    $r->print('<tr><td>Summary</td><td>0</td>'.
	      $self->html_export_row()."</tr>\n");
    #
    # Prepare to output rows
    $tableheader =<<"END";
</p><p>
<table border="2">
<tr><th>Row</th>
  <th>student</th><th>username</th><th>domain</th>
  <th>section</th><th>status</th>
END
    foreach (split(//,'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz')){
	if ($label_num<$num_uneditable) { 
            $tableheader.='<th bgcolor="#FFDDDD">';
        } else {
            $tableheader.='<th>';
        }
        $tableheader.="<b><font size=+1>$_</font></b></th>";
    }
    #
    my $num_output = 0;
    foreach my $student ($self->get_classlist()) {
	if ($num_output++ % 50 == 0) {
	    $r->print("</table>\n".$tableheader);
	}
	my $rownum = $self->get_row_number_from_key
	    ($student->{'username'}.':'.$student->{'domain'});
        my $link = '<a href="/adm/studentcalc?sname='.$student->{'username'}.
            '&sdomain='.$student->{'domain'}.'">';
        $student->{'section'} = 'none' if ($student->{'section'} eq '-1');
	$r->print('<tr>'.'<td>'.$rownum.'</td>'.
		  '<td>'.$link.$student->{'fullname'}.'</a></td>'.
		  '<td>'.$student->{'username'}.'</td>'.
		  '<td>'.$student->{'domain'}  .'</td>'.
		  '<td>'.$student->{'section'} .'</td>'.
		  '<td>'.$student->{'status'}  .'</td>'.
		  $self->html_row($num_uneditable,$rownum)."</tr>\n");
    }
    $r->print("</table></p>\n");
    return;
}

sub outsheet_csv {
    my $self = shift;
    my ($r) = @_;
    $r->print('<h1>csv output is not supported yet</h1>');
}


sub excel_rows {
    # writes the meat of the spreadsheet to an excel worksheet.  Called
    # by Spreadsheet::outsheet_excel;
    my $self = shift;
    my ($worksheet,$cols_output,$rows_output) = @_;
    #
    # Write a header row
    $cols_output = 0;
    foreach my $value ('fullname','username','domain','section','status') {
        $worksheet->write($rows_output,$cols_output++,$value);
    }
    $rows_output++;    
    #
    # Write each students row
    foreach my $student ($self->get_classlist()) {
        $cols_output = 0;
	my $rownum = $self->get_row_number_from_key
	    ($student->{'username'}.':'.$student->{'domain'});
        $student->{'section'} = 'none' if ($student->{'section'} eq '-1');
        my @studentdata = ($student->{'fullname'},
                           $student->{'username'},
                           $student->{'domain'},
                           $student->{'section'},
                           $student->{'status'});
        $self->excel_output_row($worksheet,$rownum,$rows_output++,
                                @studentdata);
    }
    return;
}


sub outsheet_recursive_excel {
    my $self = shift;
    my ($r) = @_;
} 

sub compute {
    my $self = shift;
    my ($r) = @_;
    $self->initialize_safe_space();
    my %c = $self->constants();
    my %f = $self->formulas();
    my @Students = $self->get_classlist();
    my %prog_state=&Apache::lonhtmlcommon::Create_PrgWin
        ($r,'Spreadsheet Computation Status',
         'Spreadsheet Computation', scalar(@Students));
    &Apache::studentcalc::initialize_package();
    foreach my $student ($self->get_classlist()) {
        my $sname = $student->{'username'}.':'.$student->{'domain'};
	my $studentsheet = Apache::studentcalc->new
	    ($student->{'username'},$student->{'domain'},undef);
	my @exportdata = $studentsheet->export_data();
	my $rownum = $self->get_row_number_from_key($sname);
        $f{'A'.$rownum} = $sname;
        $self->{'row_source'}->{$rownum} = $sname;
        $c{'A'.$rownum} = shift(@exportdata);
	foreach (split(//,'BCDEFGHIJKLMNOPQRSTUVWXYZ')) {
            my $cell = $_.$rownum;
            my $data = shift(@exportdata);
            if (defined($data)) {
                $f{$cell} = 'import';
                $c{$cell} = $data;
            }
	}
        &Apache::lonhtmlcommon::Increment_PrgWin($r,\%prog_state,
                                                 'last student');
    }
    &Apache::lonhtmlcommon::Close_PrgWin($r,\%prog_state);
    $r->rflush();
    $self->constants(\%c);
    $self->formulas(\%f);
    $self->calcsheet();
}

1;

__END__