Return to edit.pm CVS log

Up to [LON-CAPA] / loncom / homework

Added textfield() as an alternative to editfield().  textfield serves up an
<input type="text" .. /> form instead of a <textarea> form.  This means we
can limit the user to a single line of text within a <tag> </tag> pair.

# The LearningOnline Network with CAPA 
# edit mode helpers
#
# $Id: edit.pm,v 1.31 2002/03/22 14:45:11 matthew Exp $
#
# Copyright Michigan State University Board of Trustees
#
# This file is part of the LearningOnline Network with CAPA (LON-CAPA).
#
# LON-CAPA is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# LON-CAPA is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LON-CAPA; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#
# /home/httpd/html/adm/gpl.txt
#
# http://www.lon-capa.org/
#
# 3/20 Guy
# 01/10/02 Matthew
# 03/06/02 Matthew
package Apache::edit; 

use strict;
use Apache::lonnet;

# Global Vars
# default list of colors to use in editing
@Apache::edit::colorlist=('#ffffff','#ff0000','#00ff00','#0000ff','#0ff000','#000ff0','#f0000f');
# depth of nesting of edit
$Apache::edit::colordepth=0;

sub initialize_edit {
  $Apache::edit::colordepth=0;
}

sub tag_start {
  my ($target,$token,$description) = @_;
  my $result='';
  if ($target eq "edit") {
    my $tag=$token->[1];
    if (!$description) {
      $description=&Apache::lonxml::description($token);
      if (!$description) { $description="<$tag>"; }
    }
    $result.= &start_table($token)."<tr><td>$description</td>
<td>Delete".
  &deletelist($target,$token)
  ."</td>
<td>".
    &insertlist($target,$token).&end_row().&start_spanning_row();
#<td>". 
#  &movebuttons($target,$token).
#    "</tr><tr><td colspan=\"3\">\n";
  }
  return $result;
}

sub tag_end {
  my ($target,$token,$description) = @_;
  my $result='';
  if ($target eq 'edit') {
    my $tag=$token->[1];
    if (!defined($description)) {
      $result.="</td></tr><tr><td>&lt;/$tag&gt;</td><td colspan=\"2\">&nbsp;</td>";
    } else {
      if ($description ne '') { $result.="</td></tr><tr><td>$description</td><td colspan=\"2\">&nbsp;</td>"; }
    }
    $result.="</tr>".&end_table()."\n";
  }
  return $result;
}

sub start_table {
  my ($token)=@_;
  my $tag = $token->[1];
  my $tagnum;
  foreach my $namespace (reverse @Apache::lonxml::namespace) {
    my $testtag=$namespace.'::'.$tag;
    $tagnum=$Apache::lonxml::insertlist{"$testtag.num"};
    if (defined($tagnum)) { last; }
  }
  if (!defined ($tagnum)) { $tagnum=$Apache::lonxml::insertlist{"$tag.num"}; }
  my $color = $Apache::lonxml::insertlist{"$tagnum.color"};
  if (!defined($color)) {
    $color = $Apache::edit::colorlist[$Apache::edit::colordepth];
  }
  $Apache::edit::colordepth++;
  my $result="<table bgcolor=\"$color\" width=\"100%\" border=\"5\">";
  return $result;
}

sub end_table {
  $Apache::edit::colordepth--;
  my $result="</table>";
  return $result;
}

sub start_spanning_row { return '<tr><td colspan="3">';}
sub start_row          { return '<tr><td>';            }
sub end_row            { return '</td></tr>';          }

sub movebuttons {
  my ($target,$token) = @_;
  my $result='<input type="submit" name="moveup.'.
    $Apache::lonxml::curdepth.'" value="Move Up" />';
  $result.='<input type="submit" name="movedown.'.
    $Apache::lonxml::curdepth.'" value="Move Down" />';
  return $result;
}

sub deletelist {
  my ($target,$token) = @_;
  my $result = "<select name=\"delete_$Apache::lonxml::curdepth\">
<option></option>
<option>Yes</option>
</select>";
  return $result;
}

