Return to lonsimplepage.pm CVS log

Up to [LON-CAPA] / loncom / interface

&coursegroups() and &get_group_settings() moved to longroup.pm, which contains general utility functions for asking about groups.  Also contains &group_changes() which is used to add/drop group memberships as a result of role changes, as determined by group settings for auto-add and auto-drop. 'none' and 'all' are now reserved words which may not be used as section or group names, so they can be used instead of _all and _none  when specifying auto-add and auto-drop settings for all sections or no section roles.

# The LearningOnline Network
# Simple Page Editor
#
# $Id: lonsimplepage.pm,v 1.40 2006/05/18 01:08:50 raeburn Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#

package Apache::lonsimplepage;

use strict;
use Apache::Constants qw(:common);
use Apache::loncommon;
use Apache::lonnet;
use Apache::lontexconvert;
use Apache::lonfeedback;
use Apache::lonlocal;
use Apache::lonprintout;
use Apache::lonxml;
use Apache::longroup;

sub handler {
    my $r = shift;
    &Apache::loncommon::content_type($r,'text/html');
    $r->send_http_header;
    return OK if $r->header_only;
    my $target=$env{'form.grade_target'};
# ------------------------------------------------------------ Print the screen
    if ($target eq 'tex') {
	$r->print(&Apache::lonprintout::print_latex_header($env{'form.latex_type'}));
    } 
    my (undef,undef,undef,undef,$marker,$caller)=split(/\//,$r->uri);
# Is this even in a course?
    unless ($env{'request.course.id'}) {
	if ($target ne 'tex') {
	    &Apache::loncommon::simple_error_page($r,'','Not in a course');
	} else {
	    $r->print('\textbf{Not in a course}\end{document}');
	}
	return OK;
    }

    my $dom = $env{'course.'.$env{'request.course.id'}.'.domain'};
    my $crs = $env{'course.'.$env{'request.course.id'}.'.num'};
    my $grp_view_permission = &Apache::lonnet::allowed('vcg',
                                                   $env{'request.course.id'});
    my $namespace;

    my %curr_group = ();
    my %groupinfo = ();
    if ($caller eq 'grppg') {
        $marker =~ s/\W//g;
        $namespace = 'grppage_'.$marker;
        my %curr_groups = &Apache::loncommon::coursegroups($dom,$crs,$marker);
        if (!%curr_groups) {
	    &Apache::loncommon::simple_error_page($r,'','Invalid group name');
	    return OK;
        }
        %groupinfo = 
	    &Apache::longroup::get_group_settings($curr_groups{$marker});
    } else {  
        $marker=~s/\D//g;
        $namespace = 'smppage_'.$marker;
    }

    if (!$marker) {
	&Apache::loncommon::simple_error_page($r,'','Invalid call');
	return OK;
    }

# --------------------------------------------------------- The syllabus fields
    my %syllabusfields=&Apache::lonlocal::texthash(
       'aaa_title'         => 'Page Title',
       'bbb_content'       => 'Content',
       'ccc_webreferences' => 'Web References');
    if ($caller eq 'grppg') {
        $syllabusfields{'abb_links'} = &mt('Functionality');
    }


# ------------------------------------------------------------ Get query string
    &Apache::loncommon::get_unprocessed_cgi
                        ($ENV{'QUERY_STRING'},['forcestudent','forceedit','register']);
# --------------------------------------------------------------- Force Student
    my $forcestudent='';
    if ($env{'form.forcestudent'} || $target eq 'tex' ) { $forcestudent='student'; };
    my $forceedit='';
    if ($env{'form.forceedit'}) { $forceedit='edit'; }

   
    my %syllabus=&Apache::lonnet::dump($namespace,$dom,$crs);
       
# --------------------------------------- There is such a user, get environment

    if ($target ne 'tex') {
        my $title = 'Course Page';
        if ($caller eq 'grppg') {
            $title = 'Group Page';
        }
	my $start_page = 
	    &Apache::loncommon::start_page($title,undef,
					   {'function'       => $forcestudent,
					    'domain'         => $dom,
					    'force_register' =>
						$env{'form.register'},});
	$r->print($start_page);
    }

    if ($caller eq 'grppg') {
        if (($grp_view_permission) || 
                           (&Apache::longroup::check_group_access($caller))) {
            unless(&Apache::lonnet::allowed('vgh',
                                      $env{'request.course.id'}.'/'.$marker)) {
                &display_group_links($r,$target,$marker,'view',%groupinfo);
                return OK;
            }
        } else {
	    my $msg = 
		&mt('You do not currently have rights to view this group.');
            if ($target ne 'tex') {
                $r->print("<p>$msg</p>".
			  &Apache::loncommon::end_page());
            } else {
                $r->print('\textbf{'.$msg.'}\end{document}');
            }
	    return OK;
        }
    }

    my $allowed;
    if ($caller eq 'grppg') {
        $allowed  = $grp_view_permission;
        unless ($allowed) {
            $allowed = &Apache::lonnet::allowed('mgh',$env{'request.course.id'}.
                                                                  '/'.$marker);
        }
    } else { 
        $allowed=&Apache::lonnet::allowed('mdc',$env{'request.course.id'});
    }
    my $privileged=$allowed;
    if (($syllabus{'uploaded.lastmodified'}) && (!$forceedit)) {
	$forcestudent='student';
    }

    if ($forcestudent or $target eq 'tex') { $allowed=0; }
    
    if ($allowed) {
	$r->print('<p>'.
		  &Apache::loncommon::help_open_topic('Uploaded_Templates_TextBoxes','Help with filling in text boxes').'<br /><a href="'.$r->uri.'?forcestudent=1"><font size="+1">'.&mt('Show Student View').'</font></a>'.
		  &Apache::loncommon::help_open_topic('Uploaded_Templates_PublicView').'</p>');
    } elsif ($privileged and $target ne 'tex') {
	$r->print('<a href="'.$r->uri.'?forceedit=edit"><font size="+1">'.&mt('Edit').'</font></a>');
    } 
    if (($env{'form.uploaddoc.filename'} and $target ne 'tex') &&
	($env{'form.storeupl'}) && ($allowed)) {
	if ($env{'form.uploaddoc.filename'}=~/\.(gif|jpg|png|jpeg)$/i) {
	    if ($syllabus{'uploaded.photourl'}) {
		&Apache::lonnet::removeuploadedurl($syllabus{'uploaded.photourl'});
	    }
            if ($caller eq 'grppage') {
                $syllabus{'uploaded.photourl'}=&Apache::lonnet::userfileupload(
                                              'uploaddoc',1,"grouppage/$marker");
            } else {
	        $syllabus{'uploaded.photourl'}=
		     &Apache::lonnet::userfileupload('uploaddoc',1,'simplepage');
            }
	}
	$syllabus{'uploaded.lastmodified'}=time;
	&Apache::lonnet::put($namespace,\%syllabus,$dom,$crs);
    }
    if (($allowed) && ($env{'form.storesyl'})) {
	foreach (keys %syllabusfields) {
	    my $field=$env{'form.'.$_};
	    chomp($field);
	    $field=~s/\s+$//s;
	    $field=~s/^\s+//s;
	    $field=~s/\<br\s*\/*\>$//s;
	    $field=&Apache::lonfeedback::clear_out_html($field,1);
	    $syllabus{$_}=$field;
	}
	$syllabus{'uploaded.lastmodified'}=time;
	&Apache::lonnet::put($namespace,\%syllabus,$dom,$crs);
    }

# ---------------------------------------------------------------- Get syllabus
    if (($syllabus{'uploaded.lastmodified'}) || ($allowed)) {
	if ($syllabus{'uploaded.photourl'}) {
	    &Apache::lonnet::allowuploaded('/adm/'.$caller,
					   $syllabus{'uploaded.photourl'});
	    
	    my $image='<img src="'.$syllabus{'uploaded.photourl'}.'"
                            align="right" />';
	    if ($target eq 'tex') {
		$image=&Apache::lonxml::xmlparse($r,'tex',$image);
	    }
	    $r->print($image);
	}
	if ($allowed) {
	    $r->print(
		      '<form method="post" enctype="multipart/form-data">'.
		      '<input type="hidden" name="forceedit" value="edit" />'.
		      '<h3>Upload a Photo</h3>'.
		      '<input type="file" name="uploaddoc" size="50">'.
		      '<input type="submit" name="storeupl" value="Upload">'.
		      '</form><form method="post">');
	}
	foreach (sort keys %syllabusfields) {
	    if (($syllabus{$_}) || ($allowed)) {
		my $message=$syllabus{$_};
		&Apache::lonfeedback::newline_to_br(\$message);
		$message
		    =~s/(https*\:\/\/[^\s]+)/\<a href=\"$1\"\>\<tt\>$1\<\/tt\>\<\/a\>/g;
		if ($allowed) {
		    $message=&Apache::lonspeller::markeduptext($message);
		}
		$message=&Apache::lontexconvert::msgtexconverted($message);
                if ($_ eq 'abb_links' && $caller eq 'grppg') {
                    $r->print('<br /><input type="hidden" name="'.$_.
                                          '" value="'.$syllabus{$_}.'" />');
                    &display_group_links($r,$target,$marker,'edit',%groupinfo);
                    $r->print('<br />');
                } elsif ($_ eq 'aaa_title') {
                    if ($target ne 'tex') {
                        $r->print('<h1>'.$message.'</h1>');
                    } else {
                        my $safeinit;
                        $r->print(&Apache::lonxml::xmlparse($r,'tex','<h1>'.$message.'</h1>'));
                    }
                    if ($allowed) {
                        if ($env{'form.grade_target'} ne 'tex') {
                            $r->print(
                                      '<br />Title<br /><textarea cols="80" rows="2" name="'.$_.'">'.
                                      $syllabus{$_}.
                                      '</textarea><input type="submit" name="storesyl" value="Store" />');
                        } else {
                            my $safeinit;
                            $r->print(&Apache::lonxml::xmlparse($r,'tex',$syllabus{$_},$safeinit));
                        }
                    }
                } else {
		    if (($_ ne 'bbb_content') || ($allowed)) {
			if ($target ne 'tex') {
			    $r->print('<h3>'.$syllabusfields{$_}.'</h3>');
			} else {
			    my $safeinit;
			    $r->print(&Apache::lonxml::xmlparse($r,'tex','<h3>'.$syllabusfields{$_}.'</h3>'));
			}
		    }
		    if ($target ne 'tex') {
			$r->print('<blockquote>'.
				  $message.'</blockquote>');
		    } else {
			my $safeinit;
			$r->print(&Apache::lonxml::xmlparse($r,'tex',$message));
		    }
		    if ($allowed) {
			if ($target ne 'tex') {
			    $r->print('<br /><textarea cols="80" rows="24" name="'.$_.'" id="'.$_.'">'.
				      $syllabus{$_}.
				      '</textarea><input type="submit" name="storesyl" value="Store" />');
			} else {
			    my $safeinit;
			    $r->print(&Apache::lonxml::xmlparse($r,'tex',$syllabus{$_},$safeinit));
			}
		    }
		}
	    }
	}
	if ($allowed && ($env{'form.grade_target'} ne 'tex')) {
	    $r->print(&Apache::lonhtmlcommon::htmlareaselectactive
		      ('bbb_content').'</form>');
	}
	if ($env{'form.grade_target'} ne 'tex') {$r->print('</p>');}
    } else {
	$r->print('<p>No page information provided.</p>');
    }
    if ($env{'form.grade_target'} ne 'tex') {
	$r->print(&Apache::loncommon::end_page());
    } else {
	$r->print('\end{document}');
    }
    return OK;
}

sub display_group_links {
    my ($r,$target,$marker,$context,%groupinfo) = @_;
    my @available = ();
    my %menu = ();
    %{$menu{'email'}} = (
                        text => 'Group e-mail',
                        href => '/adm/email?compose=group&group='.$marker,
                      );
    %{$menu{'discussion'}} = (
                        text => 'Discussion Boards',
                        href => '/adm/groupboards?group='.$marker,
                      );
    %{$menu{'chat'}} = (
                        text => 'Group chat',
                        href => "javascript:group_chat('$marker')",
                      );
    %{$menu{'files'}} = (
                        text => 'File repository',
                        href => '/adm/coursegrp_portfolio?group='.$marker,
                      );
    %{$menu{'roster'}} = (
                        text => 'Membership roster',
                        href => '/adm/grouproster?group='.$marker,
                      );
    foreach my $tool (sort(keys(%menu))) {
        if ($groupinfo{functions}{$tool} eq 'on') {
            push(@available,$tool);
        }
    }
    if (@available > 0) {
        my $output = '<table cellspacing="4" cellpadding="4"><tr>';
        foreach my $tool (@available) {
            if ($target eq 'tex') {
                $output .= '<td>'.$menu{$tool}{text}.'</td>';
            } else {
                $output .= '<td><a href="'.$menu{$tool}{href}.'">'.
                           $menu{$tool}{text}.'</a></td>';
            }
        }
        $output .= '</tr></table>';
        if ($target eq 'tex') {
            $r->print(&Apache::lonxml::xmlparse($r,'tex','Available functions<br /><br />'.$output));
        } else {
            $r->print('<h3>Functions</h3>'.$output);
        }
    } else {
        my $output;
        if ($context eq 'edit') {
            $output = 'No group functionality';
        } else {  
            $output = 'No group functionality (e.g., e-mail, discussion, chat or file upload) is currently available to you in this group: '.$marker;
        }
        if ($target eq 'tex') {
            $r->print(&Apache::lonxml::xmlparse($r,'tex',$output));
        } else {
            $r->print($output);
        }
    }
}
 

1;
__END__