Return to response.pm CVS log

Up to [LON-CAPA] / loncom / homework

- fixing up analyze mode for radiobutton/option/rank/match/image to all use the smae code

# The LearningOnline Network with CAPA
# various response type definitons response definition
#
# $Id: response.pm,v 1.87 2003/10/27 19:27:09 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#

package Apache::response;
use strict;

BEGIN {
    &Apache::lonxml::register('Apache::response',('responseparam','parameter','dataresponse'));
}

sub start_response {
    my ($parstack,$safeeval)=@_;
    my $id= &Apache::lonxml::get_param('id',$parstack,$safeeval);
    if ($id eq '') { $id = $Apache::lonxml::curdepth; }
    if ($#Apache::inputtags::import > -1) {
	&Apache::lonxml::debug("Turning :$id: into");
	$id = join('_',@Apache::inputtags::import).'_'.$id;
	&Apache::lonxml::debug("New  :$id:");
    }
    push (@Apache::inputtags::response,$id);
    push (@Apache::inputtags::responselist,$id);
    @Apache::inputtags::inputlist=();
    return $id;
}

sub end_response {
    #pop @Apache::inputtags::response;
    @Apache::inputtags::inputlist=();
    return '';
}

sub start_hintresponse {
    my ($parstack,$safeeval)=@_;
    my $id= &Apache::lonxml::get_param('id',$parstack,$safeeval);
    if ($id eq '') { $id = $Apache::lonxml::curdepth; }
    push (@Apache::inputtags::response,$id);
    push (@Apache::inputtags::responselist,$id);
    push (@Apache::inputtags::paramstack,[%Apache::inputtags::params]);
    return $id;
}

sub end_hintresponse {
    pop @Apache::inputtags::response;
    if (defined($Apache::inputtags::paramstack[-1])) {
	%Apache::inputtags::params=
	    @{ pop(@Apache::inputtags::paramstack) };
    }
    return '';
}

# used by response to set the non-safe space random number generator to something
# that is stable and unique based on the part number and response number
sub setrandomnumber {
    my $rndseed;
    if ($ENV{'request.state'} eq "construct") {
	$rndseed=$ENV{'form.rndseed'};
	if (!$rndseed) { $rndseed=time; }
    } else {
	$rndseed=&Apache::lonnet::rndseed();
    }
    &Apache::lonxml::debug("randseed $rndseed");
    #  $rndseed=unpack("%32i",$rndseed);
    my $rndmod=(&Apache::lonnet::numval($Apache::inputtags::part) << 10);
    if (defined($Apache::inputtags::response['-1'])) {
       $rndmod+=&Apache::lonnet::numval($Apache::inputtags::response[-1]);
    }
    if ($rndseed =~/,/) {
	{
	    use integer;
	    my ($num1,$num2)=split(/,/,$rndseed);
	    $num1+=$rndmod;
	    $num2+=$rndmod;
	    $rndseed="$num1,$num2";
	}
    } else {
	$rndseed+=$rndmod;
    }
    &Apache::lonnet::setup_random_from_rndseed($rndseed);
    &Apache::lonxml::debug("randseed $rndseed");
    return '';
}

sub meta_parameter_write {
    my ($name,$type,$default,$display)=@_;
    my $partref=$Apache::inputtags::part;
    my $result='<parameter part="'.$Apache::inputtags::part.'"';
    if (defined($Apache::inputtags::response[-1])) {
	$result.=            ' id="'.$Apache::inputtags::response[-1].'"';
	$partref.='_'.$Apache::inputtags::response[-1];
    }
    $result.=            ' name="'.$name.'"'.
                         ' type="'.$type.'"'.
($default?' default="'.$default.'"':'').
($display?' display="'.$display.' [Part: '.$partref.']"':'')
             .'></parameter>'
             ."\n";
    return $result;
}