sub handle_delete {
  if (!$ENV{"form.delete_$Apache::lonxml::curdepth"}) { return ''; }
  my ($space,$target,$token,$tagstack,$parstack,$parser,$safeeval,$style)=@_;
  my $result=0;
  if ($space) {
    my $sub1="$space\:\:delete_$token->[1]";
    {
      no strict 'refs';
      if (defined &$sub1) {
	$result=&$sub1($target,$token,$tagstack,$parstack,$parser,$safeeval,$style);
      }
    }
  }
  if (!$result) {
    my $endtag='/'.$token->[1];
    my $bodytext=&Apache::lonxml::get_all_text($endtag,$$parser[$#$parser]);
    $$parser['-1']->get_token();
    &Apache::lonxml::debug("Deleting :$bodytext: for $token->[1]");
    &Apache::lonxml::end_tag($tagstack,$parstack,$token);
  }
  return 1;
}

sub get_insert_list {
  my ($token) = @_;
  my $result='';
  my @tagnums= ();
  #&Apache::lonxml::debug("keys ".join("\n",sort(keys(%Apache::lonxml::insertlist))));
  if ($Apache::lonxml::insertlist{"$token->[1].which"}) {
    push (@tagnums, @{ $Apache::lonxml::insertlist{"$token->[1].which"} });
  }
  foreach my $namespace (@Apache::lonxml::namespace) {
    if ($Apache::lonxml::insertlist{"$namespace".'::'."$token->[1].which"}) {
      push (@tagnums, @{ $Apache::lonxml::insertlist{"$namespace".'::'."$token->[1].which"} });
    }
  }
  if (@tagnums) {
    foreach my $tagnum (@tagnums) {
      $result.='<option value="'.$tagnum.'">'.$Apache::lonxml::insertlist{"$tagnum.description"}."</option>\n";
    }
    if ($result) { $result='<option selected="on"></option>'.$result; }
  }
  return $result;
}

sub insertlist {
  my ($target,$token) = @_;
  my $result;
  if ($target eq 'edit') {
    my $optionlist= &get_insert_list($token);
    if ($optionlist) {
      $result = "Insert:
<select name=\"insert_$Apache::lonxml::curdepth\">
$optionlist
</select>"
    } else {
      $result="&nbsp;";
    }
  }
  return $result;
}

sub handle_insert {
  if ($ENV{"form.insert_$Apache::lonxml::curdepth"} eq '') { return ''; }
  my $result;
  my $tagnum = $ENV{"form.insert_$Apache::lonxml::curdepth"};
  my $func=$Apache::lonxml::insertlist{"$tagnum.function"};
  if ($func eq 'default') {
    my $newtag=$Apache::lonxml::insertlist{"$tagnum.tag"};
    my $namespace;
    if ($newtag =~ /::/) { ($namespace,$newtag) = split(/::/,$newtag); }
    $result.="\n<$newtag>\n</$newtag>";
  } else {
    if (defined(&$func)) {
      {
	no strict 'refs';
	$result.=&$func();
      }
    } else {
      my $newtag=$Apache::lonxml::insertlist{"$tagnum.tag"};
      &Apache::lonxml::error("Unable to insert tag $newtag, $func was not defined.");
    }
  }
  return $result;
}

sub insert_responseparam {
  return '
    <responseparam />';
}

sub insert_formularesponse {
  return '
<formularesponse answer="" samples="">
    <textline />
    <hintgroup>
    </hintgroup>
</formularesponse>';
}

sub insert_numericalresponse {
  return '
<numericalresponse answer="">
    <textline />
    <hintgroup>
    </hintgroup>
</numericalresponse>';
}

sub insert_stringresponse {
  return '
<stringresponse answer="" type="">
    <textline />
    <hintgroup>
    </hintgroup>
</stringresponse>';
}

sub insert_optionresponse {
  return '
<optionresponse max="10">
    <foilgroup options="">
    </foilgroup>
    <hintgroup>
    </hintgroup>
</optionresponse>';
}

sub insert_radiobuttonresponse {
  return '
<radiobuttonresponse max="10">
    <foilgroup>
    </foilgroup>
    <hintgroup>
    </hintgroup>
</radiobuttonresponse>';
}

sub insert_displayduedate { return '<displayduedate />'; }
sub insert_displaytitle   { return '<displaytitle />'; }
sub insert_hintpart {
  return '
<hintpart on="default">
    <startouttext/>
    <endouttext />
</hintpart>';
}

sub insert_numericalhint {
  return '
<numericalhint>
</numericalhint>';
}

sub insert_startouttext {
  return "<startouttext />\n<endouttext />";
}

sub insert_script {
  return "\n<script type=\"loncapa/perl\">\n</script>";
}

sub textarea_sizes {
  my ($data)=@_;
  my $count=0;
  my $maxlength=-1;
  foreach (split ("\n", $$data)) { $count++;
	if (length($_) > $maxlength) { $maxlength = length($_); }
      }
  my $rows = $count;
  my $cols = $maxlength;
  return ($rows,$cols);
}

sub textfield {
    my ($tag,$data,$description,$size)=@_;
    if ($description) { $description="<br />".$description."<br />"; }
    my $result = <<"END";
$description
<input type="text" name="homework_edit_$Apache::lonxml::curdepth" 
       value="$data" size="$size" />
END
    return $result;
}

sub editfield {
  my ($tag,$data,$description,$minwidth,$minheight)=@_;

  my ($rows,$cols)=&textarea_sizes(\$data);
  if ($cols > 80) { $cols = 80; }
  if ($cols < $minwidth ) { $cols = $minwidth; }
  if ($rows < $minheight) { $rows = $minheight; }
  if ($description) { $description="<br />".$description."<br />"; }
  return "$description\n&nbsp;&nbsp;&nbsp;<textarea rows=\"$rows\" cols=\"$cols\" name=\"homework_edit_".$Apache::lonxml::curdepth."\">$data</textarea>\n";
}

sub modifiedfield {
  my ($token) = @_;
  my $result;
#  foreach my $envkey (sort keys %ENV) {
#    &Apache::lonxml::debug("$envkey ---- $ENV{$envkey}");
#  }
#  &Apache::lonxml::debug("I want homework_edit_$Apache::lonxml::curdepth");
#  &Apache::lonxml::debug($ENV{"form.homework_edit_$Apache::lonxml::curdepth"});
  $result=$ENV{"form.homework_edit_$Apache::lonxml::curdepth"};
  return $result;
}

# Returns a 1 if the token has been modified and you should rebuild the tag
# side-effects, will modify the $token if new values are found
sub get_new_args {
  my ($token,$parstack,$safeeval,@args)=@_;
  my $rebuild=0;
  foreach my $arg (@args) {
    #just want the string that it was set to
    my $value=$token->[2]->{$arg};
    my $newvalue=$ENV{"form.$Apache::lonxml::curdepth.$arg"};
    &Apache::lonxml::debug(" for:$arg: cur is :$value: new is :$newvalue:");
    if ($value ne $newvalue) {
      $token->[2]->{$arg}=$newvalue;
      $rebuild=1;
    }
  }
  return $rebuild;
}

# looks for /> on start tags
sub rebuild_tag {
  my ($token) = @_;
  my $result;
  if ($token->[0] eq 'S') {
    $result = '<'.$token->[1];
    while (my ($key,$val)= each(%{$token->[2]})) {
      $val=~s:^\s+|\s+$::g;
      $val=~s:"::g; #"
      &Apache::lonxml::debug("setting :$key: to  :$val:");
      $result.=' '.$key.'="'.$val.'"';
    }
    if ($token->[4] =~ m:/>$:) {
      $result.=' />';
    } else {
      $result.='>';
    }
  } elsif ( $token->[0] eq 'E' ) {
    $result = '</'.$token->[1].'>';
  }
  return $result;
}

sub text_arg {
  my ($description,$name,$token,$size) = @_;
  my $result;
  if (!defined $size) { $size=20; }
  my $arg=$token->[2]{$name};
  $result=$description.'<input name="'."$Apache::lonxml::curdepth.$name".
    '" type="text" value="'.$arg.'" size="'.$size.'" />';
  return $result;
}

sub select_arg {
  my ($description,$name,$list,$token) = @_;
  my $result;
  my $optionlist="";
  my $selected=$token->[2]{$name};
  foreach my $option (@$list) {
    if ( $selected eq $option ) {
      $optionlist.="<option selected=\"on\">$option</option>\n";
    } else {
      $optionlist.="<option>$option</option>\n";
    }
  }
  $result.=$description.'<select name="'."$Apache::lonxml::curdepth.$name".'">
       '.$optionlist.'
      </select>';
  return $result;
}

sub select_or_text_arg {
  my ($description,$name,$list,$token,$size) = @_;
  my $result;
  my $optionlist="";
  my $found=0;
  my $selected=$token->[2]{$name};
  foreach my $option (@$list) {
    if ( $selected eq $option ) {
      $optionlist.="<option selected=\"on\">$option</option>\n";
      $found=1;
    } else {
      $optionlist.="<option>$option</option>\n";
    }
  }
  $optionlist.="<option value=\"TYPEDINVALUE\">Type in value</option>\n";
  if ($found) {
    $result.=$description.'<select name="'."$Apache::lonxml::curdepth.$name".'">
       '.$optionlist.'
      </select>';
  } else {
    $result.=&text_arg($description,$name,$token,$size);
  }
  return $result;
}

#----------------------------------------------------- browse
sub browse {
    # insert a link to call up the filesystem browser (lonindexer)
    $_ = shift;
    my $form    = 'lonhomework';
    my $element = &Apache::lonnet::escape("$Apache::lonxml::curdepth.$_");
    my $result = <<"ENDBUTTON";
<a href=\"javascript:openbrowser('$form','$element')\"\>Browse</a>
ENDBUTTON
    return $result;
}

#----------------------------------------------------- browse
sub search {
    # insert a link to call up the filesystem browser (lonindexer)
    $_ = shift;
    my $form    = 'lonhomework';
    my $element = &Apache::lonnet::escape("$Apache::lonxml::curdepth.$_");
    my $result = <<"ENDBUTTON";
<a href=\"javascript:opensearcher('$form','$element')\"\>Search</a>
ENDBUTTON
    return $result;
}


1;
__END__

=head1 NAME

Apache::edit - edit mode helpers

=head1 SYNOPSIS

Invoked by many homework and xml related modules.

 &Apache::edit::SUBROUTINENAME(ARGUMENTS);

=head1 INTRODUCTION

This module outputs HTML syntax helpful for the rendering of edit
mode interfaces.

This is part of the LearningOnline Network with CAPA project
described at http://www.lon-capa.org.

=head1 HANDLER SUBROUTINE

There is no handler subroutine.

=head1 OTHER SUBROUTINES

=over 4

=item *

initialize_edit() : initialize edit (set colordepth to zero)

=item *

tag_start($target,$token,$description) : provide deletion and insertion lists
for the manipulation of a start tag; return a scalar string

=item *

tag_end($target,$token,$description) : ending syntax corresponding to
&tag_start. return a scalar string.

=item *

start_table($token) : start table; update colordepth; return scalar string.

=item *

end_table() : reduce color depth; end table; return scalar string

=item *

start_spanning_row() : start a new table row spanning the 'edit' environment.

=item *

start_row() : start a new table row and element. 

=item *

end_row() : end current table element and row.

=item *

movebuttons($target,$token) : move-up and move-down buttons; return scalar
string

=item *

deletelist($target,$token) : provide a yes option in an HTML select element;
return scalar string

=item *

handle_delete($space,$target,$token,$tagstack,$parstack,$parser,$safeeval,
$style) : respond to a user delete request by passing relevant stack
and array information to various rendering functions; return a scalar string

=item *

get_insert_list($token) : provide an insertion list based on possibilities
from lonxml; return a scalar string

=item *

insertlist($target,$token) : api that uses get_insert_list;
return a scalar string

=item *

handleinsert($token) : provide an insertion list based on possibilities
from lonxml; return a scalar string

=item *

get_insert_list($token) : provide an insertion list based on possibilities
from lonxml; return a scalar string

=item *
browse($elementname) : provide a link which will open up the filesystem
browser (lonindexer) and, once a file is selected, place the result in
the form element $elementname.

=item *
search($elementname) : provide a link which will open up the filesystem
searcher (lonsearchcat) and, once a file is selected, place the result in
the form element $elementname.

= item *
textfield(tag,data,description,size): Provide a <input type="text" ../> for
single-line text entry.  This is to be used for text enclosed by tags, not
arguements/parameters associated with a tag.

=back

incomplete...

=cut