[BACK]Return to lonhelp.pm CVS log [TXT] [DIR] Up to [LON-CAPA] / loncom / interface
File:  [LON-CAPA] / loncom / interface / lonhelp.pm
Revision 1.16: download - view: text, annotated - select for diffs
Thu Feb 17 08:29:42 2005 UTC (20 years, 2 months ago) by albertel
Branches: MAIN
CVS tags: HEAD
- <html> -> &Apache::lonxml::xmlbegin, thus valid doctypes are now getting output, Yeah! StandardsCmpliance

- backing out the encoding changes for now

- some xhtml cleanups
- one icon -> lonhttpd

# The LearningOnline Network with CAPA
# .tex help system web server handler
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# .tex file help handler
# YEAR=2002
# 7/4 Jeremy Bowers

package Apache::lonhelp;

use strict;
use Apache::Constants qw(:common :http);
use Apache::File();
use Apache::loncommon();
use Apache::lonacc();
use Apache::lontexconvert();
use Apache::lonnavmaps; # for advancedUser
use Apache::lonlocal;
use tth();
use GDBM_File();

# This sub takes the name of a label in, and converts it to something
# that is a valid anchor name.
sub processLabelName 
{
    my ($name) = @_;
    $name =~ tr/a-zA-Z0-9/_/cs;
    return $name;
}

# Serve out the Tex
sub serveTex
{
    my ($tex, $r) = @_;
    my $html=&Apache::lonxml::xmlbegin();
    my $bugs=&Apache::loncommon::help_open_bug('Documentation');
    my $header=&mt('LON-CAPA Help');
    my $footer=&mt('About LON-CAPA help and More Help');
    $r->print(<<HEADER);
$html
    <head>
        <title>LON-CAPA Help</title>
    </head>
    <body bgcolor="#FFFFFF">
    <h3 style="font: sans-serif"><img align="right"
    src="/adm/help/gif/lonhelpheader.gif"/>$header<hr />$bugs</h3>
    <!-- BEGIN -->
HEADER

    $r->print($tex);

    if (Apache::lonnavmaps::advancedUser()) {
$r->print(<<FOOTER);
    <!-- END -->
    <hr />
    <center><font size="-1"><a href="/adm/help/abouthelp.html">$footer</a></font></center>
    </body>
</html>
FOOTER
} else {
    $r->print(<<FOOTER);
    <!-- END -->
    </body>
</html>
FOOTER
}
}

# Render takes a tex fragment, transforms it for TtH, and returns the
# HTML equivalent
sub render 
{
    my ($tex, $docroot, $serverroot) = @_;
    tie (my %fragmentLabels, 'GDBM_File', $docroot . '/adm/help/fragmentLabels.gdbm', 0, 0);

    # This tells TtH what to do with captions, labels, and other
    # things
    $tex = "\\documentclass{article}\n" . $tex;

    # We process these ourselves because TtH can't handle then without
    # LaTeX .aux files
    # absolute paths for use with help.loncapa.org
    $tex =~ s|  \\ref\{([^}]*)\}
             |
              if (not(exists($fragmentLabels{$1}))) {
	          &Apache::lonnet::logthis("ERROR: $1 not a valid help label");
              };
             '\\begin{html}<a href="http://' . $serverroot ."/adm/help/".
              substr($fragmentLabels{$1}, 0, -4) .
              '.hlp#' . processLabelName($1) . 
             '"><img src="http://' . $serverroot . '/adm/help/gif/smallHelp.gif" border="0" /></a>' .
             '\\end{html}'
             |gxe;

    # Backslashes
    $tex =~ s|\\textbackslash|###BACKSLASH###|g;

    # Figures leftover without captions
    $tex =~ s|  \\includegraphics(\[[^]]*\])*\{([^}]*)\}
             |  '\\begin{html}<img src="http://' . $serverroot . '/adm/help/gif/' . $2 . '.gif" border="2"'.
                ' bordercolor="#000000"/>\\end{html}'
             |gxe;


    $tex=&Apache::lontexconvert::converted(\$tex);
    
    # Finish backslashes
    $tex =~ s/###BACKSLASH###/'\\'/ge;
 
    # Fix the pretty quotes
    $tex =~ s/('')|(``)/&quot;/g; #" to get emacs syntax highlighter happy

    # For some reason all captions come out as "Figure 0:", so
    # just duck the issue...

    $tex =~ s/Figure 0://g;
	     $tex.=$Apache::lontexconvert::errorstring;
    untie %fragmentLabels;

    return $tex;
}

sub handler
{
     my $r = shift;

     my $docroot = $r->dir_config('lonDocRoot');
     my $serverroot = $ENV{'HTTP_HOST'};

     my $filenames = &Apache::lonnet::unescape(substr ($ENV{'REQUEST_URI'} , 
			    rindex($ENV{'REQUEST_URI'}, '/') + 1, -4));
     
     # Security check on the file; the whole filename must consist
     # of nothing but alphanums, ' ,, or ., or the file
     # will be "not found", no matter what.
     
     return HTTP_NOT_FOUND if ($filenames !~ /\A[-0-9a-zA-z_'',:.]+\Z/);

     &Apache::lonlocal::get_language_handle($r);

     # Join together the tex files, return HTTP_NOT_FOUND if any of
     # them are not found
     my $tex = '';
     # Since in insertlist.tab I want to specify multiple files,
     # and insertlist.tab also uses commas, I need something else
     # so replace : with ,
     $filenames =~ s/:/,/g;
     my @files = split(/,/, $filenames);
     
     for my $filename (@files) {
	 if (-e $docroot.'/adm/help/tex/'.
	     &Apache::lonlocal::current_language().'/'.
	     $filename.'.tex') {
	     $filename=&Apache::lonlocal::current_language().'/'.$filename;
	 }
	 (my $file = Apache::File->new($docroot
			   . '/adm/help/tex/'.$filename.'.tex'))
	     or return HTTP_NOT_FOUND;
	 $tex .= join('', <$file>);
     }

     if ($ENV{'browser.mathml'}) {
	 &Apache::loncommon::content_type($r,'text/xml');
	 &tth::ttminit();
	 if ($ENV{'browser.unicode'}) {
	     &tth::ttmoptions('-L -u1');
	 } else {
	     &tth::ttmoptions('-L -u0');
	 }
     } else {
	 &Apache::loncommon::content_type($r,"text/html");
	 &tth::tthinit();
	 if ($ENV{'browser.unicode'}) {
	     &tth::tthoptions('-L -u1');
	 } else {
	     &tth::tthoptions('-L -u0');
	 }
     }

     $r->send_http_header;
     $tex = render($tex, $docroot, $serverroot);
     serveTex($tex, $r);

     return OK;
}

1;
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>