sub meta_package_write {
    my $name=shift;
    my $result = '<parameter part="'.$Apache::inputtags::part.'"';
    if(defined($Apache::inputtags::response[-1])) {
	$result.= ' id="'.$Apache::inputtags::response[-1].'"';
    }
    $result.=' package="'.$name.'"></parameter>'."\n";
    return $result;
}

sub meta_stores_write {
    my ($name,$type,$display)=@_;
    my $partref=$Apache::inputtags::part;
    my $result = '<stores part="'.$Apache::inputtags::part.'"';
    if (defined($Apache::inputtags::response[-1])) {
	$result.=           ' id="'.$Apache::inputtags::response[-1].'"';
	$partref.='_'.$Apache::inputtags::response[-1];
    }	
    $result.=          ' name="'.$name.'"'.
                       ' type="'.$type.'"'.
	            ' display="'.$display.' [Part: '.$partref.']"'.
		      "></stores>\n";
}

sub mandatory_part_meta {
#
# Autogenerate metadata for mandatory
# input (from RAT or lonparmset) and 
# output (to lonspreadsheet)
# of each part
#
    return
#    &meta_parameter_write('opendate','date_start','',
#                          'Opening Date').
#    &meta_parameter_write('duedate','date_end','',
#                          'Due Date').
#    &meta_parameter_write('answerdate','date_start','',
#                          'Show Answer Date').
#    &meta_parameter_write('weight','int_zeropos','',
#                          'Available Points').
#    &meta_parameter_write('maxtries','int_pos','',
#                          'Maximum Number of Tries').
	&meta_package_write('part').
        &meta_stores_write('solved','string',
			   'Problem Status').
        &meta_stores_write('tries','int_zeropos',
			   'Number of Attempts').
        &meta_stores_write('awarded','float',
			   'Partial Credit Factor');
#
# Note: responseid-specific data 'submission' and 'awarddetail'
# not available to spreadsheet -> skip here
#
}

sub meta_part_order {
    if (@Apache::inputtags::partlist) {
	my @parts=@Apache::inputtags::partlist;
	shift(@parts);
	return '<partorder>'.join(',',@parts).'</partorder>';
    } else {
	return '<partorder>0</partorder>';
    }
}

sub check_for_previous {
    my ($curresponse,$partid,$id) = @_;
    my %previous;
    $previous{'used'} = 0;
    foreach my $key (sort(keys(%Apache::lonhomework::history))) {
	if ($key =~ /resource\.$partid\.$id\.submission/) {
	    &Apache::lonxml::debug("Trying $key");
	    my $pastresponse=$Apache::lonhomework::history{$key};
	    if ($pastresponse eq $curresponse) {
		$previous{'used'} = 1;
		my $history;
		if ( $key =~ /^(\d+):/ ) {
		    $history=$1;
		    $previous{'award'} = $Apache::lonhomework::history{"$history:resource.$partid.$id.awarddetail"};
		    $previous{'last'}='0';
		    push(@{ $previous{'version'} },$history);
		} else {
		    $previous{'award'} = $Apache::lonhomework::history{"resource.$partid.$id.awarddetail"};
		    $previous{'last'}='1';
		}
		if (! $previous{'award'} ) { $previous{'award'} = 'UNKNOWN';	}
		&Apache::lonxml::debug("got a match :$previous{'award'}:$previous{'used'}:");
	    }
	}
    }
    &Apache::lonhomework::showhash(%previous);
    return %previous;
}

sub handle_previous {
    my ($previous,$ad)=@_;
    if ($$previous{'used'} && ($$previous{'award'} eq $ad) ) {
	if ($$previous{'last'}) {
	    push(@Apache::inputtags::previous,'PREVIOUSLY_LAST');
	} else {
	    push(@Apache::inputtags::previous,'PREVIOUSLY_USED');
	}
	push(@Apache::inputtags::previous_version,$$previous{'version'});
    }
}

