Return to randomlylabel.pm CVS log

Up to [LON-CAPA] / loncom / homework

- subimages get placed properly
- missing subimages don't cause things to blow up and log an error

#!/usr/bin/perl
# The LearningOnline Network with CAPA
# randomlabel.png: composite together text and images into 1 image
#
# $Id: randomlylabel.pm,v 1.9 2003/05/13 19:08:31 albertel Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
###

package Apache::randomlylabel;

use strict;
use Image::Magick;
use Apache::Constants qw(:common);
use Apache::loncommon();
use GD;

sub get_image {
    my ($imgsrc,$set_trans)=@_;
    my $image;
    if ($imgsrc !~ /\.(png|jpg|jpeg)$/i) {
	my $conv_image = Image::Magick->new;
	my $current_figure = $conv_image->Read('filename'=>$imgsrc);
	$conv_image->Set('magick'=>'png');
	my @blobs=$conv_image->ImageToBlob();
	undef $conv_image;
	$image = GD::Image->new($blobs[0]);
    } else {
	GD::Image->trueColor(1);
	$image = GD::Image->new($imgsrc);
    }
    if ($set_trans && defined($image)) {
	my $white=$image->colorExact(255,255,255);
	if ($white != -1) { $image->transparent($white); }
    }
    return $image;
}

sub handler {
    my $r = shift;
    $r->content_type('image/png');
    my (undef,$token) = split(/=/,$ENV{'QUERY_STRING'});
    &Apache::loncommon::get_unprocessed_cgi(
               &Apache::lonnet::unescape($ENV{'imagerequest.'.$token}));
    my $image=&get_image($ENV{"form.BGIMG"},0);
    if (! defined($image)) {
        &Apache::lonnet::logthis('Unable to create image object for '.
				 $ENV{"form.BGIMG"});
        return OK;
    }
    #binmode(STDOUT);
    my $black;
    if (!($black=$image->colorResolve(0,0,0))) {
	$black = $image->colorClosestHWB(0,0,0);
    }
    for(my $i=0;$i<$ENV{"form.ICOUNT"};$i++) {
	my $subimage=&get_image($ENV{"form.IMG$i"},1);
	if (!defined($subimage)) {
            &Apache::lonnet::logthis('Unable to create image object for '.
                                 $ENV{"form.BGIMG"});
            next;
        }
	$image->copy($subimage,$ENV{"form.IX$i"},$ENV{"form.IY$i"},
		     0,0,$subimage->getBounds());
    }
    my $height=GD::Font->Giant->height;
    for(my $i=0;$i<$ENV{"form.COUNT"};$i++) {
	$image->string(gdGiantFont,$ENV{"form.X$i"},$ENV{"form.Y$i"}-$height,
		       $ENV{"form.LB$i"},$black);
    }
    $r->print($image->png);
    return OK;
}

1;