1: # The LearningOnline Network with CAPA
2: # essay (ungraded) style responses
3: #
4: # $Id: essayresponse.pm,v 1.99 2009/01/21 16:17:35 raeburn Exp $
5: #
6: # Copyright Michigan State University Board of Trustees
7: #
8: # This file is part of the LearningOnline Network with CAPA (LON-CAPA).
9: #
10: # LON-CAPA is free software; you can redistribute it and/or modify
11: # it under the terms of the GNU General Public License as published by
12: # the Free Software Foundation; either version 2 of the License, or
13: # (at your option) any later version.
14: #
15: # LON-CAPA is distributed in the hope that it will be useful,
16: # but WITHOUT ANY WARRANTY; without even the implied warranty of
17: # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18: # GNU General Public License for more details.
19: #
20: # You should have received a copy of the GNU General Public License
21: # along with LON-CAPA; if not, write to the Free Software
22: # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
23: #
24: # /home/httpd/html/adm/gpl.txt
25: #
26: # http://www.lon-capa.org/
27: #
28:
29: package Apache::essayresponse;
30: use strict;
31: use Apache::lonxml();
32: use Apache::lonnet;
33: use Apache::lonlocal;
34: use LONCAPA qw(:DEFAULT :match);
35:
36:
37: BEGIN {
38: &Apache::lonxml::register('Apache::essayresponse',('essayresponse'));
39: }
40:
41: sub start_essayresponse {
42: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
43: my $result;
44: my $id = &Apache::response::start_response($parstack,$safeeval);
45: if ($target eq 'meta') {
46: $result=&Apache::response::meta_package_write('essayresponse');
47: } elsif ($target eq 'web' &&
48: $Apache::inputtags::status[-1] eq 'CAN_ANSWER') {
49: my $part= $Apache::inputtags::part;
50: my $ncol= &Apache::lonnet::EXT("resource.$part".'_'."$id.maxcollaborators");
51: my $coll= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.collaborators"},'<>&"');
52: my $uploadedfiletypes= &Apache::lonnet::EXT("resource.$part".'_'."$id.uploadedfiletypes");
53: $uploadedfiletypes=~s/[^\w\,]//g;
54: my $maxfilesize=&Apache::lonnet::EXT("resource.$part".'_'."$id.maxfilesize");
55: if (!defined($maxfilesize)) {
56: $maxfilesize = 10.0; #FIXME This should become a domain configuration
57: }
58: if ( $Apache::lonhomework::type eq 'survey' ) {
59: $result.= '<input type="hidden" name="HWDRAFT'.$part.'_'.$id.'" value="yes" /> ';
60: }
61: $result.='<br /><table border="1">';
62: if ( $Apache::lonhomework::type ne 'survey' ) {
63: $result.= '<tr><td>'.
64: '<label>'.
65: '<input type="radio" name="HWDRAFT'.$part.'_'.$id.'" value="yes" checked="checked" /> '.
66: &mt('Submit entries below as answer to receive credit').
67: '</label> <br />'.
68: '<label>'.
69: '<input type="radio" name="HWDRAFT'.$part.'_'.$id.'" value="no" /> '.
70: &mt('Save entries below as a draft answer (not submitting them for credit yet)').
71: '</label>'.
72: '</td></tr>';
73: }
74:
75: if ($ncol > 0) {
76: $result .='<tr><td>'.'<label>'.
77: &mt('Collaborators:').' <input type="text" size="70" max="80" name="HWCOL'.
78: $part.'_'.$id.'" value="'.$coll.'" /><br />'.
79: &mt('(Enter a maximum of [quant,_1,collaborator] using username or username:domain, e.g. smithje or smithje:[_2].)',$ncol,$env{'user.domain'});
80: if ($ncol > 1) {
81: $result .= '<br />'.&mt('If entering more than one, use spaces to separate the collaborators.');
82: }
83: $result .= '</label><br />';
84: $result .= &check_collaborators($ncol,$coll) if ($coll =~ /\w+/);
85: $result .='</td></tr>';
86: }
87: my $filesfrom = 'both';
88: my $stuname = &Apache::lonnet::EXT('user.name');
89: my $studom = &Apache::lonnet::EXT('user.domain');
90: if (!&Apache::lonnet::usertools_access($stuname,$studom,'portfolio')) {
91: $filesfrom = 'uploadonly';
92: }
93: $result.=&Apache::inputtags::file_selector($part,$id,$uploadedfiletypes,
94: $filesfrom,undef,$maxfilesize);
95: $result.='</table>';
96: } elsif ($target eq 'web' &&
97: $Apache::inputtags::status[-1] ne 'CAN_ANSWER') {
98: my $part= $Apache::inputtags::part;
99: my @msgs;
100: if ($Apache::lonhomework::history{"resource.$part.$id.collaborators"} =~ /\S/) {
101: my $coll= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.collaborators"},'<>&"');
102: $result .= '<td>'.&mt('Collaborated with [_1]',$coll).'</td>';
103: }
104:
105: my $file_submission =
106: &Apache::inputtags::show_past_file_submission($part,$id);
107: if ($file_submission) {
108: $result .= '<td>'.$file_submission.'</td>';
109: }
110:
111: my $port_submission =
112: &Apache::inputtags::show_past_portfile_submission($part,$id);
113: if ($port_submission) {
114: $result .= '<td>'.$port_submission.'</td>';
115: }
116:
117: if ($result ne '') {
118: $result =
119: '<table class="LC_pastsubmission"><tr>'.$result.
120: '</tr></table>';
121: }
122: }
123: return $result;
124: }
125:
126: sub end_essayresponse {
127: my ($target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
128: my $part = $Apache::inputtags::part;
129: my $id = $Apache::inputtags::response[-1];
130: my $increment = &Apache::response::repetition();
131: my $result;
132: if ( $target eq 'grade' ) {
133: my $collaborators = $env{'form.HWCOL'.$part.'_'.$id};
134: if ($collaborators =~ /[^\s]/) {
135: my $previous_list= &HTML::Entities::encode($Apache::lonhomework::history{"resource.$part.$id.collaborators"},'<>&"');
136: $Apache::lonhomework::results{"resource.$part.$id.collaborators"}=$collaborators
137: if ($collaborators ne $previous_list);
138: }
139: if ( &Apache::response::submitted('scantron') ) {
140: $increment=&Apache::response::scored_response($part,$id);
141: } elsif ( &Apache::response::submitted() ) {
142: my $response = $env{'form.HWVAL_'.$id};
143: my $filename = $env{'form.HWFILE'.$part.'_'.$id.'.filename'} ||
144: $env{'form.HWFILETOOBIG'.$part.'_'.$id};
145: my $portfiles = $env{'form.HWPORT'.$part.'_'.$id};
146: if (( $response =~ /[^\s]/) || ($filename =~ /[^\s]/) || ($portfiles =~ /[^\s]/)) {
147: my $award='DRAFT';
148: if ($env{'form.HWDRAFT'.$part.'_'.$id} eq 'yes') {
149: $award='SUBMITTED';
150: }
151: my $uploadedflag=0;
152: my $totalsize=0;
153: &file_submission($part,$id,'filename',\$award,\$uploadedflag,\$totalsize);
154: &file_submission($part,$id,'portfiles',\$award,\$uploadedflag,\$totalsize);
155: $Apache::lonhomework::results{"resource.$part.$id.submission"}=$response;
156: $Apache::lonhomework::results{"resource.$part.$id.awarddetail"}=$award;
157: my %previous=&Apache::response::check_for_previous($response,$part,$id);
158: unless ($uploadedflag) { &Apache::response::handle_previous(\%previous,$award); }
159: #
160: # Store with resource author for similarity testing
161: #
162: if ($award eq 'SUBMITTED') {
163: my ($symb,$crsid,$domain,$name)=
164: &Apache::lonnet::whichuser();
165: if ($crsid) {
166: my $akey=join('.',&escape($name),&escape($domain),
167: &escape($crsid));
168: my $essayurl=
169: &Apache::lonnet::declutter($ENV{'REQUEST_URI'});
170: my ($adom,$aname,$apath)=
171: ($essayurl=~/^($LONCAPA::domain_re)\/($LONCAPA::username_re)\/(.*)$/);
172: $apath=&escape($apath);
173: $apath=~s/\W/\_/gs;
174: &Apache::lonnet::put('nohist_essay_'.$apath,
175: { $akey => $response },$adom,$aname);
176: }
177: }
178: }
179: }
180: } elsif ($target eq 'edit') {
181: $result.=&Apache::edit::end_table();
182:
183: } elsif ($target eq 'tex'
184: && $Apache::lonhomework::type eq 'exam') {
185: $result .= &Apache::inputtags::exam_score_line($target);
186:
187: } elsif ($target eq 'answer') {
188: $result.=&Apache::response::answer_header($$tagstack[-1]);
189: my $answer = &mt('Essay will be hand graded.');
190: $result.=&Apache::response::answer_part($$tagstack[-1],$answer,
191: {'no_verbatim' => 1});
192: $result.=&Apache::response::answer_footer($$tagstack[-1]);
193: }
194: if ($target eq 'web') {
195: &Apache::response::setup_prior_tries_hash(\&format_prior_response,
196: ['portfiles',
197: 'uploadedurl']);
198: }
199:
200: if ($target eq 'grade' || $target eq 'web' || $target eq 'answer' ||
201: $target eq 'tex' || $target eq 'analyze') {
202: &Apache::lonxml::increment_counter($increment, "$part.$id");
203:
204: if ($target eq 'analyze') {
205: $Apache::lonhomework::analyze{"$part.$id.type"} = 'essayresponse';
206: push (@{ $Apache::lonhomework::analyze{"parts"} },"$part.$id");
207: &Apache::lonhomework::set_bubble_lines();
208: }
209: }
210: &Apache::response::end_response;
211:
212: return $result;
213: }
214:
215: sub format_prior_response {
216: my ($mode,$answer,$other_data) = @_;
217: my $output;
218:
219: my (undef,undef,$udom,$uname) = &Apache::lonnet::whichuser();
220: my $port_url = '/uploaded/'.$udom.'/'.$uname.'/portfolio/';
221:
222: my $file_list;
223:
224: foreach my $file (split(/\s*,\s*/,
225: $other_data->[0].','.$other_data->[1])) {
226: next if ($file!~/\S/);
227: if ($file !~ m{^/uploaded/}) { $file=$port_url.$file; }
228: $file=~s|/+|/|g;
229: &Apache::lonnet::allowuploaded('/adm/essayresponse',$file);
230: $file_list.='<li><span class="LC_nobreak"><a href="'.$file.'?rawmode=1" target="lonGRDs"><img src="'.
231: &Apache::loncommon::icon($file).'" alt="file icon" border="0" /> '.$file.
232: '</a></span></li>'."\n";
233: }
234: if ($file_list) {
235: $output.= &mt('Submitted Files').'<ul>'.$file_list.'</ul>';
236: }
237: if ($answer =~ /\S/) {
238: $output.='<p>'.&mt('Submitted text').
239: '<blockquote>'.$answer.'</blockquote></p>';
240: }
241:
242: return '<div class="LC_prior_essay">'.$output.'</div>';
243: }
244:
245: sub file_submission {
246: my ($part,$id,$which,$award,$uploadedflag,$totalsize)=@_;
247: my $files;
248: my $jspart=$part;
249: $jspart=~s/\./_/g;
250: if ($which eq 'portfiles') {
251: $files= $env{'form.HWPORT'.$jspart.'_'.$id};
252: } elsif ($which eq 'filename') {
253: if ($env{'form.HWFILETOOBIG'.$jspart.'_'.$id} ne '') {
254: $$award = 'EXCESS_FILESIZE';
255: return;
256: } else {
257: $files = $env{'form.HWFILE'.$jspart.'_'.$id.'.filename'};
258: }
259: }
260: if ($files =~ /[^\s]/) {
261: $files =~s/,$//;
262: my (@submitted_files,@acceptable_files,@accepted_files);
263: if ($which eq 'portfiles') {
264: @submitted_files = split(/\s*,\s*/,$files);
265: } else {
266: @submitted_files = ($files);
267: }
268: my $uploadedfiletypes=
269: &Apache::lonnet::EXT("resource.$part".'_'."$id.uploadedfiletypes");
270: if ($uploadedfiletypes ne '') {
271: $uploadedfiletypes=~s/[^\w\,]//g;
272: $uploadedfiletypes=','.$uploadedfiletypes.',';
273: foreach my $file (@submitted_files) {
274: my ($extension)=($file=~/\.(\w+)$/);
275: if ($uploadedfiletypes=~/\,\s*\Q$extension\E\s*\,/i) {
276: push(@acceptable_files,$file);
277: } else {
278: $$award='INVALID_FILETYPE';
279: if ($which eq 'filename') {
280: &delete_form_items($jspart,$id);
281: }
282: }
283: }
284: } else {
285: foreach my $file (@submitted_files) {
286: push(@acceptable_files,$file);
287: }
288: }
289: my $maxfilesize=&Apache::lonnet::EXT("resource.$part".'_'."$id.maxfilesize");
290: if (!$maxfilesize) {
291: $maxfilesize = 10.0; #FIXME This should become a domain configuration
292: }
293: my %dirlist;
294: foreach my $file (@acceptable_files) {
295: if ($which eq 'filename') {
296: if (ref($totalsize)) {
297: $$totalsize += $env{'form.HWFILESIZE'.$jspart.'_'.$id};
298: }
299: } else {
300: my ($symb,$crsid,$udom,$uname) = &Apache::lonnet::whichuser();
301: my ($path,$filename) = ($file =~ m{^(.*/)([^/]+)$});
302: my $fullpath = '/userfiles/portfolio'.$path;
303: if (!exists($dirlist{$fullpath})) {
304: my @list = &Apache::lonnet::dirlist($fullpath,$udom,$uname,1);
305: $dirlist{$fullpath} = \@list;
306: }
307: if (ref($dirlist{$fullpath}) eq 'ARRAY') {
308: foreach my $dir_line (@{$dirlist{$fullpath}}) {
309: my ($fname,$dom,undef,$testdir,undef,undef,undef,undef,
310: $size,undef,$mtime,undef,undef,undef,$obs,undef) =
311: split(/\&/,$dir_line,16);
312: if ($filename eq $fname) {
313: my $mbsize = $size/(1024.0*1024.0);
314: if (ref($totalsize)) {
315: $$totalsize += $mbsize;
316: }
317: last;
318: }
319: }
320: }
321: }
322: if (ref($totalsize)) {
323: if ($$totalsize > $maxfilesize) {
324: $$award='EXCESS_FILESIZE';
325: if ($which eq 'filename') {
326: &delete_form_items($jspart,$id);
327: }
328: last;
329: } else {
330: push(@accepted_files,$file);
331: }
332: } else {
333: push(@accepted_files,$file);
334: }
335: }
336: $Apache::lonhomework::results{"resource.$part.$id.$which"}=join(',',@accepted_files);
337: if (($$award eq 'INVALID_FILETYPE') || ($award eq 'EXCESS_FILESIZE')) {
338: return;
339: }
340: if (ref($uploadedflag)) {
341: $$uploadedflag=1;
342: }
343: my ($symb,$crsid,$domain,$name)=&Apache::lonnet::whichuser();
344: if ($which eq 'portfiles') {
345: &Apache::lonnet::unmark_as_readonly($domain,$name,[$symb,$crsid]);
346: &Apache::lonnet::mark_as_readonly($domain,$name,\@submitted_files,[$symb,$crsid]);
347: &Apache::lonnet::clear_selected_files($name);
348: }
349: if ($which eq 'filename') {
350: $Apache::lonhomework::results{"resource.$part.$id.uploadedfile"}=
351: $files;
352: my $cleanpart = $part;
353: $cleanpart =~ s/\W/_/g;
354: my $cleanid = $id;
355: $cleanid =~ s/\W/_/g;
356: my ($map,$resid,$res)=&Apache::lonnet::decode_symb($symb);
357: my $container;
358: if ($map =~ /^uploaded/) {
359: (my $prefix,$container) = ($map =~ m{^uploaded/[^/]+/[^/]+/(default|supplemental)_?([^.]*)\.(?:sequence|page)$});
360: if (length($container) > 10) {
361: $container = substr($container,-10,10);
362: }
363: if ($container ne '') {
364: $container = $prefix.'_'.$container;
365: } else {
366: $container = $prefix;
367: }
368: } else {
369: ($container) = ($map =~ m{(.+)\.(?:sequence|page)$});
370: $container =~ s/\W/_/g;
371: if (length($container) > 255) {
372: $container = substr($container,0,254);
373: }
374: }
375: my $subdir = 'essayresponse';
376: my %crsdesc = &Apache::lonnet::coursedescription($crsid);
377: foreach my $item ($crsdesc{'domain'},$crsdesc{'num'},$container,$resid,$cleanpart,$cleanid) {
378: if ($item ne '') {
379: $subdir .= '/'.$item;
380: }
381: }
382: $Apache::lonhomework::results{"resource.$part.$id.uploadedurl"}=
383: &Apache::lonnet::userfileupload('HWFILE'.$jspart.'_'.$id,undef,
384: $subdir);
385: delete($env{'form.HWFILE'.$jspart.'_'.$id});
386: }
387: } elsif ($which eq 'portfiles' &&
388: $Apache::lonhomework::history{"resource.$part.$id.$which"}) {
389: my ($symb,$crsid,$domain,$name)=&Apache::lonnet::whichuser();
390: &Apache::lonnet::unmark_as_readonly($domain,$name,[$symb,$crsid]);
391: $Apache::lonhomework::results{"resource.$part.$id.$which"}="";
392: }
393: }
394:
395: sub delete_form_items {
396: my ($jspart,$id) = @_;
397: delete($env{'form.HWFILE'.$jspart.'_'.$id.'.filename'});
398: delete($env{'form.HWFILE'.$jspart.'_'.$id.'.mimetype'});
399: delete($env{'form.HWFILE'.$jspart.'_'.$id});
400: }
401:
402:
403: sub check_collaborators {
404: my ($ncol,$coll) = @_;
405: my %classlist=&Apache::lonnet::dump('classlist',
406: $env{'course.'.$env{'request.course.id'}.'.domain'},
407: $env{'course.'.$env{'request.course.id'}.'.num'});
408: my (@badcollaborators,$result);
409:
410: my (@collaborators) = split(/,?\s+/,$coll);
411: foreach my $entry (@collaborators) {
412: my $collaborator;
413: if ($entry =~ /:/) {
414: $collaborator = $entry;
415: } else {
416: $collaborator = $entry.':'.$env{'user.domain'};
417: }
418: if ($collaborator !~ /^$match_username:$match_domain$/) {
419: if (!grep(/^\Q$entry\E$/,@badcollaborators)) {
420: push(@badcollaborators,$entry);
421: }
422: } elsif (!grep(/^\Q$collaborator\E$/i,keys(%classlist))) {
423: if (!grep(/^\Q$entry\E$/,@badcollaborators)) {
424: push(@badcollaborators,$entry);
425: }
426: }
427: }
428:
429: my $numbad = scalar(@badcollaborators);
430: if ($numbad) {
431: $result = '<table border="0"><tr bgcolor="#ffbbbb"><td>';
432: if ($numbad == 1) {
433: $result .= &mt('The following user is invalid:');
434: } else {
435: $result .= &mt('The following [_1] users are invalid:',$numbad);
436: }
437: $result .= ' '.join(', ',@badcollaborators).'. '.&mt('Please correct.').
438: '</td></tr></table>';
439: }
440: my $toomany = scalar(@collaborators) - $ncol;
441: if ($toomany > 0) {
442: $result .= '<table border="0"><tr bgcolor="#ffbbbb"><td>'.
443: &mt('You have too many collaborators.').' '.
444: &mt('Please remove [quant,_1,collaborator].',$toomany).
445: '</td></tr></table>';
446: }
447: return $result;
448: }
449:
450: 1;
451: __END__
452:
453:
454: =pod
455:
456: =head1 NAME
457:
458: Apache::easyresponse
459:
460: =head1 SYNOPSIS
461:
462: Handler to evaluate essay (ungraded) style responses.
463:
464: This is part of the LearningOnline Network with CAPA project
465: described at http://www.lon-capa.org.
466:
467: =head1 SUBROUTINES
468:
469: =over
470:
471: =item start_essayresponse()
472:
473: =item end_essayresponse()
474:
475: =item format_prior_response()
476:
477: =item file_submission()
478:
479: =item delete_form_items()
480:
481: =item check_collaborators()
482:
483: =back
484:
485: =cut
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>