sub view_or_modify {
    my ($symb,$courseid,$domain,$name) = &Apache::lonxml::whichuser();
    my $myself=0;
    if ( ($name eq $ENV{'user.name'}) && ($domain eq $ENV{'user.domain'}) ) {
	$myself=1;
    }
    my $vgr=&Apache::lonnet::allowed('vgr',$courseid);
    my $mgr=&Apache::lonnet::allowed('vgr',$courseid);
    if ($mgr) { return "M"; }
    if ($vgr) { return "V"; }
    if ($myself) { return "V"; }
    return '';
}

sub start_dataresponse {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $id = &Apache::response::start_response($parstack,$safeeval);
    my $result;
    if ($target eq 'web') {
	$result = $token->[2]->{'display'}.':';
    } elsif ($target eq 'meta') {
	$result = &Apache::response::meta_stores_write($token->[2]->{'name'},
						       $token->[2]->{'type'},
						       $token->[2]->{'display'});
	$result .= &Apache::response::meta_package_write('dataresponse');
    }
    return $result;
}

sub end_dataresponse {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result;
    if ( $target eq 'web' ) {
    } elsif ($target eq 'grade' ) {
	if ( defined $ENV{'form.submitted'}) {
	    my ($symb,$courseid,$domain,$name)=&Apache::lonxml::whichuser();
	    my $allowed=&Apache::lonnet::allowed('mgr',$courseid);
	    if ($allowed) {
		&Apache::response::setup_params('dataresponse');
		my $partid = $Apache::inputtags::part;
		my $id = $Apache::inputtags::response['-1'];
		my $response = $ENV{'form.HWVAL_'.$id};
		my $name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
		if ( $response =~ /[^\s]/) {
		    $Apache::lonhomework::results{"resource.$partid.$id.$name"}=$response;
		    $Apache::lonhomework::results{"resource.$partid.$id.submission"}=$response;
		    $Apache::lonhomework::results{"resource.$partid.$id.awarddetail"}='SUBMITTED';
		}
	    } else {
		$result='Not Permitted to change values.'
	    }
	}
    }
    &Apache::response::end_response;
    return $result;
}

sub decide_package {
    my ($tagstack)=@_;
    my $package;
    if ($$tagstack[-1] eq 'parameter') {
	$package='part';
    } else {
	my $i=-1;
	while (defined($$tagstack[$i])) {
	    if ($$tagstack[$i] =~ /(response|hint)$/) {
		$package=$$tagstack[$i];
		last;
	    }
	    $i--;
	}
    }
    return $package;
}

