1: # The LearningOnline Network with CAPA
2: # mutliple choice style responses
3: #
4: # $Id: radiobuttonresponse.pm,v 1.148.2.1 2011/09/16 23:14:28 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
22: #
23: # /home/httpd/html/adm/gpl.txt
24: #
25: # http://www.lon-capa.org/
26: #
27:
28:
29:
30: package Apache::radiobuttonresponse;
31: use strict;
32: use HTML::Entities();
33: use Apache::lonlocal;
34: use Apache::lonnet;
35: use Apache::response;
36:
37: my $default_bubbles_per_line = 10;
38:
39:
40: BEGIN {
41: &Apache::lonxml::register('Apache::radiobuttonresponse',('radiobuttonresponse'));
42: }
43:
44: sub bubble_line_count {
45: my ($numfoils, $bubbles_per_line) = @_;
46: my $bubble_lines;
47: $bubble_lines = int($numfoils / $bubbles_per_line);
48: if (($numfoils % $bubbles_per_line) != 0) {
49: $bubble_lines++;
50: }
51: return $bubble_lines;
52:
53: }
54:
55:
56: sub start_radiobuttonresponse {
57: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
58: my $result;
59:
60: #when in a radiobutton response use these
61: &Apache::lonxml::register('Apache::radiobuttonresponse',('foilgroup','foil','conceptgroup'));
62: push (@Apache::lonxml::namespace,'radiobuttonresponse');
63: my $id = &Apache::response::start_response($parstack,$safeeval);
64:
65: %Apache::hint::radiobutton=();
66: undef(%Apache::response::foilnames);
67: if ($target eq 'meta') {
68: $result=&Apache::response::meta_package_write('radiobuttonresponse');
69: } elsif ($target eq 'edit' ) {
70: $result.=&Apache::edit::start_table($token)
71: .'<tr><td>'.&Apache::lonxml::description($token)
72: .&Apache::loncommon::help_open_topic('Radio_Response_Problems')
73: .'</td>'
74: .'<td><span class="LC_nobreak">'.&mt('Delete?').' '
75: .&Apache::edit::deletelist($target,$token)
76: .'</span></td>'
77: .'<td> '.&Apache::edit::end_row()
78: .&Apache::edit::start_spanning_row();
79: $result.=
80: &Apache::edit::text_arg('Max Number Of Shown Foils:','max',
81: $token,'4').' 'x 3 .
82: &Apache::edit::select_arg('Randomize Foil Order:','randomize',
83: ['yes','no'],$token).' 'x 3 .
84: &Apache::edit::select_arg('Display Direction:','direction',
85: ['vertical','horizontal'],$token).
86: &Apache::edit::end_row().
87: &Apache::edit::start_spanning_row()."\n";
88: } elsif ($target eq 'modified') {
89: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
90: $safeeval,'max',
91: 'randomize','direction');
92: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
93: } elsif ($target eq 'tex') {
94: my $type=&Apache::lonxml::get_param('TeXtype',$parstack,$safeeval,
95: undef,0);
96: if ($type eq '1') {
97: $result .= ' \renewcommand{\labelenumi}{\arabic{enumi}.}';
98: } elsif ($type eq 'A') {
99: $result .= ' \renewcommand{\labelenumi}{\Alph{enumi}.}';
100: } elsif ($type eq 'a') {
101: $result .= ' \renewcommand{\labelenumi}{\alph{enumi}.}';
102: } elsif ($type eq 'i') {
103: $result .= ' \renewcommand{\labelenumi}{\roman{enumi}.}';
104: } else {
105: $result .= ' \renewcommand{\labelenumi}{\Alph{enumi}.}';
106: }
107: if($env{'form.pdfFormFields'} eq 'yes' && $Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
108: $result .= '\begin{itemize}';
109: } else {
110: $result .= '\begin{enumerate}';
111: }
112: } elsif ($target eq 'analyze') {
113: my $part_id="$Apache::inputtags::part.$id";
114: $Apache::lonhomework::analyze{"$part_id.type"} = 'radiobuttonresponse';
115: push (@{ $Apache::lonhomework::analyze{"parts"} },$part_id);
116: }
117: return $result;
118: }
119:
120: sub end_radiobuttonresponse {
121: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
122: my $result;
123: if ($target eq 'edit') { $result=&Apache::edit::end_table(); }
124: if ($target eq 'tex' ) {
125: if($env{'form.pdfFormFields'} eq 'yes' and $Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
126: $result .= '\end{itemize}';
127: } else {
128: $result .= '\end{enumerate}';
129: }
130: }
131: &Apache::response::end_response;
132: pop @Apache::lonxml::namespace;
133: &Apache::lonxml::deregister('Apache::radiobuttonresponse',('foilgroup','foil','conceptgroup'));
134: undef(%Apache::response::foilnames);
135: return $result;
136: }
137:
138: %Apache::response::foilgroup=();
139: sub start_foilgroup {
140: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
141: my $result;
142: %Apache::response::foilgroup=();
143: $Apache::radiobuttonresponse::conceptgroup=0;
144: &Apache::response::pushrandomnumber(undef,$target);
145: if ($target eq 'tex' && $Apache::lonhomework::type eq 'exam') {
146: $result.='\item[\textbf{'.$Apache::lonxml::counter.'}.]';
147: }
148: return $result;
149: }
150:
151: sub storesurvey {
152: my ($style) = @_;
153: if ( !&Apache::response::submitted() ) { return ''; }
154: my $response = $env{'form.HWVAL_'.$Apache::inputtags::response['-1']};
155: &Apache::lonxml::debug("Here I am!:$response:");
156: if ( $response !~ /[0-9]+/) { return ''; }
157: my $part = $Apache::inputtags::part;
158: my $id = $Apache::inputtags::response['-1'];
159: my @whichfoils=@{ $Apache::response::foilgroup{'names'} };
160: my %responsehash;
161: $responsehash{$whichfoils[$response]}=$response;
162: my $responsestr=&Apache::lonnet::hash2str(%responsehash);
163: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
164: $responsestr;
165: my %previous=&Apache::response::check_for_previous($responsestr,$part,$id);
166: my $ad;
167: if ($style eq 'anonsurvey') {
168: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='ANONYMOUS';
169: } elsif ($style eq 'anonsurveycred') {
170: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='ANONYMOUS_CREDIT';
171: } elsif ($style eq 'surveycred') {
172: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='SUBMITTED_CREDIT';
173: } else {
174: $ad=$Apache::lonhomework::results{"resource.$part.$id.awarddetail"}='SUBMITTED';
175: }
176: &Apache::response::handle_previous(\%previous,$ad);
177: &Apache::lonxml::debug("submitted a $response<br />\n");
178: return '';
179: }
180:
181:
182: sub grade_response {
183: my ($answer, $whichfoils, $bubbles_per_line)=@_;
184:
185: if ( !&Apache::response::submitted() ) { return; }
186: my $response;
187:
188: if ($env{'form.submitted'} eq 'scantron') {
189: $response = &Apache::response::getresponse(1,undef,
190: &bubble_line_count(scalar(@{ $whichfoils}),
191: $bubbles_per_line),
192: $bubbles_per_line);
193:
194: } else {
195: $response = $env{'form.HWVAL_'.$Apache::inputtags::response['-1']};
196: }
197:
198:
199: if ( $response !~ /[0-9]+/) { return; }
200: my $part=$Apache::inputtags::part;
201: my $id = $Apache::inputtags::response['-1'];
202: my %responsehash;
203: $responsehash{$whichfoils->[$response]}=$response;
204: my $responsestr=&Apache::lonnet::hash2str(%responsehash);
205: my %previous=&Apache::response::check_for_previous($responsestr,
206: $part,$id);
207: $Apache::lonhomework::results{"resource.$part.$id.submission"}=
208: $responsestr;
209: &Apache::lonxml::debug("submitted a $response<br />\n");
210: my $ad;
211: if ($response == $answer) {
212: $ad='EXACT_ANS';
213: } else {
214: $ad='INCORRECT';
215: }
216: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$ad;
217: &Apache::response::handle_previous(\%previous,$ad);
218: }
219:
220: sub end_foilgroup {
221: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
222:
223: my $result;
224: my $bubble_lines;
225: my $bubbles_per_line;
226: my $answer_count;
227: my $id = $Apache::inputtags::response['-1'];
228: my $part = $Apache::inputtags::part;
229: $bubbles_per_line =
230: &Apache::response::get_response_param($Apache::inputtags::part."_$id",
231: 'numbubbles',
232: $default_bubbles_per_line);
233:
234:
235: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
236: $target eq 'tex' || $target eq 'analyze') {
237: my $style = $Apache::lonhomework::type;
238: my $direction = &Apache::lonxml::get_param('direction',$parstack,
239: $safeeval,'-2');
240: if ( (($style eq 'survey') || ($style eq 'surveycred') ||
241: ($style eq 'anonsurvey') || ($style eq 'anonsurveycred'))
242: && ($target ne 'analyze')) {
243: if ($target eq 'web' || $target eq 'tex') {
244: $result=&displayallfoils($direction, $target);
245: } elsif ( $target eq 'answer' ) {
246: $result=&displayallanswers();
247: } elsif ( $target eq 'grade' ) {
248: $result=&storesurvey($style);
249: }
250: $answer_count = scalar(@{$Apache::response::foilgroup{'names'}});
251:
252: } else {
253:
254: my $name;
255: my $max = &Apache::lonxml::get_param('max',$parstack,$safeeval,
256: '-2');
257: my $randomize = &Apache::lonxml::get_param('randomize',$parstack,
258: $safeeval,'-2');
259: my ($answer, @shown) = &whichfoils($max, $randomize);
260: $answer_count = scalar(@shown);
261:
262: if ($target eq 'web' || $target eq 'tex') {
263: $result=&displayfoils($target,
264: $answer, \@shown,
265: $direction,
266: $bubbles_per_line);
267: } elsif ($target eq 'answer' ) {
268: $result=&displayanswers($answer, \@shown, $bubbles_per_line);
269: } elsif ( $target eq 'grade') {
270: &grade_response($answer, \@shown, $bubbles_per_line);
271: } elsif ( $target eq 'analyze') {
272: my $bubble_lines = &bubble_line_count($answer_count,
273: $bubbles_per_line);
274: &Apache::response::analyze_store_foilgroup(\@shown,
275: ['text','value','location']);
276: my $part_id="$part.$id";
277: push (@{ $Apache::lonhomework::analyze{"$part_id.options"} },
278: ('true','false'));
279:
280: }
281: }
282: $Apache::lonxml::post_evaluate=0;
283: }
284: if ($target eq 'web') {
285: &Apache::response::setup_prior_tries_hash(\&format_prior_answer,
286: [\%Apache::response::foilgroup]);
287: }
288: &Apache::response::poprandomnumber();
289: $bubble_lines = &bubble_line_count($answer_count, $bubbles_per_line);
290: &Apache::lonxml::increment_counter($bubble_lines,
291: "$part.$id");
292: if ($target eq 'analyze') {
293: &Apache::lonhomework::set_bubble_lines();
294: }
295: return $result;
296: }
297:
298: sub getfoilcounts {
299: my @names;
300: my $truecnt=0;
301: my $falsecnt=0;
302: my $name;
303: if ( $Apache::response::foilgroup{'names'} ) {
304: @names= @{ $Apache::response::foilgroup{'names'} };
305: }
306: foreach $name (@names) {
307: if ($Apache::response::foilgroup{$name.'.value'} eq 'true') {
308: $truecnt++;
309: } elsif ($Apache::response::foilgroup{$name.'.value'} eq 'false') {
310: $falsecnt++;
311: }
312: }
313: return ($truecnt,$falsecnt);
314: }
315:
316: sub format_prior_answer {
317: my ($mode,$answer,$other_data) = @_;
318: my $foil_data = $other_data->[0];
319: my %response = &Apache::lonnet::str2hash($answer);
320: my ($name) = keys(%response);
321: return '<span class="LC_prior_radiobutton">'.
322: $foil_data->{$name.'.text'}.'</span>';
323:
324: }
325:
326: sub displayallfoils {
327: my ($direction, $target)=@_;
328: my $result;
329: &Apache::lonxml::debug("survey style display");
330: my @names;
331: if ( $Apache::response::foilgroup{'names'} ) {
332: @names= @{ $Apache::response::foilgroup{'names'} };
333: }
334:
335: my $temp=0;
336: my $i =0;
337: my $id=$Apache::inputtags::response['-1'];
338: my $part=$Apache::inputtags::part;
339: my ($lastresponse,$newvariation,$showanswer);
340: if ((($Apache::lonhomework::history{"resource.$part.type"} eq 'randomizetry') ||
341: ($Apache::lonhomework::type eq 'randomizetry')) &&
342: ($Apache::inputtags::status[-1] eq 'CAN_ANSWER')) {
343: if ($env{'form.'.$part.'.rndseed'} ne
344: $Apache::lonhomework::history{"resource.$part.rndseed"}) {
345: $newvariation = 1;
346: }
347: }
348: $showanswer = &Apache::response::show_answer();
349: unless ((($Apache::lonhomework::history{"resource.$part.type"} eq 'anonsurvey') || ($Apache::lonhomework::history{"resource.$part.type"} eq 'anonsurveycred')) && (defined($env{'form.grade_symb'})) ||
350: ($newvariation && !$showanswer)) {
351: $lastresponse =
352: $Apache::lonhomework::history{"resource.$part.$id.submission"};
353: }
354: if ($direction eq 'horizontal') { $result.='<table><tr>'; }
355: my %lastresponse=&Apache::lonnet::str2hash($lastresponse);
356: if ($showanswer) {
357: foreach my $name (@names) {
358: if ($Apache::response::foilgroup{$name.'.value'} ne 'unused') {
359: if (($direction eq 'horizontal') && ($target ne 'tex')) {
360: $result.="<td>";
361: } else {
362: if ($target eq 'tex') {
363: $result .= '\item \vskip -2mm ';
364: } else {
365: $result.="<br />";
366: }
367: }
368: if (defined($lastresponse{$name})) {
369: if ($target eq 'tex') {
370: $result .= '}';
371: } else {
372: $result.='<b>';
373: }
374: }
375: $result .= $Apache::response::foilgroup{$name.'.text'};
376: if (defined($lastresponse{$name}) && ($target ne 'tex')) {
377: $result.='</b>';
378: }
379: if (($direction eq 'horizontal') && ($target ne 'tex')) { $result.="</td>"; }
380: }
381: }
382: } else {
383: foreach my $name (@names) {
384: if ($Apache::response::foilgroup{$name.'.value'} ne 'unused') {
385: if ($direction eq 'horizontal') {
386: $result.="<td>";
387: } else {
388: if ($target eq 'tex') {
389: if($env{'form.pdfFormFields'} eq 'yes' && $Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
390: my $fieldname = $env{'request.symb'}.'&part_'. $Apache::inputtags::part
391: .'&radiobuttonresponse'.'&HWVAL_'.$Apache::inputtags::response['-1'];
392: $result .= '\item[{'.&Apache::lonxml::print_pdf_radiobutton($fieldname,$temp).'}]'
393: .$Apache::response::foilgroup{$name.'.text'}."\n";
394: } else {
395: $result .= '\item \vskip -2mm ';
396: }
397: } else {
398: $result.="<br />";
399: }
400: }
401: if ($target eq 'tex') {
402: if($env{'form.pdfFormFields'} ne 'yes' or $Apache::inputtags::status[-1] ne 'CAN_ANSWER') {
403: $result .= '$\bigcirc$'.$Apache::response::foilgroup{$name.'.text'}.'\\\\'; #' stupid emacs
404: }
405: $i++;
406: } else {
407: $result .= '<label>';
408: $result.="<input
409: onchange=\"javascript:setSubmittedPart('$part');\"
410: type=\"radio\"
411: name=\"HWVAL_$Apache::inputtags::response['-1']\"
412: value=\"$temp\"";
413:
414: if (defined($lastresponse{$name})) { $result .= ' checked="checked"'; }
415: $result .= ' />'.$Apache::response::foilgroup{$name.'.text'}.
416: '</label>';
417: }
418: $temp++;
419: if ($target ne 'tex') {
420: if (($direction eq 'horizontal') && ($target ne 'tex')) { $result.="</td>"; }
421: } else {
422: $result.='\vskip 0 mm ';
423: }
424: }
425: }
426: }
427:
428: if (($direction eq 'horizontal') && ($target ne 'tex')) { $result.='</tr></table>'; }
429: return $result;
430: }
431:
432:
433: sub whichfoils {
434: my ($max,$randomize)=@_;
435:
436: my @truelist;
437: my @falselist;
438: my @whichfalse =();
439: my ($truecnt,$falsecnt) = &getfoilcounts();
440: my $count=0;
441: # we will add in 1 of the true statements
442: if ( $max>0 && ($falsecnt+1)>$max) { $count=$max } else { $count=$falsecnt+1; $max=$count; }
443: my $answer=int(&Math::Random::random_uniform() * ($count));
444: &Apache::lonxml::debug("Count is $count, $answer is $answer");
445: my @names;
446: if ( $Apache::response::foilgroup{'names'} ) {
447: @names= @{ $Apache::response::foilgroup{'names'} };
448: }
449: if (&Apache::response::showallfoils()) {
450: @whichfalse=@names;
451: } elsif ($randomize eq 'no') {
452: &Apache::lonxml::debug("No randomization");
453: my $havetrue=0;
454: foreach my $name (@names) {
455: if ($Apache::response::foilgroup{$name.'.value'} eq 'true') {
456: if (!$havetrue ) {
457: push(@whichfalse,$name); $havetrue++; $answer=$#whichfalse;
458: }
459: } elsif ($Apache::response::foilgroup{$name.'.value'} eq 'false') {
460: push (@whichfalse,$name);
461: } elsif ($Apache::response::foilgroup{$name.'.value'} eq 'unused') {
462: } else {
463: &Apache::lonxml::error(&HTML::Entities::encode("No valid value assigned ($Apache::response::foilgroup{$name.'.value'}) for foil $name in <foilgroup>",'<>&"'));
464: }
465: }
466: if ((!$havetrue) &&
467: ($Apache::lonhomework::type ne 'survey') &&
468: ($Apache::lonhomework::type ne 'surveycred') &&
469: ($Apache::lonhomework::type ne 'anonsurvey') &&
470: ($Apache::lonhomework::type ne 'anonsurveycred')) {
471: &Apache::lonxml::error(&mt('There are no true statements available.').'<br />');
472: }
473: } else {
474: my $current=0;
475: &Apache::lonhomework::showhash(%Apache::response::foilgroup);
476: my (%top,%bottom);
477: #first find out where everyone wants to be
478: foreach my $name (@names) {
479: $current++;
480: if ($Apache::response::foilgroup{$name.'.value'} eq 'true') {
481: push (@truelist,$name);
482: if ($Apache::response::foilgroup{$name.'.location'} eq 'top') {
483: $top{$name}=$current;
484: } elsif ($Apache::response::foilgroup{$name.'.location'} eq 'bottom') {
485: $bottom{$name}=$current;
486: }
487: } elsif ($Apache::response::foilgroup{$name.'.value'} eq 'false') {
488: push (@falselist,$name);
489: if ($Apache::response::foilgroup{$name.'.location'} eq 'top') {
490: $top{$name}=$current;
491: } elsif ($Apache::response::foilgroup{$name.'.location'} eq 'bottom') {
492: $bottom{$name}=$current;
493: }
494: } elsif ($Apache::response::foilgroup{$name.'.value'} eq 'unused') {
495: } else {
496: &Apache::lonxml::error(&HTML::Entities::encode("No valid value assigned ($Apache::response::foilgroup{$name.'.value'}) for foil $name in <foilgroup>",'<>&"'));
497: }
498: }
499: #pick a true statement
500: my $notrue=0;
501: if (scalar(@truelist) == 0) { $notrue=1; }
502: my $whichtrue = int(&Math::Random::random_uniform() * ($#truelist+1));
503: &Apache::lonxml::debug("Max is $max, From $#truelist elms, picking $whichtrue");
504: my (@toplist, @bottomlist);
505: my $topcount=0;
506: my $bottomcount=0;
507: # assign everyone to either toplist/bottomlist or whichfalse
508: # which false is randomized, toplist bottomlist are in order
509: while ((($#whichfalse+$topcount+$bottomcount) < $max-2) && ($#falselist > -1)) {
510: &Apache::lonxml::debug("Have $#whichfalse max is $max");
511: my $afalse=int(&Math::Random::random_uniform() * ($#falselist+1));
512: &Apache::lonxml::debug("From $#falselist elms, picking $afalse");
513: $afalse=splice(@falselist,$afalse,1);
514: &Apache::lonxml::debug("Picked $afalse");
515: &Apache::lonhomework::showhash(('names'=>\@names));
516: &Apache::lonhomework::showhash(%top);
517: if ($top{$afalse}) {
518: $toplist[$top{$afalse}]=$afalse;
519: $topcount++;
520: } elsif ($bottom{$afalse}) {
521: $bottomlist[$bottom{$afalse}]=$afalse;
522: $bottomcount++;
523: } else {
524: push (@whichfalse,$afalse);
525: }
526: }
527: &Apache::lonxml::debug("Answer wants $answer");
528: my $truename=$truelist[$whichtrue];
529: my $dosplice=1;
530: if (($notrue) &&
531: ($Apache::lonhomework::type ne 'survey') &&
532: ($Apache::lonhomework::type ne 'surveycred') &&
533: ($Apache::lonhomework::type ne 'anonsurvey') &&
534: ($Apache::lonhomework::type ne 'anonsurveycred')) {
535: $dosplice=0;
536: &Apache::lonxml::error(&mt('There are no true statements available.').'<br />');
537: }
538: #insert the true statement, keeping track of where it wants to be
539: if ($Apache::response::foilgroup{$truename.'.location'} eq 'top' && $dosplice) {
540: $toplist[$top{$truename}]=$truename;
541: $answer=-1;
542: foreach my $top (reverse(@toplist)) {
543: if ($top) { $answer++;}
544: if ($top eq $truename) { last; }
545: }
546: $dosplice=0;
547: } elsif ($Apache::response::foilgroup{$truename.'.location'} eq 'bottom' && $dosplice) {
548: $bottomlist[$bottom{$truename}]=$truename;
549: $answer=-1;
550: foreach my $bot (@bottomlist) {
551: if ($bot) { $answer++;}
552: if ($bot eq $truename) { last; }
553: }
554: $answer+=$topcount+$#whichfalse+1;
555: $dosplice=0;
556: } else {
557: if ($topcount>0 || $bottomcount>0) {
558: my $inc = 1;
559: if (($bottomcount > 0) && ($Apache::lonhomework::type ne 'exam')) {
560: $inc = 2;
561: }
562: $answer=int(&Math::Random::random_uniform() * ($#whichfalse+$inc))
563: + $topcount;
564:
565: }
566: }
567: &Apache::lonxml::debug("Answer now wants $answer");
568: #add the top items to the top, bottom items to the bottom
569: for (my $i=0;$i<=$#toplist;$i++) {
570: if ($toplist[$i]) { unshift(@whichfalse,$toplist[$i]) }
571: }
572: for (my $i=0;$i<=$#bottomlist;$i++) {
573: if ($bottomlist[$i]) { push(@whichfalse,$bottomlist[$i]) }
574: }
575: #if the true statement is randomized insert it into the list
576: if ($dosplice) { splice(@whichfalse,$answer,0,$truelist[$whichtrue]); }
577: }
578: &Apache::lonxml::debug("Answer is $answer");
579: return ($answer,@whichfalse);
580: }
581:
582: sub displayfoils {
583: my ($target,$answer,$whichfoils,$direction, $bubbles_per_line)=@_;
584: my $result;
585:
586: my $part=$Apache::inputtags::part;
587: my $solved=$Apache::lonhomework::history{"resource.$part.solved"};
588: if ( ($target ne 'tex') &&
589: &Apache::response::show_answer() ) {
590: if ($direction eq 'horizontal') {
591: if ($target ne 'tex') {
592: $result.='<table><tr>';
593: }
594: }
595: foreach my $name (@{ $whichfoils }) {
596: if ($direction eq 'horizontal') {
597: if ($target ne 'tex') { $result.='<td>'; }
598: }
599: if ($target ne 'tex') {
600: $result.="<br />";
601: } else {
602: $result.='\item \vskip -2 mm ';
603: }
604: if ($Apache::response::foilgroup{$name.'.value'} eq 'true') {
605: if ($target ne 'tex') {
606: $result.=&mt('Correct:').'<b>';
607: } else {
608: $result.=&mt('Correct:').' \textbf{';
609: }
610: } else {
611: $result.=&mt('Incorrect:');
612: }
613: if ($target eq 'web') { $result.="<label>"; }
614: $result.=$Apache::response::foilgroup{$name.'.text'};
615: if ($target eq 'web') { $result.="</label>"; }
616: if ($Apache::response::foilgroup{$name.'.value'} eq 'true') {
617: if ($target ne 'tex') { $result.='</b>';} else {$result.='}';}
618: }
619: if ($direction eq 'horizontal') {
620: if ($target ne 'tex') { $result.='</td>'; }
621: }
622: }
623: if ($direction eq 'horizontal') {
624: if ($target ne 'tex') {
625: $result.='</tr></table>';
626: }
627: }
628: } else {
629: my @alphabet = ('A'..'Z');
630: my $i = 0;
631: my $bubble_number = 0;
632: my $line = 0;
633: my $temp=0;
634: my $id=$Apache::inputtags::response['-1'];
635: my $part=$Apache::inputtags::part;
636: my ($lastresponse,$newvariation);
637: if ((($Apache::lonhomework::history{"resource.$part.type"} eq 'randomizetry') ||
638: ($Apache::lonhomework::type eq 'randomizetry')) &&
639: ($Apache::inputtags::status[-1] eq 'CAN_ANSWER')) {
640: if ($env{'form.'.$part.'.rndseed'} ne
641: $Apache::lonhomework::history{"resource.$part.rndseed"}) {
642: $newvariation = 1;
643: }
644: }
645: unless ($newvariation) {
646: $lastresponse=$Apache::lonhomework::history{"resource.$part.$id.submission"};
647: }
648: my %lastresponse=&Apache::lonnet::str2hash($lastresponse);
649: if ($target ne 'tex' && $direction eq 'horizontal') {
650: $result.="<table><tr>";
651: }
652: foreach my $name (@{ $whichfoils }) {
653: if ($target ne 'tex') {
654: if ($direction eq 'horizontal') {
655: $result.="<td>";
656: } else {
657: $result.="<br />";
658: }
659: }
660: if ($target ne 'tex') {
661: $result.= '<label>';
662: $result.=
663: "<input type=\"radio\"
664: onchange=\"javascript:setSubmittedPart('$part');\"
665: name=\"HWVAL_$Apache::inputtags::response['-1']\"
666: value=\"$temp\"";
667: if (defined($lastresponse{$name})) { $result .= ' checked="checked"'; }
668: $result .= ' />'.$Apache::response::foilgroup{$name.'.text'}."</label>";
669: } else {
670: if ($Apache::lonhomework::type eq 'exam') {
671: if($bubble_number >= $bubbles_per_line) {
672: $line++;
673: $i = 0;
674: $bubble_number = 0;
675: $result.='\item[\textbf{'.($Apache::lonxml::counter+$line).'}.]';
676: }
677: $result .= '{\small \textbf{'.$alphabet[$i].'}}$\bigcirc$'.$Apache::response::foilgroup{$name.'.text'}.'\\\\'; #' stupid emacs
678: $i++;
679: $bubble_number++;
680: } else {
681: if($env{'form.pdfFormFields'} eq 'yes' && $Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
682: my $fieldname = $env{'request.symb'}.'&part_'. $Apache::inputtags::part
683: .'&radiobuttonresponse'.'&HWVAL_'.$Apache::inputtags::response['-1'];
684: $result .= '\item[{'.&Apache::lonxml::print_pdf_radiobutton($fieldname,$temp).'}]'
685: .$Apache::response::foilgroup{$name.'.text'}."\n";
686: } else {
687: $result .= '\vspace*{-2 mm}\item '.$Apache::response::foilgroup{$name.'.text'};
688: }
689: }
690: }
691: if ($target ne 'tex' && $direction eq 'horizontal') {
692: $result.="</td>";
693: }
694: $temp++;
695: }
696: if ($target ne 'tex' && $direction eq 'horizontal') {
697: $result.="</tr></table>";
698: }
699: }
700: if ($target ne 'tex') { if ($direction ne 'horizontal') { $result.="<br />";} } else { $result.='\vskip 0 mm '; }
701: return $result;
702: }
703:
704: sub displayallanswers {
705: my @names;
706: if ( $Apache::response::foilgroup{'names'} ) {
707: @names= @{ $Apache::response::foilgroup{'names'} };
708: }
709: my $result=&Apache::response::answer_header('radiobuttonresponse');
710: foreach my $name (@names) {
711: $result.=&Apache::response::answer_part('radiobuttonresponse',
712: $Apache::response::foilgroup{$name.'.value'});
713: }
714: $result.=&Apache::response::answer_footer('radiobuttonresponse');
715: return $result;
716: }
717:
718: sub displayanswers {
719: my ($answer, $whichopt, $bubbles_per_line)=@_;
720: my $result;
721:
722: if ($Apache::lonhomework::type eq 'exam') {
723: my $line = int($answer/$bubbles_per_line);
724: my $correct = ('A'..'Z')[$answer%$bubbles_per_line];
725: $result .= &Apache::response::answer_header('radiobuttonresponse',
726: $line);
727: $result .= &Apache::response::answer_part('radiobuttonresponse',
728: $correct);
729: } else {
730: $result .= &Apache::response::answer_header('radiobuttonresponse');
731: }
732: foreach my $name (@{ $whichopt }) {
733: $result.=&Apache::response::answer_part('radiobuttonresponse',
734: $Apache::response::foilgroup{$name.'.value'});
735: }
736: $result.=&Apache::response::answer_footer('radiobuttonresponse');
737: return $result;
738: }
739:
740: sub start_conceptgroup {
741: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
742: $Apache::radiobuttonresponse::conceptgroup=1;
743: %Apache::response::conceptgroup=();
744: my $result;
745: if ($target eq 'edit') {
746: $result.=&Apache::edit::tag_start($target,$token);
747: $result.=&Apache::edit::text_arg('Concept:','concept',$token,'50').
748: &Apache::edit::end_row().&Apache::edit::start_spanning_row();
749: } elsif ($target eq 'modified') {
750: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
751: $safeeval,'concept');
752: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
753: }
754: return $result;
755: }
756:
757: sub end_conceptgroup {
758: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
759: $Apache::radiobuttonresponse::conceptgroup=0;
760: my $result;
761: if ($target eq 'web' || $target eq 'grade' || $target eq 'answer' ||
762: $target eq 'tex' || $target eq 'analyze') {
763: &Apache::response::pick_foil_for_concept($target,
764: ['value','text','location'],
765: \%Apache::hint::radiobutton,
766: $parstack,$safeeval);
767: } elsif ($target eq 'edit') {
768: $result=&Apache::edit::end_table();
769: }
770: return $result;
771: }
772:
773: sub insert_conceptgroup {
774: my $result="\n\t\t<conceptgroup concept=\"\">".&insert_foil()."\n\t\t</conceptgroup>\n";
775: return $result;
776: }
777:
778: sub start_foil {
779: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
780: my $result='';
781: if ($target eq 'web' || $target eq 'tex' || $target eq 'analyze') {
782: &Apache::lonxml::startredirection;
783: if ($target eq 'analyze') {
784: &Apache::response::check_if_computed($token,$parstack,$safeeval,'value');
785: }
786: } elsif ($target eq 'edit') {
787: $result=&Apache::edit::tag_start($target,$token);
788: $result.=&Apache::edit::text_arg('Name:','name',$token);
789: $result.=&Apache::edit::select_or_text_arg('Correct Option:','value',
790: ['unused','true','false'],
791: $token);
792: my $randomize=&Apache::lonxml::get_param('randomize',$parstack,
793: $safeeval,'-3');
794: if ($randomize ne 'no') {
795: $result.=&Apache::edit::select_arg('Location:','location',
796: ['random','top','bottom'],$token);
797: }
798: $result.=&Apache::edit::end_row().&Apache::edit::start_spanning_row();
799: } elsif ($target eq 'modified') {
800: my $constructtag=&Apache::edit::get_new_args($token,$parstack,
801: $safeeval,'value','name',
802: 'location');
803: if ($constructtag) { $result = &Apache::edit::rebuild_tag($token); }
804: }
805: return $result;
806: }
807:
808: sub end_foil {
809: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
810: my $text='';
811: if ($target eq 'web' || $target eq 'tex' || $target eq 'analyze') {
812: $text=&Apache::lonxml::endredirection;
813: }
814: if ($target eq 'web' || $target eq 'grade' || $target eq 'answer'
815: || $target eq 'tex' || $target eq 'analyze') {
816: my $value = &Apache::lonxml::get_param('value',$parstack,$safeeval);
817: if ($value ne 'unused') {
818: my $name = &Apache::lonxml::get_param('name',$parstack,$safeeval);
819: if ($name eq "") {
820: &Apache::lonxml::warning(&mt('Foils without names exist. This can cause problems to malfunction.'));
821: $name=$Apache::lonxml::curdepth;
822: }
823: if (defined($Apache::response::foilnames{$name})) {
824: &Apache::lonxml::error(&mt('Foil name [_1] appears more than once. Foil names need to be unique.','<b><tt>'.$name.'</tt></b>'));
825: }
826: $Apache::response::foilnames{$name}++;
827: my $location =&Apache::lonxml::get_param('location',$parstack,
828: $safeeval);
829: if ( $Apache::radiobuttonresponse::conceptgroup
830: && !&Apache::response::showallfoils() ) {
831: push @{ $Apache::response::conceptgroup{'names'} }, $name;
832: $Apache::response::conceptgroup{"$name.value"} = $value;
833: $Apache::response::conceptgroup{"$name.text"} = $text;
834: $Apache::response::conceptgroup{"$name.location"} = $location;
835: } else {
836: push @{ $Apache::response::foilgroup{'names'} }, $name;
837: $Apache::response::foilgroup{"$name.value"} = $value;
838: $Apache::response::foilgroup{"$name.text"} = $text;
839: $Apache::response::foilgroup{"$name.location"} = $location;
840: }
841: }
842: }
843: return '';
844: }
845:
846: sub insert_foil {
847: return '
848: <foil name="" value="unused">
849: <startouttext />
850: <endouttext />
851: </foil>';
852: }
853: 1;
854: __END__
855:
856:
857:
858: =head1 NAME
859:
860: Apache::radiobuttonresponse
861:
862: =head1 SYNOPSIS
863:
864: Handles multiple-choice style responses.
865:
866: This is part of the LearningOnline Network with CAPA project
867: described at http://www.lon-capa.org.
868:
869: =head1 SUBROUTINES
870:
871: =over
872:
873: =item start_radiobuttonresponse()
874:
875: =item bubble_line_count()
876:
877: =item end_radiobuttonresponse()
878:
879: =item start_foilgroup()
880:
881: =item storesurvey()
882:
883: =item grade_response()
884:
885: =item end_foilgroup()
886:
887: =item getfoilcounts()
888:
889: =item format_prior_answer()
890:
891: =item displayallfoils()
892:
893: =item &whichfoils($max,$randomize)
894:
895: Randomizes the list of foils.
896: Respects
897: - each foils desire to be randomized
898: - the existance of Concept groups of foils (select 1 foil from each)
899: - and selects a single correct statement from all possilble true statments
900: - and limits it to a toal of $max foils
901:
902: WARNING: this routine uses the random number generator, it should only
903: be called once per target, otherwise it can cause randomness changes in
904: homework problems.
905:
906: Arguments
907: $max - maximum number of foils to select (including the true one)
908: (so a max of 5 is: 1 true, 4 false)
909:
910: $randomize - whether to randomize the listing of foils, by default
911: will randomize, only if randomize is 'no' will it not
912:
913: Returns
914: $answer - location in the array of the correct answer
915: @foils - array of foil names in to display order
916:
917: =item displayfoils()
918:
919: =item displayallanswers()
920:
921: =item displayanswers()
922:
923: =item start_conceptgroup()
924:
925: =item end_conceptgroup()
926:
927: =item insert_conceptgroup()
928:
929: =item start_foil()
930:
931: =item end_foil()
932:
933: =item insert_foil()
934:
935: =back
936:
937: =cut
938:
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>