sub start_responseparam {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    my $result='';
    if ($target eq 'meta') {
	$result = &meta_parameter_write($token->[2]->{'name'},
					$token->[2]->{'type'},
					$token->[2]->{'default'},
					$token->[2]->{'description'});
    } elsif ($target eq 'edit') {
	$result.=&Apache::edit::tag_start($target,$token);
	my $optionlist;
	my $package=&decide_package($tagstack);
	foreach my $key (sort(keys(%Apache::lonnet::packagetab))) {
	    if ($key =~ /^\Q$package\E&(.*)&display$/) {
		$optionlist.='<option value="'.$1.'">'.
		    $Apache::lonnet::packagetab{$key}.'</option>';
	    }
	}
	if (defined($optionlist)) {
	    $result.='Use template: <select name="'.
		&Apache::edit::html_element_name('parameter_package').'">'.
		    '<option value=""></option>'.$optionlist.'</select><br />';
	}
	$result.=&Apache::edit::text_arg('Name:','name',$token).
	    &Apache::edit::text_arg('Type:','type',$token).
		&Apache::edit::text_arg('Description:','description',$token).
		    &Apache::edit::text_arg('Default:','default',$token).
			"</td></tr>";
	$result.=&Apache::edit::end_table;
    } elsif ($target eq 'modified') {
	my $constructtag=&Apache::edit::get_new_args($token,$parstack,
						     $safeeval,'name','type',
						     'description','default');
	my $element=&Apache::edit::html_element_name('parameter_package');
	if (defined($ENV{"form.$element"}) && $ENV{"form.$element"} ne '') {
	    my $name=$ENV{"form.$element"};
	    my $tag=&decide_package($tagstack);
	    $token->[2]->{'name'}=$name;
	    $token->[2]->{'type'}=
		$Apache::lonnet::packagetab{"$tag&$name&type"};
	    $token->[2]->{'description'}=
		$Apache::lonnet::packagetab{"$tag&$name&display"};
	    $token->[2]->{'default'}=
		$Apache::lonnet::packagetab{"$tag&$name&default"};
	    $constructtag=1;
	}
	if ($constructtag) {
	    $result = &Apache::edit::rebuild_tag($token);
	    $result.=&Apache::edit::handle_insert();
	}
    } elsif ($target eq 'grade' || $target eq 'answer' || $target eq 'web' ||
	     $target eq 'tex' || $target eq 'analyze' ) {
	if ($ENV{'request.state'} eq 'construct') {
	    my $name   =&Apache::lonxml::get_param('name',$parstack,$safeeval);
	    my $default=&Apache::lonxml::get_param('default',$parstack,
						     $safeeval);
	    if ($name) {$Apache::inputtags::params{$name}=$default;}
	}
    }
    return $result;
}

sub end_responseparam {
    my ($target,$token,$tagstack,$parstack,$parser,$safeeval)=@_;
    if ($target eq 'edit') { return ('','no'); }
    return '';
}

sub start_parameter {
    my $result = &start_responseparam(@_);
    return $result;
}

sub end_parameter {
    my $result = &end_responseparam(@_);
    return $result;
}

sub reset_params {
    %Apache::inputtags::params=();
}

sub setup_params {
    my ($tag) = @_;

    if ($ENV{'request.state'} eq 'construct') { return; }
    my %paramlist=();
    foreach my $key (keys(%Apache::lonnet::packagetab)) {
	if ($key =~ /^$tag/) {
	    my ($package,$name) = split(/&/,$key);
	    $paramlist{$name}=1;
	}
    }
    foreach my $key (keys(%paramlist)) {
	my $entry= 'resource.'.$Apache::inputtags::part;
	if (defined($Apache::inputtags::response[-1])) {
	    $entry.='_'.$Apache::inputtags::response[-1];
	}
	$entry.='.'.$key;
	&Apache::lonxml::debug("looking for $entry");
	my $value = &Apache::lonnet::EXT("$entry");
	&Apache::lonxml::debug("$key has value :$value:");
	if ($value eq 'con_lost' || $value =~ /^error:/) {
	    &Apache::lonxml::debug("using nothing");
	    $Apache::inputtags::params{$key}='';
	} else {
	    &Apache::lonxml::debug("using value");
	    $Apache::inputtags::params{$key}=$value;
	}
    }
}

sub answer_header {
    my ($type) = @_;
    my $result;
    if ($ENV{'form.answer_output_mode'} eq 'tex') {
	$result = ' \vskip 0 mm \begin{tabular}{|c|}\hline Answer for Part: \verb|'.
                  $Apache::inputtags::part.'| \\\\ \hline ';
    } else {
	$result = '<table border="1"><tr><td>Answer for Part:'.
	    $Apache::inputtags::part. '</td>'."\n";
    }
    return $result;
}

sub answer_part {
    my ($type,$answer) = @_;
    my $result;
    if ($ENV{'form.answer_output_mode'} eq 'tex') {
	$result = ' \verb|'.$answer.'|\\\\ \hline ';
    } else {
	$result = '<td>'.$answer.'</td>';
    }
    return $result;
}

sub answer_footer {
    my ($type) = @_;
    my $result;
    if ($ENV{'form.answer_output_mode'} eq 'tex') {
	$result = ' \end{tabular} \vskip 0 mm ';
    } else {
	$result = '</tr></table>';
    }
    return $result;
}

sub showallfoils {
    my $return=0;
    if (defined($ENV{'form.showallfoils'}) &&
	$ENV{'request.state'} eq 'construct') {
	$return=1;
    }
    return $return;
}

sub getresponse {
    my ($temp)=@_;
    my $formparm='form.HWVAL_'.$Apache::inputtags::response['-1'];
    my $response;
    if (!defined($temp)) {
	$temp=1;
    } else {
	$formparm.=":$temp";
    }
    my %let_to_num=('A'=>0,'B'=>1,'C'=>2,'D'=>3,'E'=>4,'F'=>5,'G'=>6,'H'=>7,
		    'I'=>8,'J'=>9,'K'=>10,'L'=>11,'M'=>12,'N'=>13,'O'=>14,
		    'P'=>15,'Q'=>16,'R'=>17,'S'=>18,'T'=>19,'U'=>20,'V'=>21,
		    'W'=>22,'X'=>23,'Y'=>24,'Z'=>25);
    if ($ENV{'form.submitted'} eq 'scantron') {
	my $part  = $Apache::inputtags::part;
	my $id    = $Apache::inputtags::response[-1];
	$response = $ENV{'scantron.'.($Apache::lonxml::counter+$temp-1).
			 '.answer'};
	# save bubbled letter for later
	$Apache::lonhomework::results{"resource.$part.$id.scantron"}.=
	    $response;
	$response = $let_to_num{$response};
    } else {
	$response = $ENV{$formparm};
    }
    return $response;
}

sub repetition {
    my $id = $Apache::inputtags::part;
    my $weight = &Apache::lonnet::EXT("resource.$id.weight");
    my $repetition = int $weight/9;
    if ($weight % 9 != 0) {$repetition++;} 
    return $repetition;
}

sub scored_response {
    my ($part,$id)=@_;
    my $repetition=&repetition();
    my $score=0;
    for (my $i=0;$i<$repetition;$i++) {
	my $increase=&Apache::response::getresponse($i+1);
	if ($increase ne '') { $score+=$increase+1; }
    }
    my $weight = &Apache::lonnet::EXT("resource.$part.weight");
    my $pcr=$score/$weight;
    $Apache::lonhomework::results{"resource.$part.$id.awarded"}=$pcr;
    $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=
	'ASSIGNED_SCORE';
    return $repetition;
}

sub whichorder {
    my ($max,$randomize,$showall,$hash)=@_;
    #&Apache::lonxml::debug("man $max randomize $randomize");
    if (!defined(@{ $$hash{'names'} })) { return; }
    my @names = @{ $$hash{'names'} };
    my @whichopt =();
    my (%top,@toplist,%bottom,@bottomlist);
    if (!($showall || ($randomize eq 'no'))) {
	my $current=0;
	foreach my $name (@names) {
	    $current++;
	    if ($$hash{"$name.location"} eq 'top') {
		$top{$name}=$current;
	    } elsif ($$hash{"$name.location"} eq 'bottom') {
		$bottom{$name}=$current;
	    }
	}
    }
    my $topcount=0;
    my $bottomcount=0;
    while (((scalar(@whichopt)+$topcount+$bottomcount) < $max || $showall)
	   && ($#names > -1)) {
	#&Apache::lonxml::debug("Have $#whichopt max is $max");
	my $aopt;
	if ($showall || ($randomize eq 'no')) {
	    $aopt=0;
	} else {
	    $aopt=int(&Math::Random::random_uniform() * ($#names+1));
	}
	#&Apache::lonxml::debug("From $#whichopt $max $#names elms, picking $aopt");
	$aopt=splice(@names,$aopt,1);
	#&Apache::lonxml::debug("Picked $aopt");
	if ($top{$aopt}) {
	    $toplist[$top{$aopt}]=$aopt;
	    $topcount++;
	} elsif ($bottom{$aopt}) {
	    $bottomlist[$bottom{$aopt}]=$aopt;
	    $bottomcount++;
	} else {
	    push (@whichopt,$aopt);
	}
    }
    for (my $i=0;$i<=$#toplist;$i++) {
	if ($toplist[$i]) { unshift(@whichopt,$toplist[$i]) }
    }
    for (my $i=0;$i<=$#bottomlist;$i++) {
	if ($bottomlist[$i]) { push(@whichopt,$bottomlist[$i]) }
    }

    return @whichopt;
}

sub show_answer {
    my $part   = $Apache::inputtags::part;
    my $award  = $Apache::lonhomework::history{"resource.$part.solved"};
    my $status = $Apache::inputtags::status[-1];
    return  ( ($award =~ /^correct/
	       && lc($Apache::lonhomework::problemstatus) ne 'no')
	      || $status eq "SHOW_ANSWER");
}

sub analyze_store_foilgroup {
    my ($shown,$attrs)=@_;
    my $part_id="$Apache::inputtags::part.$Apache::inputtags::response[-1]";
    foreach my $name (@{ $Apache::response::foilgroup{'names'} }) {
	if (defined($Apache::lonhomework::analyze{"$part_id.foil.value.$name"})) { next; }
	push (@{ $Apache::lonhomework::analyze{"$part_id.foils"} },$name);
	foreach my $attr (@$attrs) {
	    $Apache::lonhomework::analyze{"$part_id.foil.".$attr.".$name"} =
		$Apache::response::foilgroup{"$name.".$attr};
	}
    }
    push (@{ $Apache::lonhomework::analyze{"$part_id.shown"} }, @{ $shown });
}

sub pick_foil_for_concept {
    my ($target,$attrs,$hinthash,$parstack,$safeeval)=@_;
    if (not defined(@{ $Apache::response::conceptgroup{'names'} })) { return; }
    my @names = @{ $Apache::response::conceptgroup{'names'} };
    my $pick=int(&Math::Random::random_uniform() * ($#names+1));
    my $name=$names[$pick];
    push @{ $Apache::response::foilgroup{'names'} }, $name;
    foreach my $attr (@$attrs) {
	$Apache::response::foilgroup{"$name.".$attr} =
	    $Apache::response::conceptgroup{"$name.".$attr};
    }
    my $concept = &Apache::lonxml::get_param('concept',$parstack,$safeeval);
    $Apache::response::foilgroup{"$name.concept"} = $concept;
    &Apache::lonxml::debug("Selecting $name in $concept");
    my $part_id="$Apache::inputtags::part.$Apache::inputtags::response[-1]";
    if ($target eq 'analyze') {
	push (@{ $Apache::lonhomework::analyze{"$part_id.concepts"} },
	      $concept);
	$Apache::lonhomework::analyze{"$part_id.concept.$concept"}=
	    $Apache::response::conceptgroup{'names'};
	foreach my $name (@{ $Apache::response::conceptgroup{'names'} }) {
	    push (@{ $Apache::lonhomework::analyze{"$part_id.foils"} },
		  $name);
	    foreach my $attr (@$attrs) {
		$Apache::lonhomework::analyze{"$part_id.foil.$attr.$name"}=
		    $Apache::response::conceptgroup{"$name.$attr"};
	    }
	}
    }
    push(@{ $hinthash->{"$part_id.concepts"} },$concept);
    $hinthash->{"$part_id.concept.$concept"}=
	$Apache::response::conceptgroup{'names'};

}


1;
__END__
 

Internal Server Error

The server encountered an internal error or misconfiguration and was unable to complete your request.

Please contact the server administrator at root@localhost to inform them of the time this error occurred, and the actions you performed just before this error.

More information about this error may be available in the server error log.